C_LCMUserValueHelp

@AbapCatalog.sqlViewName: 'CLCMUSRVH'
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@AccessControl.personalData.blocking: #NOT_REQUIRED
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:  [ '_LglCntntMUser' ]

@ObjectModel.semanticKey: [ 'UserID' ]

@ObjectModel.representativeKey: 'UserID'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #L
@ObjectModel.usageType.dataClass: #MASTER
//@ObjectModel.dataCategory: #VALUE_HELP

@EndUserText.label: 'LCM User Value Help'
@AbapCatalog.dbHints: [{dbSystem: #HDB, hint:'NO_RECOMPILE_WITH_SQL_PARAMETERS' }]

define view C_LCMUserValueHelp
 as select distinct from I_LglCntntMUserValueHelp as _UserVH 
{

      @ObjectModel.text.element:  [ 'FullName' ]
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7  }
      @UI.selectionField.position: 10
      @UI.lineItem.position: 10
      @EndUserText.label: 'User ID'
  key UserID,

      @Semantics.text: true
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
      @UI.selectionField.position: 15
      @UI.lineItem.position: 15
      FirstName,

      @Semantics.text: true
      @Search: { defaultSearchElement: true, ranking: #HIGH, fuzzinessThreshold: 0.7 }
      @UI.selectionField.position: 20
      @UI.lineItem.position: 20
      LastName,

      @Semantics.text: true
      @ObjectModel.readOnly: true
      @UI.hidden: true
      @EndUserText.label: 'Full Name'
      FullName,

      @ObjectModel.readOnly: true
      @EndUserText.label: 'Email'
      @Search: { defaultSearchElement: true, ranking: #HIGH}
      @UI.selectionField.position: 25
      @UI.lineItem.position: 25
      EmailAddress,

      @ObjectModel.readOnly: true
      @EndUserText.label: 'Department'
      @Search: { defaultSearchElement: true, ranking: #HIGH}
      @UI.selectionField.position: 30
      @UI.lineItem.position: 30
      Department,
      
      _LglCntntMUser


}