C_IntrastatSCByLanguage

@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CISSRVCCDBYLANG'
@AbapCatalog.preserveKey:true
@EndUserText.label: 'Intrastat Service Code by Given Language'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:  [ '_CreatedByUser' , '_LastChangedByUser' ]
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions: true
@ObjectModel.semanticKey: ['IntrastatServiceCode']

// enable entity set CRUD operation

@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.deleteEnabled: true

@ObjectModel.usageType.sizeCategory: 'L'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED

@Search.searchable: true
define view C_IntrastatSCByLanguage
  as select from I_IntrastatServiceCode  as IntrastatServiceCode
    cross join   I_Language      as _Language
  association [0..1] to I_TrdClassfctnNmbrOfclDescByLa as _OfficialDescOnLanguage on  _OfficialDescOnLanguage.TrdClassfctnNmbrSchmCntnt = $projection.TrdClassfctnNmbrSchmCntnt
                                                                                  and _OfficialDescOnLanguage.TrdClassfctnNmbr          = $projection.IntrastatServiceCode
                                                                                  and _OfficialDescOnLanguage.ValidityStartDate         = $projection.ValidityStartDate
                                                                                  and _OfficialDescOnLanguage.Language                  = _Language.Language
  association [0..1] to I_TrdClassfctnNmbrCoDescByLa  as _CnctntdDescOnLanguage  on  _CnctntdDescOnLanguage.TrdClassfctnNmbrSchmCntnt = $projection.TrdClassfctnNmbrSchmCntnt
                                                                                  and _CnctntdDescOnLanguage.TrdClassfctnNmbr          = $projection.IntrastatServiceCode
                                                                                  and _CnctntdDescOnLanguage.ValidityStartDate         = $projection.ValidityStartDate
                                                                                  and _CnctntdDescOnLanguage.Language                  = _Language.Language
{
      @ObjectModel.text.control: #('ASSOCIATED_TEXT_UI_HIDDEN')
      @Consumption.filter.hidden: true
      @Semantics.language: false
  key _Language.Language,
      @Consumption.valueHelpDefinition: [{
        entity: { 
          name: 'I_IntrastatSrvcNmbrSchmCntntVH',
          element: 'TrdClassfctnNmbrSchmCntnt' 
      } }]
      @Consumption.filter: { mandatory : true, selectionType : #SINGLE, multipleSelections : false }
  key IntrastatServiceCode.TrdClassfctnNmbrSchmCntnt,
      @Consumption.semanticObject: 'IntrastatServiceCode'
      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.8
      }
  key IntrastatServiceCode,
  key IntrastatServiceCode.ValidityStartDate,
      IntrastatServiceCode.ValidityEndDate,
      @ObjectModel.text.association: '_OfficialDescOnLanguage'
      @Consumption.filter.hidden: true
      TrdClassfctnNmbrForOfclDesc,
      @ObjectModel.text.association: '_CnctntdDescOnLanguage'
      @Consumption.filter.hidden: true
      TrdClassfctnNmbrForCnctntdDesc,
      CreatedByUser,
      @ObjectModel.readOnly: true
      @Consumption.filter.hidden: true
      CreationDateTime,
      @ObjectModel.readOnly: true
      LastChangedByUser,
      @ObjectModel.readOnly: true
      @Consumption.filter.hidden: true
      LastChangeDateTime,

      @ObjectModel.filter.enabled: false
      _OfficialDescOnLanguage,
      @ObjectModel.filter.enabled: false
      _CnctntdDescOnLanguage,
      @Consumption.hidden: true
      _OfficialDesc,
      @Consumption.hidden: true
      _CnctntdDesc,
      @Consumption.filter.hidden: true
      _CreatedByUser,
      @Consumption.filter.hidden: true
      _LastChangedByUser
}