C_LegalTrLinkedObjectsTP

@AbapCatalog.sqlViewName: 'CLGLTRLINKOBJTP'
@AccessControl.authorizationCheck: #CHECK
@ClientHandling.algorithm: #SESSION_VARIABLE

@EndUserText.label: 'Legal Transaction Linked Objects'

@VDM.viewType: #CONSUMPTION

@ObjectModel: {
                semanticKey: 'LegalTransactionLinkdObjUUID',
                representativeKey: 'LegalTransactionLinkdObjUUID',

                transactionalProcessingDelegated: true,

                createEnabled: true,
                updateEnabled: true,
                deleteEnabled: 'EXTERNAL_CALCULATION',

                usageType.dataClass: #MIXED,
                usageType.serviceQuality:  #C,
                usageType.sizeCategory: #L,

                delegatedAction: [
                                    // Action that are called directly in UI using breakouts

                                  { name: 'DETERMINE_URL_FOR_EXT_LNKD_OBJ',        exposureName: 'DetermineURLForExtLinkdObj'      }
                                 ]

              }

//@Metadata.ignorePropagatedAnnotations: true


@UI.headerInfo:{
  typeName: 'Linked Object',
  typeNamePlural: 'Linked Objects',
  title: { value: 'LglCntntMLinkdObj' },
  description: { value: 'LglCntntMLinkdObjTypeName' }
}
@UI:
{
  presentationVariant:
  {
    requestAtLeast: ['LegalTransactionUUID']
    }
}
@Search.searchable: true

define view C_LegalTrLinkedObjectsTP
  as select from I_LegalTrLinkedObjectsTP as LinkedObject
  association [1..1] to C_LegalTransactionTP           as _LegalTransactionTP        on  $projection.LegalTransactionUUID = _LegalTransactionTP.LegalTransactionUUID
  //Value Helps

  association [0..1] to C_LCMLinkedObjectTypeValueHelp as _LinkedObjectTypeValueHelp on  $projection.LglCntntMLinkdObjType = _LinkedObjectTypeValueHelp.LglCntntMLinkdObjType
  association [0..1] to C_LglCntntMLinkedObjVH         as _LglCntntMLinkedObjVH      on  $projection.LglCntntMLinkdObj     = _LglCntntMLinkedObjVH.LglCntntMLinkdObj
                                                                                     and $projection.LglCntntMLinkdObjType = _LglCntntMLinkedObjVH.LglCntntMLinkdObjType

{
      @UI.facet: [
              { label:'General Information',
                 id:'GeneralInformation',
                 type: #COLLECTION,
                 isSummary,
                 position: 10
               },
                 {
                   label: 'General Information',
                   id: 'MyInbox_BasicData',
                   parentId: 'GeneralInformation',
                   type: #FIELDGROUP_REFERENCE,
                   position: 10,
                   targetQualifier: 'MyInbox_BasicData'
                 } ]


      @UI.hidden : true
  key LinkedObject.LegalTransactionLinkdObjUUID,

      @UI: {
            identification:{position: 10, importance: #HIGH },
            lineItem: [{position: 10, importance: #HIGH },
            {qualifier: 'MyInbox', position: 10, importance: #HIGH, label: 'Linked Object Type' }],
            textArrangement: #TEXT_ONLY
           }
      @UI.fieldGroup: [{qualifier: 'MyInbox_BasicData', groupLabel : 'Basic Data', position: 10}]
      @ObjectModel.text.element: 'LglCntntMLinkdObjTypeName'
      @Consumption.valueHelp: '_LinkedObjectTypeValueHelp'
      @Semantics.text: true
      @EndUserText.label: 'Linked Object Type'
      @ObjectModel.mandatory: true
      @ObjectModel.readOnly: 'EXTERNAL_CALCULATION'
      LinkedObject.LglCntntMLinkdObjType,

      @UI.hidden: true
      @ObjectModel.readOnly: true
      @Semantics.text: true
      _LinkedObjectTypeValueHelp.LglCntntMLinkdObjTypeName     as LglCntntMLinkdObjTypeName,

      @UI: {
      //            identification:{position: 20, importance: #HIGH, label: 'Object ID'}

                  lineItem: {qualifier: 'MyInbox',position: 20, importance: #HIGH, label: 'Linked Object'}
           }
      @UI.fieldGroup: [{qualifier: 'MyInbox_BasicData', groupLabel : 'Basic Data', position: 20}]

      //      @Consumption.semanticObject: 'LglCntntMLinkdObj'

      @UI.textArrangement: #TEXT_FIRST
      @EndUserText.label: 'Linked Object'
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
      @Consumption.valueHelp: '_LglCntntMLinkedObjVH'
      @ObjectModel.text.element: ['LglCntntMLinkdObjName']
      LinkedObject.LglCntntMLinkdObj,

      @ObjectModel.readOnly: true
      @Semantics.text: true
      @EndUserText.label: 'Linked Object Description'
      @UI: {  identification: {position: 25, importance: #HIGH } }
      @Consumption.filter.hidden: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'CL_LCM_LINKEDOBJ_DESCR'
      @UI.hidden: true
      cast ('' as lcm_linkedobject_name )                      as LglCntntMLinkdObjName,

      @UI.hidden: true
      @ObjectModel.readOnly : true
      _LinkedObjectTypeValueHelp.LglCntntMLinkdObjTechType,

      @UI.hidden: true
      //      @ObjectModel.readOnly: true

      _LinkedObjectTypeValueHelp.LglCntntMLinkdObjTechCat      as LglCntntMLinkdObjTechCat,

      @UI.hidden: true
      @ObjectModel.readOnly: true
      _LinkedObjectTypeValueHelp.LglCntntMSemanticObject       as LglCntntMSemanticObject,

      @UI.hidden: true
      @ObjectModel.readOnly: true
      _LinkedObjectTypeValueHelp.LglCntntMSemanticObjectAttrib as LglCntntMSemanticObjectAttrib,

      @UI.hidden: true
      @ObjectModel.readOnly: true
      _LinkedObjectTypeValueHelp.LglCntntMIntentAction         as LglCntntMIntentAction,

      @UI: {
            identification:{position: 30, importance: #HIGH, label: 'Required'},
            lineItem: [{position: 30, importance: #HIGH, label: 'Required'}]
           }
      @ObjectModel.mandatory: true
      @ObjectModel.readOnly: true
      @EndUserText.label: 'Required'
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'CL_LCM_LT_REQUIRED_FLAG_EXIT'
      @Semantics.booleanIndicator: true
      ''                                                       as LglCntntMIsMandatory,
      //      cast( I_LegalTrLinkedObjectsTP.LegalTransactionMandatoryFlag as lcm_lt_mandatory_ctrl_to_bool preserving type ) as LglCntntMIsMandatory,


      @ObjectModel.readOnly: true
      LinkedObject.LegalTransactionMandatoryFlag,

      //      @UI.hidden: true

      @UI: {
              identification:{position: 40, importance: #HIGH, label: 'Integrated'},
              lineItem: {position: 40, importance: #HIGH, label: 'Integrated'}
           }
      @ObjectModel.readOnly: true
      @EndUserText.label: 'Integrated'
      @Feature: 'BF:LCM_BOINTEGRATION'
      LinkedObject.LglCntntMIsIntegRelevant                    as LglCntntMIsIntegRelevant,


      @UI: {
              identification:{position: 50, importance: #HIGH},
              lineItem: {position: 50, importance: #HIGH}
           }
      @ObjectModel.readOnly: true
      LinkedObject.LegalTransactionIsTriggerObj                as LegalTransactionIsTriggerObj,

      @UI.hidden : true
      @ObjectModel.readOnly: true
      LinkedObject.LegalTransactionUUID,

      @UI.hidden : true
      @ObjectModel.readOnly: true
      _LegalTransaction.LegalTransaction,

//      @UI.hidden: true

//      @ObjectModel.readOnly: true

//      _LegalTransactionTP.LglCntntMProfile,


      @ObjectModel.readOnly: true
      @Semantics.text: true
      @Consumption.filter.hidden: true
      @ObjectModel.virtualElement: true
      @ObjectModel.virtualElementCalculatedBy: 'CL_LCM_COMMON_CALC_EXIT'
      @UI.hidden: true
      cast ('' as is_cloud_system )                            as IsCloudSystem,


      @ObjectModel.association.type:  [ #TO_COMPOSITION_PARENT, #TO_COMPOSITION_ROOT ]
      _LegalTransactionTP,

      _LegalTransaction,

      _LinkedObjectTypeValueHelp,

      _LglCntntMLinkedObjVH



}