C_FR_TaxReturnBoxCube

@AbapCatalog.sqlViewName: 'CFRTAXRETURNBOXC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'ATR enabled Tax Items for France Cube'
@VDM.viewType: #CONSUMPTION
@Analytics: { dataCategory: #CUBE }
@Analytics.internalName: #LOCAL
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #X
@ObjectModel.usageType.dataClass: #MIXED
@Metadata.allowExtensions: true
@AccessControl.personalData.blocking: #NOT_REQUIRED

define view C_FR_TaxReturnBoxCube
  with parameters
    P_StatryRptgEntity      : srf_reporting_entity,
    P_StatryRptCategory     : srf_rep_cat_id,
    P_StatryRptRunID        : srf_report_run_id,
    P_ReportingCountry      : land1
      
as select from I_StRpTaxReturnBoxCube(
                                                                                  P_TaxIsDeferredRelevant: 'N',    
                                                                                  P_TaxIsMossRelevant   :  'N',     
                                                                                  P_StatryRptgEntity     : $parameters.P_StatryRptgEntity , 
                                                                                  P_StatryRptCategory    : $parameters.P_StatryRptCategory,
                                                                                  P_StatryRptRunID       : $parameters.P_StatryRptRunID,
                                                                                  P_ReportingCountry     : $parameters.P_ReportingCountry,
                                                                                  P_TaxBoxConfiguration  : '1'                                               
                                                                                  )
   left outer to many join  I_TaxGroup                  on  I_StRpTaxReturnBoxCube.Country       = I_TaxGroup.Country
                                                        and I_StRpTaxReturnBoxCube.TaxItemGroupingVersion = I_TaxGroup.TaxItemGroupingVersion
                                                        and I_StRpTaxReturnBoxCube.TaxItemGroupingVersion <> ' '
                                                        and I_StRpTaxReturnBoxCube.TaxBox                 = I_TaxGroup.TaxBalancesGrp            
  
   left outer to one join   P_T007B_GLO as TransactionType on I_StRpTaxReturnBoxCube.TransactionTypeDetermination = TransactionType.ktosl
   
  {
                                                               
  key CompanyCode,
  key AccountingDocument,
  key FiscalYear,
  key TaxItem,
  key TransactionTypeDetermination,
  key TaxBox,
  key  AccountingDocumentType,
  key  SupplierAccountGroup,      
  key  DebitCreditCode,
  
  key TaxDeclnAmountType,
  key TaxBoxStrucValidityStartDate as ValidityStartDate, 
  key case 
  when UnifiedTaxBoxStructureType = ' '
     then 'CA3'
     else UnifiedTaxBoxStructureType
  end as UnifiedTaxBoxStructureType, 
  key TaxGroup,
  key TaxItemGrpgDebitCreditCode,
  key TaxItemGrpgAcctgDocumentType,
  key TaxItemGrpgSupplierAcctGroup,
  key TaxItemGrpgSpecialGLCode,
  key StatryRptgEntity,
  key StatryRptCategory,
  key StatryRptRunID,
  key  
         cast(
      case 
    when UnifiedTaxBoxStructureType = '' and I_TaxGroup.TaxGroupExternalID is not null 
                                           and I_TaxGroup.TaxGroupExternalID <> ''
      then                                     I_TaxGroup.TaxGroupExternalID
      else                                     TaxBox  
    end as fi_exttaxbox preserving type) as TaxBoxByTaxAuthority,

 
      TaxCode,
      I_StRpTaxReturnBoxCube.Country,
      TaxBoxStrucValidityEndDate as ValidityEndDate,
      TaxBoxName,
      I_StRpTaxReturnBoxCube.TaxItemGroupingVersion,
      TaxBoxStructureType,
      TaxBoxStructure,
      TaxBoxStructureName,
      TaxBoxCondition,
      TaxCountry,
      TaxCalculationProcedure,
      @DefaultAggregation:#MIN
      TaxRate,
      TaxRateValidityStartDate,
      GLAccount,
      TaxItemGroup,
      ReferenceDocumentType,
      PostingDate,
      DocumentDate,
      TaxReportingDate,
      ReportingDate,
      TaxType,
      FiscalPeriod,
      @DefaultAggregation:#MIN
      ExchangeRate,
      CompanyCodeCountry,
      ReportingCountry,
      TaxReturnCountry,
      TaxTypeName, 
       
      @Semantics.currencyCode:true
      CompanyCodeCurrency,
      @Semantics.currencyCode:true
      DocumentCurrency,
      @Semantics.currencyCode:true
      ReportingCurrency,
      @Semantics.currencyCode:true
      AdditionalCurrency1,
      @Semantics.currencyCode:true
      AdditionalCurrency2,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      AmountInReportingCurrency,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      AmountInTransactionCurrency,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      TaxBaseAmountInRptgCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      TaxAmountInRptgCrcy,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      TaxBaseAmountInCoCodeCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      TaxAmountInCoCodeCrcy,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      TaxBaseAmountInTransCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'DocumentCurrency'
      TaxAmount,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      NonDeductibleInputTaxAmount,

      TargetTaxCode,
      CAReconciliationKey,
      StatryRptRun,
      TaxIsNotDeductible,
               
// Add new columns for reporting currency

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      case TaxDeclnAmountType
      when 'B'
      then AmountInReportingCurrency
      end                                        as CalculatedTaxBaseAmtInRptgCrcy,   

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      case TaxDeclnAmountType
      when 'T'
      then AmountInReportingCurrency
      end                                        as CalculatedTaxAmountInRptgCrcy,   
      
      // To determine the tax type

      case TransactionType.stgrp
         when '1' then 'A'
         when '2' then 'V' 
         else TaxType
         end                                     as DerivedTaxType,
      
     _TaxTypeText 
}