C_MaintNotifActivityTP

@EndUserText.label: 'Maintenance Notification Activity'

@VDM.viewType: #CONSUMPTION
@AccessControl.authorizationCheck: #CHECK
@AbapCatalog.sqlViewName: 'CNOTIFACTVTP'

@ObjectModel.transactionalProcessingDelegated:true

@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.deleteEnabled: true

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #A
@ObjectModel.usageType.sizeCategory: #XL

@ObjectModel: {
  representativeKey : 'MaintNotificationActivity',
  semanticKey: [ 'MaintNotificationActivity', 'MaintenanceNotification']
}

@AccessControl.privilegedAssociations: ['_MaintNotifActivityCodeText', '_MaintNotifActivityCodeGroupT']

define view C_MaintNotifActivityTP
  as select from I_MaintNotifActivityTP
  association [1..1] to C_MaintNotificationTP     as _MaintNotificationTP          on  _MaintNotificationTP.MaintenanceNotification = $projection.MaintenanceNotification
  association [0..*] to I_InspectionCodeText      as _MaintNotifActivityCodeText   on  $projection.MaintNotificationActivityCode = _MaintNotifActivityCodeText.InspectionCode
                                                                                   and $projection.MaintNotifActivityCodeCatalog = _MaintNotifActivityCodeText.InspectionCatalog
                                                                                   and $projection.MaintNotifActivityCodeGroup   = _MaintNotifActivityCodeText.InspectionCodeGroup
  association [0..*] to I_Inspectioncodegrouptext as _MaintNotifActivityCodeGroupT on  $projection.MaintNotifActivityCodeCatalog = _MaintNotifActivityCodeGroupT.InspectionCatalog
                                                                                   and $projection.MaintNotifActivityCodeGroup   = _MaintNotifActivityCodeGroupT.InspectionCodeGroup
{

  key I_MaintNotifActivityTP.MaintNotificationActivity,
      @ObjectModel.foreignKey.association: '_MaintNotificationTP'
  key I_MaintNotifActivityTP.MaintenanceNotification,

      I_MaintNotifActivityTP.MaintenanceNotificationItem,
      I_MaintNotifActivityTP.MaintNotifActivityForEdit,

      I_MaintNotifActivityTP.MaintNotifActyTxt,
      I_MaintNotifActivityTP.MaintNotifActivityCodeCatalog,
      //--[ GENERATED:012:GFBfhxvv7jY4hOWGDORKHm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_InspectionCodeStdVH',
                     element: 'InspectionCode' },
          additionalBinding: [{ localElement: 'MaintNotifActivityCodeCatalog',
                                element: 'InspectionCatalog' },
                              { localElement: 'MaintNotifActivityCodeGroup',
                                element: 'InspectionCodeGroup' }]
        }]
      // ]--GENERATED

      @ObjectModel.text.association: '_MaintNotifActivityCodeText'
      I_MaintNotifActivityTP.MaintNotificationActivityCode,
      //--[ GENERATED:012:GFBfhxvv7jY4hOWGDORKHm

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_InspectionCodeGroupStdVH',
                     element: 'InspectionCodeGroup' },
          additionalBinding: [{ localElement: 'MaintNotifActivityCodeCatalog',
                                element: 'InspectionCatalog' }]
        }]
      // ]--GENERATED

      @ObjectModel.text.association: '_MaintNotifActivityCodeGroupT'
      I_MaintNotifActivityTP.MaintNotifActivityCodeGroup,
      I_MaintNotifActivityTP.IsDeleted,
      I_MaintNotifActivityTP.CreatedByUser,
      I_MaintNotifActivityTP.PlannedStartDate,
      I_MaintNotifActivityTP.PlannedStartTime,
      I_MaintNotifActivityTP.MaintNotifActyQtyFactor,
      I_MaintNotifActivityTP.PlannedEndDate,
      I_MaintNotifActivityTP.PlannedEndTime,

      I_MaintNotifActivityTP.MaintNotifActivitySortNumber,

      /* Associations */
      I_MaintNotifActivityTP._IsDeleted,
      I_MaintNotifActivityTP._MaintenanceNotification,
      I_MaintNotifActivityTP._MaintenanceNotificationItem,

      I_MaintNotifActivityTP._MaintNotifActivityCodeCatalog,
      I_MaintNotifActivityTP._MaintNotifActivityCodeGroup,
      I_MaintNotifActivityTP._MaintNotificationActivityCode,

      @ObjectModel.association.type: [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _MaintNotificationTP,
      _MaintNotifActivityCodeGroupT,
      _MaintNotifActivityCodeText
}
where
  I_MaintNotifActivityTP.IsDeleted != 'X'