@AccessControl.authorizationCheck: #CHECK
@Metadata.allowExtensions: true
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'FMEA Causes with Actions'
@Search.searchable: true
@ObjectModel.usageType: {
dataClass: #TRANSACTIONAL,
sizeCategory: #M,
serviceQuality: #C
}
define view entity C_FMEAMngCauseTask
as projection on I_FMEACauseTaskTP
{
key FMEANodeUUID,
key FMEATaskUUID,
// NumberOfFailureModes
FMEANodeNumberOfUsages,
// Cause
FMEAHeaderUUID,
@ObjectModel.text.element: ['FMEANodeDescription']
FMEANode,
@Semantics.text: true
@Consumption.filter.hidden: true
_FMEANodeText.FMEANodeDescription : localized,
//Rating and Result
@ObjectModel.text.element: ['FMEARatingText']
FMEARating,
@Semantics.text: true
@Consumption.filter.hidden: true
_FMEARating._Text.FMEARatingText : localized,
@ObjectModel.text.element: ['FMEARatingProfileText']
@Consumption.filter.hidden: true
FMEARatingProfile,
@ObjectModel.text.element: ['FMEARatingText']
@Consumption.filter.hidden: true
_FMEARatingProfile._Text.FMEARatingProfileText : localized,
@ObjectModel.text.element: ['FMEAValuationProcedureText']
@Consumption.filter.hidden: true
FMEAValuationProcedure,
@Consumption.filter.hidden: true
_FMEAValuationProcedure._Text.FMEAValuationProcedureText : localized,
FMEAValuationResultValue, // is this the right field?
//Cause Origin
//@Consumption.semanticObject: 'FailureModeAndEffectsAnalysis'
@ObjectModel.text.element: ['FMEACauseElementDescription']
FMEACauseElementFMEA,
FMEACauseElementDescription, //localized is actually necessary, but seems not to be possible
// Task
@ObjectModel.text.element: ['FMEATaskDescription']
_FMEARelatedTask.FMEATask as FMEATask,
@Semantics.text: true
@Consumption.filter.hidden: true
_FMEARelatedTask.FMEATaskDescription as FMEATaskDescription,
@ObjectModel.text.element: ['FMEATaskTypeText']
_FMEARelatedTask.FMEATaskType,
@Semantics.text: true
@Consumption.filter.hidden: true
_FMEARelatedTask._FMEATaskType._Text.FMEATaskTypeText : localized,
FMEATaskLongText,
// _FMEARelatedTask._FMEATaskDescription.FMEALongText as FMEATaskLongText : localized,
//_FMEATaskDescription[1:Language = $session.system_language].FMEALongText as FMEATaskLongText,
//Target Valuation of Task/Action
@Consumption.valueHelpDefinition: [{ entity:
{name: 'I_FMEAValnProfileValuationVH' , element: 'FMEAValnProfileValuation' },
additionalBinding: [{ localElement: 'FMEAValuationProfile', element: 'FMEAValuationProfile' }]
}]
@ObjectModel.text.element: ['FMEAValnProfileTargetValnText']
FMEAValnPrflTargetValuation,
@Semantics.text: true
@Consumption.filter.hidden: true
_FMEARelatedTask._FMEAValnProfileTargetValn._Text.FMEAValnProfileValnText as FMEAValnProfileTargetValnText : localized,
//Previous Valuation of Task/Action
// Commented out, as it was decided to keep the "previous valuation" hidden
// 22-02-17 commented in again, since it is needed for action sub OP
@Consumption.valueHelpDefinition: [{ entity:
{name: 'I_FMEAValnProfileValuationVH' , element: 'FMEAValnProfileValuation' },
additionalBinding: [{ localElement: 'FMEAValuationProfile', element: 'FMEAValuationProfile' }]
}]
@ObjectModel.text.element: ['FMEAValnProfileValnText']
_FMEARelatedTask.FMEAValnProfileValuation,
@Semantics.text: true
@Consumption.filter.hidden: true
_FMEARelatedTask._FMEAValnProfileValuation._Text.FMEAValnProfileValnText : localized,
@ObjectModel.text.element: ['FMEAValnProfileValnText']
FMEATargetValnResultValue,
@Consumption.valueHelpDefinition: [{ entity:
{name: 'I_FMEAVALUATIONPROFILEVH' , element: 'FMEAValuationProfile' }}]
@ObjectModel.text.element: ['FMEAValuationProfileText']
FMEAValuationProfile,
@Semantics.text: true
@Consumption.filter.hidden: true
_FMEARelatedTask._FMEAValuationProfile._Text.FMEAValuationProfileText : localized,
// Commented out, as it was decided to keep the technical status hidden - again 29.09.22 (EO)
// 22-01-31 commented in again, since it is needed for task sub OP
// @Consumption.filter.hidden: true
// @ObjectModel.text.element: ['FMEAStatusDescription']
// _FMEARelatedTask.FMEATaskStatus,
@Semantics.text: true
@Consumption.filter.hidden: true
_FMEARelatedTask._FMEATaskStatus._Text.FMEAStatusDescription : localized,
@ObjectModel.text.element: ['FMEATaskActionStatusDesc']
_FMEARelatedTask._FMEATaskActionStatus.FMEATaskActionStatus,
@Semantics.text: true
@Consumption.filter.hidden: true
_FMEARelatedTask._FMEATaskActionStatus._Text.FMEATaskActionStatusDesc : localized,
@Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
@Consumption.valueHelpDefinition: [{entity: {name: 'I_FMEATaskGroupVH',element: 'FMEATaskGroup'} }]
FMEATaskGroup,
@Consumption.filter.selectionType: #SINGLE
FMEATaskPlannedStartDate,
// @Consumption.filter.selectionType: #SINGLE
// FMEATaskConfirmationDate,
FMEATaskConfirmationDateTime,
@Consumption.filter.selectionType: #SINGLE
FMEATaskPlannedFinishDate,
@Consumption.filter.selectionType: #SINGLE
ChangedDateTime,
//QualityTaskCodeCatalog, //EO commented out 29.09.22: Is this field needed on the UI?
@ObjectModel.text.element: ['ConfigblCodesCodeGrpTxt']
@Consumption.valueHelpDefinition: [{entity: {name: 'I_QltyTskCodeGroupStdVH',element: 'QualityTaskCodeGroup'} }]
QualityTaskCodeGroup,
@ObjectModel.text.element: ['ConfigurableCodesCodeText']
@Consumption.valueHelpDefinition: [{entity: {name: 'I_QltyTskCodeStdVH',element: 'QualityTaskCode'} , additionalBinding: [{ localElement: 'QualityTaskCodeGroup', element: 'QualityTaskCodeGroup' }] } ]
QualityTaskCode,
@Semantics.text: true
@Consumption.filter.hidden: true
_FMEARelatedTask._ConfigurableCodesCodeGroup._Text.ConfigblCodesCodeGrpTxt : localized,
@Semantics.text: true
@Consumption.filter.hidden: true
_FMEARelatedTask._ConfigurableCodesCode._Text.ConfigurableCodesCodeText : localized,
@Search: { defaultSearchElement: true, ranking: #MEDIUM, fuzzinessThreshold: 0.8}
@Consumption.valueHelpDefinition: [{entity: {name: 'I_QltyBPWithUserStdVH',element: 'BusinessPartner'} }]
@ObjectModel.text.element: ['PersonFullName']
FMEATaskProcessor,
@Semantics.text: true
@Consumption.filter.hidden: true
PersonFullName,
BusinessPartnerUUID,
FMEAPartnerUUID,
FMEATaskIsStartAction,
//Cause Info Section
@ObjectModel.text.element: ['InspSpecAddlCodeGroupText']
InspectionCodeGroup,
@Semantics.text: true
@Consumption.filter.hidden: true
_InspectionCodeGroup._Text.InspSpecAddlCodeGroupText : localized,
@ObjectModel.text.element: ['InspectionCodeText']
InspectionCode,
@Semantics.text: true
@Consumption.filter.hidden: true
_InspectionCode._Text.InspectionCodeText : localized,
@Semantics.text: true
@Consumption.filter.hidden: true
_FMEANodeLongText.FMEALongText : localized,
//Admin Data
_FMEATaskAssignment.CreatedByUser as CreatedByUser,
_FMEATaskAssignment.CreationDate as CreationDate,
_FMEATaskAssignment.LastChangedByUser as LastChangedByUser,
_FMEATaskAssignment.LastChangedDate as LastChangedDate,
//FMEA
_FailureModeEffectAnalysisTP.FMEAInCurLangDescription as FMEADescription,
// Needed for authorization check
// commeted in again, because of use in Sub OP
_FMEARelatedTask.FMEAAuthorizationGroup as FMEAAuthorizationGroup,
//Associations
_FailureModeEffectAnalysisTP : redirected to parent C_FMEAMng,
_FailureModeEffectAnalysis,
_FMEATaskPartner,
_FMEARelatedTask
}