C_FMEAMngFunction

@EndUserText.label: 'FMEA Function Projection'
@AccessControl.authorizationCheck: #CHECK

@Metadata.allowExtensions: true
@AccessControl.privilegedAssociations:  [ '_CreatedByUserContactCard', '_LastChangedByUserContactCard' ]
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: {
    dataClass: #TRANSACTIONAL,
    sizeCategory: #M,
    serviceQuality: #C
}
define view entity C_FMEAMngFunction
  as projection on I_FMEAFunctionNodeTP
{

      @ObjectModel.text.element: ['FMEANodeDescription']
  key FMEANodeUUID,
      FMEANode,
      FMEAHeaderUUID,
      FMEANodeType,
      FMEANodeListType,
      FMEAItemType,
      FMEAParentNodeUUID,

      FMEANodeReferenceUUID,
      _FMEAReferenceAssignment.FMEANode                            as FMEANodeReference,
      _FMEANodeText.FMEANodeDescription                                                         : localized,
      FMEANodeLongTextDescription,
      //FMEAParentNode,

      _FMEAParentNodeText.FMEANodeDescription                      as FMEAParentNodeDescription : localized,


      @Consumption.filter.hidden: true
      cast( CreatedByUser as plmt_created_by preserving type )     as CreatedByUser,

      //  @Consumption.filter.hidden: true

      //  _CreatedByUserContactCard.FullName,

      @Consumption.filter.hidden: true
      _FMEANodeAssignment.CreationDate,
      @Consumption.filter.hidden: true
      cast( LastChangedByUser as plmt_changed_by preserving type ) as LastChangedByUser,
      @Consumption.filter.hidden: true
      _FMEANodeAssignment.LastChangedDate,
      ChangedDateTime,

      // Associations

      _FailureModeEffectAnalysisTP : redirected to parent C_FMEAMng,
      _FailureModeEffectAnalysis,
      //Associations

      @Consumption.filter.hidden: true
      _CreatedByUserContactCard,
      @Consumption.filter.hidden: true
      _LastChangedByUserContactCard
}