C_MaintWorkRequestDamageCodeVH

@AbapCatalog.sqlViewName: 'CMWRKRQCODE'
@VDM.viewType: #CONSUMPTION

@AccessControl.authorizationCheck: #CHECK
@Metadata.ignorePropagatedAnnotations: true
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
  usageType: {
    serviceQuality: #C,
    sizeCategory: #M,
    dataClass: #CUSTOMIZING }
}
@AbapCatalog.preserveKey:true
@AbapCatalog.compiler.compareFilter:true
@Search.searchable: true
@ObjectModel.dataCategory: #VALUE_HELP
define view C_MaintWorkRequestDamageCodeVH
  as select distinct from I_InspectionCode
  inner join I_PMNotificationType as pmnotiftype on I_InspectionCode.InspectionCatalog = pmnotiftype.MaintNotifCodgCatalogTypeCode
  association [0..*] to I_Inspectioncodegrouptext as _InspectionCodeGroupText on  _InspectionCodeGroupText.InspectionCatalog   = $projection.InspectionCatalog
                                                                              and _InspectionCodeGroupText.InspectionCodeGroup = $projection.InspectionCodeGroup

  association [0..*] to I_NotificationCatalogText as _NotificationCatalogText on  $projection.InspectionCatalog = _NotificationCatalogText.NotificationCatalog
{
      @Search.defaultSearchElement: true
      @UI.lineItem: [{ position: 60 }]
      @UI.selectionField: [{ position: 10  }]
  key I_InspectionCode.InspectionCatalog,

      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7  }
      @ObjectModel.text.element:  [ 'InspectionCodeText' ]
      @EndUserText.label: 'Failure Mode'
      @UI.lineItem: [{ position: 20 }]
      @UI.selectionField: [{ position: 30  }]
  key I_InspectionCode.InspectionCode,
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7  }
      //--[ GENERATED:012:GFBfhxvv7jY4hYOuhNduX0

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'C_MaintWrkReqDamageCodeGroupVH',
                     element: 'InspectionCodeGroup' },
          additionalBinding: [{ localElement: 'InspectionCatalog',
                                element: 'InspectionCatalog' ,
                                usage: #FILTER }]
        }]
      // ]--GENERATED

      @ObjectModel.text.element: ['InspSpecAddlCodeGroupText']
      @EndUserText.label: 'Failure Mode Group'
      @UI.lineItem: [{ position: 40 }]
      @UI.selectionField: [{ position: 50  }]
  key I_InspectionCode.InspectionCodeGroup,

      @EndUserText.label: 'Catalog Profile'
      @UI.lineItem:[{ hidden: true } ]
      @ObjectModel.readOnly: true
      @ObjectModel.filter.transformedBy: 'ABAP:CL_EAM_MALF_CODE_VH_EXIT'
      @UI.selectionField: [{ position: 70  }]
      cast ('' as rbnr)  as CatalogProfile,

      @Consumption.filter.hidden: true
      @UI.lineItem:[{ hidden: true } ]
      @ObjectModel.filter.transformedBy: 'ABAP:CL_EAM_MNTNTF_NOTIF_TYPE_EXIT'
      cast ('' as qmart) as NotificationType,

      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7 }
      @Semantics.text: true
      @EndUserText.label: 'Failure Mode Text'
      @UI.lineItem: [{ position: 30 }]
      @UI.selectionField: [{ position: 40  }]
      I_InspectionCode._Text[1: Language = $session.system_language ].InspectionCodeText,

      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7 }
      @EndUserText.label: 'Failure Mode Group Text'
      @UI.lineItem: [{ position: 50 }]
      @UI.selectionField: [{ position: 60  }]
      @Semantics.text: true
      _InspectionCodeGroupText[1: Language = $session.system_language ].InspSpecAddlCodeGroupText,

      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.7 }
      @EndUserText.label: 'Catalog Text'
      @UI.lineItem: [{ position: 70 }]
      @Semantics.text: true
      @UI.selectionField: [{ position: 20  }]
      _NotificationCatalogText[1: Language = $session.system_language ].InspSpecAdditionalCatalogText,

      @Consumption.hidden: true
      @UI.hidden: true
      I_InspectionCode.CodeIsInactive,
      _InspectionCodeGroupText,
      I_InspectionCode._InspectionCodeGroup,
      _InspectionCatalog,
      _NotificationCatalogText

}
where
      I_InspectionCode.CodeIsInactive                           = ''
  and I_InspectionCode._InspectionCodeGroup.CodeGroupStatus     = '2' // Released

  and I_InspectionCode._InspectionCodeGroup.CodeGroupIsInactive = ''