C_LglCntntMDocImportantCat

@AbapCatalog.sqlViewName: 'CLEGALDOCIMPCAT'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@ObjectModel: {
  representativeKey: 'LglCntntMDocumentUUID',
  usageType.serviceQuality: #C,
  usageType.sizeCategory: #L,
  usageType.dataClass: #TRANSACTIONAL
}

@EndUserText.label: 'Documents with Important Category'

define view C_LglCntntMDocImportantCat
  as select from I_LglCntntMDocCategory as DocCategory
    inner join   I_LglCntntMCategory    as Category on  DocCategory.LglCntntMCategory        = Category.LglCntntMCategory
                                                    and (
                                                       Category.LglCntntMCatConstant         = 'SAP_CM_LABEL_IMP_YES'
                                                       or Category.LglCntntMCatConstant      = 'SAP_CM_LABEL_IMP_NO'
                                                     )
                                                    and Category.LglCntntMCatIsSystGenerated = 'X'
                                                    and Category.LglCntntMCatIsObsolete      = ''

{
  key  DocCategory.LglCntntMDocumentUUID                 as LglCntntMDocumentUUID,

       DocCategory.LglCntntMCategory                     as LglCntntMCategory,

       Category.LglCntntMCatConstant                     as LglCntntMCatConstant,

       cast ( case Category.LglCntntMCatConstant
              when 'SAP_CM_LABEL_IMP_YES' then 'Y'
              when 'SAP_CM_LABEL_IMP_NO' then 'N'
              else ' '
              end as lcm_doc_important preserving type ) as LglCntntMDocImportant,

       // For Authorization

       DocCategory._DocumentAuth

}