C_GnrcSftyInstrnFactoryFltrVH

@EndUserText.label: 'Factory locations for generic safety instruction'

@AbapCatalog: { sqlViewName: 'CFSIGNRCLOCVH',
                compiler.compareFilter: true,
                preserveKey: true }

@AccessControl.authorizationCheck: #CHECK

@VDM.viewType: #CONSUMPTION

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel: {
                dataCategory:#VALUE_HELP,
                representativeKey: 'EHSLocationUUID',
                semanticKey: 'EHSLocationUUID',
                usageType:{ serviceQuality: #C,
                            sizeCategory:  #M,
                            dataClass: #MIXED }
               }

@Search.searchable: true

@Metadata: { ignorePropagatedAnnotations: true,
             allowExtensions:true }

define view C_GnrcSftyInstrnFactoryFltrVH
  as select distinct from I_EHSLocation
 
    inner join   I_SafetyInstructionDefinition  on  I_EHSLocation.Plant           = I_SafetyInstructionDefinition.Plant
                                                and I_EHSLocation.EHSLocationType = I_SafetyInstructionDefinition.SafetyInstructionLocType
                                                and I_SafetyInstructionDefinition.SafetyInstructionType = 'GENRC'

    inner join   I_EHSLocationHierarchyRevision on  I_EHSLocationHierarchyRevision.RevisionStartDate <= $session.system_date
                                                and I_EHSLocationHierarchyRevision.RevisionEndDate   >= $session.system_date

    inner join   I_EHSLocationHierarchyNode     on  I_EHSLocationHierarchyNode.EHSLocationUUID             = I_EHSLocation.EHSLocationUUID
                                                and I_EHSLocationHierarchyNode.EHSLocHierarchyRevisionUUID = I_EHSLocationHierarchyRevision.EHSLocHierarchyRevisionUUID

  association [0..1] to I_CurrentEHSLocationNameText as _EHSLocationName on  $projection.EHSLocationUUID = _EHSLocationName.EHSLocationUUID
                                                                         and _EHSLocationName.Language   = $session.system_language

{

         @ObjectModel: { filter.enabled: false,
                         sort.enabled: true,
                         text: { association: '_EHSLocationName',
                                 control: #ASSOCIATED_TEXT_UI_HIDDEN } }
  key    I_EHSLocation.EHSLocationUUID,


         @Consumption.hidden: true
         @ObjectModel.readOnly: true
         cast ( EHSLocationType as ehfnd_loc_type_code_nc preserving type )                             as EHSLocationType,

         @ObjectModel: { readOnly: true,
                         filter.enabled: true,
                         sort.enabled: true }
         @Search: { defaultSearchElement: true,
                    ranking: #HIGH,
                    fuzzinessThreshold: 0.9 }
         _EHSLocationName.EHSLocationName,

         @Search: { defaultSearchElement: true,
                    fuzzinessThreshold: 1,
                    ranking: #MEDIUM }
         @ObjectModel.readOnly: true
         I_EHSLocation.Plant,

         @Consumption.hidden: true
         @ObjectModel.readOnly: true
         I_EHSLocation.EHSLocationStatus,

         @Consumption.hidden: true
         @ObjectModel.readOnly: true
         cast( I_EHSLocation.EHSLocationAuthorizationGroup as ehfnd_loc_auth_group_nc preserving type ) as EHSLocationAuthorizationGroup,

         @Search: { defaultSearchElement: true,
                    fuzzinessThreshold: 1,
                    ranking: #MEDIUM }
         @ObjectModel.readOnly: true
         I_EHSLocation.CostCenter,

         @Search: { defaultSearchElement: true,
                    fuzzinessThreshold: 1,
                    ranking: #MEDIUM }
         @ObjectModel.readOnly: true
         I_EHSLocation.Country,

         @Consumption.hidden: true
         @ObjectModel.readOnly: true
         I_EHSLocation.CompanyCode,

         @Consumption.hidden: true
         @ObjectModel.readOnly: true
         I_EHSLocation.BusinessArea,

         -- Associations
         _EHSLocationName

}
where
      I_EHSLocation.RevisionStartDate <= $session.system_date
  and I_EHSLocation.RevisionEndDate   >= $session.system_date