C_Insplot_Object

@AbapCatalog.sqlViewName: 'CINSPLOTOBJECT'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:  [ '_BusinessCardInfo'  ,  '_ChangedByBusinessCardInfo'  ]
@AccessControl.personalData.blocking: #REQUIRED
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Inspection Lot Object Page'
@Search.searchable: true
@ObjectModel.usageType: {
    dataClass: #MIXED,
    sizeCategory: #L, //expected number of rows < 10.000.000

    serviceQuality: #D
}

define view C_Insplot_Object
  as select from    I_InspectionLot           as _InspLot
  //Get description of inspection lot type

    left outer join I_InspectionLotTypeText   as _InspLotText             on  _InspLot.InspectionLotType = _InspLotText.InspectionLotType
                                                                          and _InspLotText.Language      = $session.system_language
  //Get description of origin

    left outer join I_InspectionLotOriginText as _InspectionLotOriginText on  _InspLot.InspectionLotOrigin      = _InspectionLotOriginText.InspectionLotOrigin
                                                                          and _InspectionLotOriginText.Language = $session.system_language
  //Get description of MPN material

  // left outer join I_MaterialText            as _MaterialText                  on  _InspLot.ManufacturerPartNmbr    = _MaterialText.Material

  //                                                                            and _MaterialText.Language           = $session.system_language

  //Get maintenance plan information

    left outer join I_MaintenancePlanBasic    as _MaintenancePlan         on _InspLot.MaintenancePlan = _MaintenancePlan.MaintenancePlan
  //Get maintenance plan item information

  //  left outer join I_MaintenanceItem as _MaintenanceItem                       on _InspLot.MaintenancePlanItemIntID = _MaintenanceItem.MaintenanceItem

  //Get description of maintenance strategy

    left outer join I_MaintenanceStrategyT    as _MaintenanceStrategyT    on  _InspLot.MaintenanceStrategy   = _MaintenanceStrategyT.MaintenanceStrategy
                                                                          and _MaintenanceStrategyT.Language = $session.system_language
  //Operation tab

  association [1..*] to C_Inspoperation_Object   as _Operation                 on  $projection.InspectionLot = _Operation.InspectionLot
  //Header Status

  association [1..*] to C_InspLotStatus          as _InspLotStatus             on  $projection.InspectionLot = _InspLotStatus.InspectionLot
  //Get description of customer

  association [0..1] to I_Customer               as _Customer                  on  $projection.Customer = _Customer.Customer
  //Get description of Supplier

  association [0..1] to I_Supplier               as _Supplier                  on  $projection.Supplier = _Supplier.Supplier
  //Get description of manufacturer

  association [0..1] to I_Supplier               as _Manufacturer              on  $projection.Manufacturer = _Manufacturer.Supplier
  //Get description of purchasing organization

  association [1..1] to I_PurchasingOrganization as _PurchasingOrganization    on  $projection.PurchasingOrganization = _PurchasingOrganization.PurchasingOrganization
  //Get description of production version

  association [1..1] to I_ProductionVersion      as _ProductionVersion         on  $projection.Material          = _ProductionVersion.Material
                                                                               and $projection.Plant             = _ProductionVersion.Plant
                                                                               and $projection.ProductionVersion = _ProductionVersion.ProductionVersion
  //Stock Posting tab

  association [0..*] to C_InspLotStockPosting    as _InspLotStockPosting       on  $projection.InspectionLot = _InspLotStockPosting.InspectionLot
  //Get detail information of BusinessCard

  //  association [1..*] to C_BusinessCardInfo        as _BusinessCardInfo        on  $projection.InspectionLotCreatedBy        = _BusinessCardInfo.UserID

  //                                                                              or  $projection.InspectionLotChangedBy        = _BusinessCardInfo.UserID

  //                                                                              or  $projection.inspectionlotusagedecidedby   = _BusinessCardInfo.UserID

  //                                                                              or  $projection.insplotusagedecisionchangedby = _BusinessCardInfo.UserID


  //Retrieve all BusinessCard information for Inspection Lot

  association [0..1] to I_UserContactCard        as _BusinessCardInfo          on  $projection.InspectionLotCreatedBy      = _BusinessCardInfo.ContactCardID
                                                                               or  $projection.inspectionlotusagedecidedby = _BusinessCardInfo.ContactCardID
  association [0..1] to I_UserContactCard        as _ChangedByBusinessCardInfo on  $projection.InspectionLotChangedBy        = _ChangedByBusinessCardInfo.ContactCardID
                                                                               or  $projection.insplotusagedecisionchangedby = _ChangedByBusinessCardInfo.ContactCardID
  //Document

  association [1..*] to C_InspLotDocument        as _InspLotDocument           on  $projection.InspectionLot = _InspLotDocument.LinkedSAPObjectKey

  //changed from inner to assosication POC

  association [0..1] to I_MaterialText           as _MaterialText              on  _InspLot.Material      = _MaterialText.Material
                                                                               and _MaterialText.Language = $session.system_language

{
  key _InspLot.InspectionLot,
      _InspLot.InspectionLotType,
      _InspLotText.InspectionLotTypeText,
      _InspLot.Material,
      _InspLot.InspectionLotObjectText, //Description of material

      _InspLot.InspectionLotText,
      _InspLot.InspectionLotQuantity,
      _InspLot._InspectionLotQuantityUnit._Text[1:Language=$session.system_language].UnitOfMeasure_E as InspectionLotQuantityUnit,
      _InspLot.Plant,
      _InspLot._Plant.PlantName,
      _InspLot.MaterialIsBatchManaged,
      _InspLot.Batch,
      _InspLot.BatchBySupplier, //Vendor Batch

      _InspLot.InspectionLotStartDate,
      _InspLot.InspectionLotEndDate,
      _InspLot.MatlQualityAuthorizationGroup,

      //General information tab

      _InspLot.BillOfOperationsType,
      _InspLot.BillOfOperationsGroup,
      _InspLot.BillOfOperationsVariant,
      _InspLot.BillOfOperationsChangeStateID,
      _InspLot._BillOfOperationsChangeState.BillOfOperationsDesc,
      _InspLot._BillOfOperationsType._Text[1:Language=$session.system_language].BillOfOperationsTypeName,
      _InspLot.QualityCostCollector,
      @Feature:'SW:EAM_SFWS_CHECKLIST'
      _InspLot.Equipment,
      @Feature:'SW:EAM_SFWS_CHECKLIST'
      _InspLot._Equipment._EquipmentText[1:Language=$session.system_language].EquipmentName,
      @Feature:'SW:EAM_SFWS_CHECKLIST'
      _InspLot.FunctionalLocation,
      @Feature:'SW:EAM_SFWS_CHECKLIST'
      _InspLot._FunctionalLocation._FunctionalLocationText[1:Language=$session.system_language].FunctionalLocationName,
      
      

      //Administrative Data tab--Inspection Lot

      _InspLot.InspLotCreatedOnLocalDate,
      _InspLot.InspLotCreatedOnLocalTime,
      _InspLot.InspectionLotCreatedOnTime,
      _InspLot.InspectionLotCreatedOn,
      _InspLot.InspectionLotCreatedBy,
      _InspLot.InspectionLotChangeDate,
      _InspLot.InspectionLotChangeTime,
      _InspLot.InspectionLotChangedBy,

      //Usage Decision tab

      _InspLot._InspLotUsageDecision.InspLotUsageDecisionValuation,
      _InspLot._InspLotUsageDecision.InspectionLotUsageDecisionCode,
      _InspLot._InspLotUsageDecision.InspLotUsageDecisionCodeGroup,
      _InspLot._InspLotUsageDecision._UsageDecisionCode.UsageDecisionCodeText,
      _InspLot._InspLotUsageDecision.InspectionLotQualityScore,
      _InspLot._InspLotUsageDecision.InspLotUsgeDcsnFollowUpAction,

      //Administrative Data tab--Usage Decision

      _InspLot._InspLotUsageDecision.InspectionLotUsageDecidedOn,
      _InspLot._InspLotUsageDecision.InspLotUsageDecisionTime,
      _InspLot._InspLotUsageDecision.InspectionLotUsageDecidedBy,
      _InspLot._InspLotUsageDecision.InspLotUsageDecisionChangedBy,
      _InspLot._InspLotUsageDecision.InspLotUsageDecisionChangedOn,
      _InspLot._InspLotUsageDecision.InspLotUsgeDcsnChangedTime,

      //Origin tab---Quantities

      _InspLot.InspectionLotActualQuantity,
      _InspLot.InspectionLotSampleQuantity,
      _InspLot._InspectionLotSampleUnit._Text[1:Language=$session.system_language].UnitOfMeasure_E   as InspectionLotSampleUnit,
      _InspLot.InspLotQtyDestroyed,
      _InspLot.InspectionLotDefectiveQuantity,
      _InspLot.InspLotQtyToBePosted                                                                  as InspQtyPosted,

      //Origin tab--Origin

      _InspLot.InspectionLotOrigin,
      _InspectionLotOriginText.InspectionLotOriginText,

      //Display information of Origin type:2/6/10/11/12/15/89

      //--[ GENERATED:012:GlBfhyFV7kY4h7jYW0xcqG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_Customer_VH',
                     element: 'Customer' }
        }]
      // ]--GENERATED

      @ObjectModel.readOnly:'EXTERNAL_CALCULATED'
      _InspLot.Customer,
      _Customer.CustomerName, //Customer description


      //Display information of Origin type:1/5/7/15/17/89

      //--[ GENERATED:012:GlBfhyFV7kY4h7jYW0xcqG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_Supplier_VH',
                     element: 'Supplier' }
        }]
      // ]--GENERATED

      @ObjectModel.readOnly:'EXTERNAL_CALCULATED'
      _InspLot.Supplier, //Supplier

      _Supplier.SupplierName, //Vendor description


      //Display information of Origin type:1/7/15/89

      //--[ GENERATED:012:GlBfhyFV7kY4h7jYW0xcqG

      @Consumption.valueHelpDefinition: [
        { entity:  { name:    'I_Supplier_VH',
                     element: 'Supplier' }
        }]
      // ]--GENERATED

      @ObjectModel.readOnly:'EXTERNAL_CALCULATED'
      _InspLot.Manufacturer,
      _Manufacturer.SupplierName                                                                     as ManufacturerName, //Manufacturer description


      //Display information of Origin type:1

      @ObjectModel.readOnly:'EXTERNAL_CALCULATED'
      _InspLot.ManufacturerPartNmbr, //MPN material

      _MaterialText.MaterialName, //description of MPN material


      //Display information of Origin type:1/7/89

      @ObjectModel.readOnly:'EXTERNAL_CALCULATED'
      _InspLot.PurchasingOrganization,
      _PurchasingOrganization.PurchasingOrganizationName,

      //Display information of Origin type:1

      @ObjectModel.readOnly:'EXTERNAL_CALCULATED'
      _InspLot.PurchasingDocument,
      //If it has no value, set null

      case _InspLot.PurchasingDocumentItem
          when '00000' then ''
          else _InspLot.PurchasingDocumentItem
          end                                                                                        as PurchasingDocumentItem,

      //Display information of Origin type:1/2/4/5/8/9

      //If it has no value, set null

      case _InspLot.MaterialDocumentYear
          when '0000' then ''
          else _InspLot.MaterialDocumentYear
          end                                                                                        as MaterialDocumentYear,
      @ObjectModel.readOnly:'EXTERNAL_CALCULATED'
      _InspLot.MaterialDocument,
      //If it has no value, set null

      case _InspLot.MaterialDocumentItem
          when '0000' then ''
          else _InspLot.MaterialDocumentItem
          end                                                                                        as MaterialDocumentItem,

      //Display information of Origin type:11/12/17

      @ObjectModel.readOnly:'EXTERNAL_CALCULATED'
      _InspLot.DeliveryDocument,
      //If it has no value, set null

      case _InspLot.DeliveryDocumentItem
          when '000000'then''
          else _InspLot.DeliveryDocumentItem
          end                                                                                        as DeliveryDocumentItem,

      //Display information of Origin type:3/4/14/17

      @ObjectModel.readOnly:'EXTERNAL_CALCULATED'
      _InspLot.ManufacturingOrder, //Order


      //Display information of Origin type:13

      @ObjectModel.readOnly:'EXTERNAL_CALCULATED'
      _InspLot.ProductionVersion,
      _ProductionVersion.ProductionVersionText,

      //Display information of Origin type:6/10/12

      @ObjectModel.readOnly:'EXTERNAL_CALCULATED'
      _InspLot.SalesOrder,
      //If it has no value, set null

      case _InspLot.SalesOrderItem
          when '000000' then ''
          else _InspLot.SalesOrderItem end                                                           as SalesOrderItem,

      //Display information of Origin type:16

      _InspLot.MaintenanceStrategy,
      _InspLot.MaintenancePlan,
      _InspLot.MaintenancePlanItemIntID,
      _MaintenancePlan.MaintenancePlanDesc,
      _MaintenanceItem.MaintenanceItemDescription                                                    as MaintenancePlanItemDesc,
      _MaintenanceStrategyT.MaintenanceStrategyDesc,

      // Fields necessary for auth. check

      @Consumption.hidden: true
      _InspLot.IsBusinessPurposeCompleted,

      //field control for the inspection lot quantity decimals

      case
      //Follow the standard logic for the case when the vuale for the UnitOfMeasureNumberOfDecimals greater than 4

      //e.g. UnitOfMeasureNumberOfDecimals = 99

          when _InspLot._InspectionLotQuantityUnit.UnitOfMeasureNumberOfDecimals > 4
          then 4
          else _InspLot._InspectionLotQuantityUnit.UnitOfMeasureNumberOfDecimals
          end                                                                                        as InspLotQuantityUnitDecPlaces,
      case
      //Follow the standard logic for the case when the vuale for the UnitOfMeasureNumberOfDecimals greater than 4

      //e.g. UnitOfMeasureNumberOfDecimals = 99

          when _InspLot._InspectionLotSampleUnit.UnitOfMeasureNumberOfDecimals > 4
          then 4
          else _InspLot._InspectionLotSampleUnit.UnitOfMeasureNumberOfDecimals
          end                                                                                        as InspLotSampleQtyUnitDecPlaces,

      // Key Date of Inspection Plan

      InspLotSelectionValidFromDate,
      // adding additional field to denote if the inspection lot has serialized material

      @Semantics.booleanIndicator: true
      _InspLot.InspLotIsSerialNmbrPossible,
      _InspLot.SerialNumberProfile,

      //Associations

      _Operation,
      _InspLotStatus,
      _Customer,
      _Manufacturer,
      _Supplier,
      _PurchasingOrganization,
      _ProductionVersion,
      _InspLotUsageDecision,
      _InspLotStockPosting,
      _InspLotDocument,
      _BusinessCardInfo,
      _ChangedByBusinessCardInfo,
      _MaterialText
}