C_FixedAssetOvwPlntPurgOrgVH

DDL: C_FIXEDASSETOVWPLNTPURGORGVH SQL: CFASSETOVPPOVH Type: view CONSUMPTION

Plant Purchasing Organization Value Help

C_FixedAssetOvwPlntPurgOrgVH is a Consumption CDS View that provides data about "Plant Purchasing Organization Value Help" in SAP S/4HANA. It reads from 1 data source (I_Plant) and exposes 4 fields with key fields Plant, PurchasingOrganization. It has 1 association to related views.

1 data source(s) 4 fields

Data Sources (1)

SourceAliasJoin Type
I_Plant I_Plant from

Associations (1)

CardinalityTargetAliasCondition
[1..*] I_PlantPurchasingOrganization _PlantPurchasingOrganization $projection.Plant = _PlantPurchasingOrganization.Plant

Annotations (14)

NameValueLevelField
AbapCatalog.sqlViewName CFASSETOVPPOVH view
AbapCatalog.compiler.compareFilter true view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #NOT_REQUIRED view
VDM.viewType #CONSUMPTION view
ObjectModel.dataCategory #VALUE_HELP view
ObjectModel.representativeKey PurchasingOrganization view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #S view
ObjectModel.usageType.dataClass #MASTER view
EndUserText.label Plant Purchasing Organization Value Help view
ClientHandling.algorithm #SESSION_VARIABLE view
Search.searchable true view
Consumption.ranked true view

Fields (4)

KeyFieldSource TableSource FieldDescription
KEY Plant Plant
KEY PurchasingOrganization
PlantName PlantName
PurchasingOrganizationName 
@AbapCatalog.sqlViewName: 'CFASSETOVPPOVH'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@VDM.viewType: #CONSUMPTION
@ObjectModel: { dataCategory: #VALUE_HELP,
                semanticKey: ['Plant', 'PurchasingOrganization'],
                representativeKey: 'PurchasingOrganization',
                usageType.serviceQuality: #C,
                usageType.sizeCategory: #S,
                usageType.dataClass: #MASTER }
@EndUserText.label: 'Plant Purchasing Organization Value Help'
@ClientHandling.algorithm: #SESSION_VARIABLE
@Search.searchable: true
@Consumption.ranked: true

define view C_FixedAssetOvwPlntPurgOrgVH
  as select from I_Plant
  association [1..*] to I_PlantPurchasingOrganization as _PlantPurchasingOrganization on $projection.Plant = _PlantPurchasingOrganization.Plant
{
      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      @ObjectModel.text.element:  [ 'PlantName' ]
  key Plant,

      @Search: {
        defaultSearchElement: true,
        ranking: #HIGH,
        fuzzinessThreshold: 0.8
      }
      @ObjectModel.text.element:  [ 'PurchasingOrganizationName' ]
  key cast(_PlantPurchasingOrganization.PurchasingOrganization as faa_asset_purch_organization) as PurchasingOrganization,

      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      @Semantics.text: true
      PlantName,

      @Search: {
        defaultSearchElement: true,
        ranking: #LOW,
        fuzzinessThreshold: 0.8
      }
      @Semantics.text: true
      _PlantPurchasingOrganization._PurchasingOrganization.PurchasingOrganizationName           as PurchasingOrganizationName
}

Learn More