C_FactoringReceivableOpenItem

@AbapCatalog: {
  sqlViewName: 'CWLFFCTRCVOI',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #NOT_ALLOWED,
  personalData.blocking: #NOT_REQUIRED
}
@ClientHandling: {
  algorithm: #SESSION_VARIABLE
}
@ObjectModel: {
  usageType.dataClass: #MIXED,
  usageType.serviceQuality: #C,
  usageType.sizeCategory: #XXL
}
@VDM: {
  viewType: #CONSUMPTION
}
@EndUserText: {
  label: 'Factoring Receivable Open Items for BVB'
}
@Metadata: {
  allowExtensions: true,
  ignorePropagatedAnnotations: true
}
define view C_FactoringReceivableOpenItem
  as select from I_OperationalAcctgDocItem
{
  key CompanyCode                                                            as CompanyCode,
  key AccountingDocument                                                     as AccountingDocument,
  key cast( FiscalYear as fis_gjahr_no_conv preserving type )                as FiscalYear,
  key AccountingDocumentItem                                                 as AccountingDocumentItem,
      ReferenceDocumentLogicalSystem                                         as ReferenceDocumentLogicalSystem,
      cast( '40' as wlf_ref_type )                                           as SettlmtRefDocCat,
      PostingDate                                                            as PostingDate,
      DocumentDate                                                           as DocumentDate,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast( AmountInTransactionCurrency as wlf_open_item_amount )            as OpenItemAmountInTC,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      cast( - AmountInTransactionCurrency as wlf_open_item_amount_inverted ) as OpenItemAmountInvertedInTC,
      @Semantics.currencyCode: true
      TransactionCurrency                                                    as TransactionCurrency,
      DebitCreditCode                                                        as DebitCreditCode,
      AccountingDocumentType                                                 as AccountingDocumentType,
      Customer                                                               as Customer,
      _Customer.Country                                                      as CustomerCountry
      // _CustomerCompany.<FactoringGroup> as FactoringGroup,

      
}
where
      AccountingDocumentCategory = ' '
  and FinancialAccountType       = 'D'
  and ClearingAccountingDocument = ' '
  and _PostingKey.IsSalesRelated = 'X'
//and SpecialGLCode = ' '     // this is covered by posting key