C_MaintItemObjPgObjectList

@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AbapCatalog.sqlViewName: 'CMNTITMOPOBJLIST'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: [ '_TechnicalObjQuickVw', '_ServiceProduct' ]
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Object List for the Maintenance Item Object Page'
@Metadata.allowExtensions: true
@ObjectModel: {
    usageType: {
        dataClass: #TRANSACTIONAL,
        serviceQuality: #C,
        sizeCategory: #XL
    }
}
@VDM.viewType: #CONSUMPTION


define view C_MaintItemObjPgObjectList
  as select from I_MaintenanceItemObject

  association [0..1] to I_FunctionalLocationLabel   as _FunctionalLocationLabel   on  _FunctionalLocationLabel.FunctionalLocation = $projection.FunctionalLocation

  association [0..*] to I_FunctionalLocationText    as _FunctionalLocationText    on  _FunctionalLocationText.FunctionalLocation = $projection.FunctionalLocation

  association [0..*] to I_EquipmentText             as _EquipmentText             on  _EquipmentText.Equipment = $projection.Equipment

  association [0..1] to I_TechObjIsEquipOrFuncnlLoc as _TechObjIsEquipOrFuncnlLoc on  _TechObjIsEquipOrFuncnlLoc.TechObjIsEquipOrFuncnlLoc = $projection.TechObjIsEquipOrFuncnlLoc

  association [0..1] to C_TechObjQuickVw            as _TechnicalObjQuickVw       on  _TechnicalObjQuickVw.TechnicalObject           = $projection.TechnicalObject
                                                                                  and _TechnicalObjQuickVw.TechObjIsEquipOrFuncnlLoc = $projection.TechObjIsEquipOrFuncnlLoc
                                                                                  and _TechnicalObjQuickVw.TechnicalObjectLabel      = $projection.TechnicalObjectLabel

  association [0..1] to C_EAMProductQuickVw         as _ServiceProduct            on  $projection.Product = _ServiceProduct.Material
{
  key MaintenanceItemObjectList,

  key MaintenanceItemObject,

      @Consumption.hidden: true
      Equipment,

      @Consumption.hidden: true
      _EquipmentText[1:Language = $session.system_language].EquipmentName,

      @Consumption.hidden: true
      FunctionalLocation,

      @Consumption.hidden: true
      _FunctionalLocationLabel._FuncLocationLabelSearch.FunctionalLocationLabelName,

      @Consumption.hidden: true
      _FunctionalLocationText[1:Language = $session.system_language].FunctionalLocationName,

      @EndUserText.label: 'Technical Object Type'
      @ObjectModel.foreignKey.association: '_TechObjIsEquipOrFuncnlLoc'
      @UI.textArrangement: #TEXT_ONLY
      cast(
        case
            when Equipment <> '' then 'EAMS_EQUI'
            else
                case
                    when FunctionalLocation <> '' then 'EAMS_FL'
                    else ''
                end
        end
      as eams_tec_obj_type_value )                                      as TechObjIsEquipOrFuncnlLoc,

      cast(
        case
            when Equipment <> '' then Equipment
            else FunctionalLocation
        end
      as eams_tec_obj )                                                 as TechnicalObject,

      @Consumption.semanticObject: 'MaintenanceObject'
      @Consumption.valueHelp: '_TechnicalObjectLabelVH'
      @EndUserText.label: 'Technical Object'
      @ObjectModel.text.element: ['TechnicalObjectDescription']
      @ObjectModel: { foreignKey.association: '_TechnicalObjQuickVw', mandatory: true}
      cast(
        case
            when Equipment <> '' then Equipment
            else
                case
                    when FunctionalLocation <> '' then _FunctionalLocationLabel.FunctionalLocationLabelName
                    else ''
                end
        end as eams_tech_obj_conv )                                     as TechnicalObjectLabel,

      @Semantics.text: true
      cast(
        case
            when Equipment <> '' then _EquipmentText[1:Language = $session.system_language].EquipmentName
            else
                case
                    when FunctionalLocation <> '' then _FunctionalLocationText[1:Language = $session.system_language].FunctionalLocationName
                    else ''
                end
        end
      as eams_tec_obj_des )                                             as TechnicalObjectDescription,

      @Consumption.semanticObject: 'Material'
      @EndUserText.label:'Assembly'
      Assembly,

      @Consumption.semanticObject: 'Material'
      Material,

      SerialNumber,

      SortField,

      @ObjectModel.readOnly: true
      @EndUserText.label: 'Product Name'
      _Product._Text[1:Language = $session.system_language].ProductName as ProductName,

      @ObjectModel.text.element: [ 'ProductName' ]
      @Consumption.semanticObject: 'Material'
      @ObjectModel: { foreignKey.association: '_ServiceProduct', mandatory: true}
      @EndUserText.label: 'Product'
      Product,

      /* Associations */
      @Consumption.filter.hidden: true
      _Assembly,

      @Consumption.filter.hidden: true
      _Material,

      @Consumption.filter.hidden: true
      _ServiceProduct,

      @Consumption.filter.hidden: true
      _TechObjIsEquipOrFuncnlLoc,

      @Consumption.filter.hidden: true
      _TechnicalObjQuickVw,

      /* Associations - DCL */
      @Consumption.filter.hidden: true
      _MaintenanceItem
}