C_MaintNotifRootCauseItem

DDL: C_MAINTNOTIFROOTCAUSEITEM SQL: CMNTNTFROOTIT Type: view CONSUMPTION

Root Cause Item

C_MaintNotifRootCauseItem is a Consumption CDS View that provides data about "Root Cause Item" in SAP S/4HANA. It reads from 1 data source (I_MaintNotifCauseTechObj) and exposes 21 fields with key fields MaintenanceNotificationItem, MaintenanceNotification. It has 1 association to related views.

1 data source(s) 21 fields

Data Sources (1)

SourceAliasJoin Type
I_MaintNotifCauseTechObj I_MaintNotifCauseTechObj from

Associations (1)

CardinalityTargetAliasCondition
[0..1] P_MaintNotifRootCauseActivity _MaintNotifRootCauseActivity $projection.MaintenanceNotificationItem = _MaintNotifRootCauseActivity.MaintenanceNotificationItem and $projection.MaintenanceNotification = _MaintNotifRootCauseActivity.MaintenanceNotification

Annotations (8)

NameValueLevelField
AbapCatalog.sqlViewName CMNTNTFROOTIT view
AccessControl.authorizationCheck #CHECK view
EndUserText.label Root Cause Item view
VDM.viewType #CONSUMPTION view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view

Fields (21)

KeyFieldSource TableSource FieldDescription
KEY MaintenanceNotificationItem I_MaintNotifCauseTechObj MaintenanceNotificationItem
KEY MaintenanceNotification I_MaintNotifCauseTechObj MaintenanceNotification
MaintNotifItemText
MaintNotifObjPrtCode
MaintNotifObjPrtCodeName
MaintNotificationDamageCode
MaintNotifDamageCodeName
MaintNotificationCauseCode
MaintNotificationCauseCodeName
MaintNotificationActivityCode
MaintNotifActivityCodeName
IsDeleted I_MaintNotifCauseTechObj IsDeleted
CreationDate I_MaintNotifCauseTechObj CreationDate
TimeOfCreation I_MaintNotifCauseTechObj TimeOfCreation
TechnicalObject
TechObjIsEquipOrFuncnlLoc
_MaintenanceNotificationItem I_MaintNotifCauseTechObj _MaintenanceNotificationItem
_MaintNotificationTechObj I_MaintNotifCauseTechObj _MaintNotificationTechObj
_MaintenanceNotification I_MaintNotifCauseTechObj _MaintenanceNotification
_TechnicalObject
_TechObjIsEquipOrFuncnlLoc 
@AbapCatalog.sqlViewName: 'CMNTNTFROOTIT'
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Root Cause Item'

@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL


@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA') 

define view C_MaintNotifRootCauseItem

  as select from I_MaintNotifCauseTechObj
  association [0..1] to P_MaintNotifRootCauseActivity as _MaintNotifRootCauseActivity on  $projection.MaintenanceNotificationItem = _MaintNotifRootCauseActivity.MaintenanceNotificationItem
                                                                                      and $projection.MaintenanceNotification     = _MaintNotifRootCauseActivity.MaintenanceNotification
{


  key I_MaintNotifCauseTechObj.MaintenanceNotificationItem,
      @UI.lineItem: { position: 60, importance: #MEDIUM }
  key I_MaintNotifCauseTechObj.MaintenanceNotification,


      @UI.lineItem: { position: 20, importance: #HIGH }
      I_MaintNotifCauseTechObj._MaintenanceNotificationItem.MaintNotifItemText,


      // Object Part

      @UI.lineItem: { position: 10, importance: #HIGH }
      @ObjectModel.text.element:  [ 'MaintNotifObjPrtCodeName' ]
      cast( I_MaintNotifCauseTechObj._MaintenanceNotificationItem._MaintNotifObjPrtCode.InspectionCode  as eam_object_part_code )                                                                                                                         as MaintNotifObjPrtCode,
      @Semantics.text: true
      I_MaintNotifCauseTechObj._MaintenanceNotificationItem._MaintNotifObjPrtCode._Text[1: Language = $session.system_language ].InspectionCodeText                                                                                                       as MaintNotifObjPrtCodeName,

      // Damage

      @UI.lineItem: { position: 30, importance: #HIGH }
      @ObjectModel.text.element:  [ 'MaintNotifDamageCodeName' ]
      cast( I_MaintNotifCauseTechObj._MaintenanceNotificationItem._MaintNotificationDamageCode.InspectionCode   as eam_damage_code )                                                                                                                      as MaintNotificationDamageCode,
      @Semantics.text: true
      I_MaintNotifCauseTechObj._MaintenanceNotificationItem._MaintNotificationDamageCode._Text[1: Language = $session.system_language ].InspectionCodeText                                                                                                as MaintNotifDamageCodeName,



      // Root Cause

      @UI.lineItem: { position: 40, importance: #MEDIUM }
      @ObjectModel.text.element:  [ 'MaintNotificationCauseCodeName' ]
      cast( I_MaintNotifCauseTechObj.MaintNotificationCauseCode  as eam_cause_code )                                                                                                                                                                      as MaintNotificationCauseCode,
      @Semantics.text: true
      I_MaintNotifCauseTechObj._MaintNotificationCauseCode._Text[1: Language = $session.system_language ].InspectionCodeText
                                                                                                                                                                                                                                                          as MaintNotificationCauseCodeName,

      @UI.lineItem: { position: 50, importance: #MEDIUM }
      @ObjectModel.text.element:  [ 'MaintNotifActivityCodeName' ]
      cast( _MaintNotifRootCauseActivity._MaintNotificationActivity .MaintNotificationActivityCode as eam_activity_code )                                                                                                                                 as MaintNotificationActivityCode,
      @Semantics.text: true
      _MaintNotifRootCauseActivity._MaintNotificationActivity ._MaintNotificationActivityCode._Text[1: Language = $session.system_language ].InspectionCodeText                                                                                           as MaintNotifActivityCodeName,


      @UI.hidden: true
      I_MaintNotifCauseTechObj.IsDeleted,
      @UI.hidden: true
      I_MaintNotifCauseTechObj.CreationDate,

      @UI.hidden: true
      I_MaintNotifCauseTechObj.TimeOfCreation,



      I_MaintNotifCauseTechObj._MaintNotificationTechObj.TechnicalObject,
      I_MaintNotifCauseTechObj._MaintNotificationTechObj.TechObjIsEquipOrFuncnlLoc,

      I_MaintNotifCauseTechObj._MaintenanceNotificationItem,
      I_MaintNotifCauseTechObj._MaintNotificationTechObj,
      I_MaintNotifCauseTechObj._MaintenanceNotification,
      I_MaintNotifCauseTechObj._MaintNotificationTechObj._TechnicalObject,
      I_MaintNotifCauseTechObj._MaintNotificationTechObj._TechObjIsEquipOrFuncnlLoc


}
where
      I_MaintNotifCauseTechObj.IsDeleted != 'X'
  and I_MaintNotifCauseTechObj.MaintNotificationRootCause = '2'

Learn More