C_EntProjectBriefStatusAreaTP

DDL: C_ENTPROJECTBRIEFSTATUSAREATP Type: view_entity CONSUMPTION

Enterprise Project Brief StatusArea

C_EntProjectBriefStatusAreaTP is a Consumption CDS View that provides data about "Enterprise Project Brief StatusArea" in SAP S/4HANA. It reads from 1 data source (R_EntProjStatusAreaTP) and exposes 11 fields with key field StatusAreaUUID. It is exposed through 1 OData service (UI_ENTPROJECTBRIEF).

1 data source(s) Exposed by 1 service(s) 11 fields

Data Sources (1)

SourceAliasJoin Type
R_EntProjStatusAreaTP R_EntProjStatusAreaTP projection

Annotations (7)

NameValueLevelField
EndUserText.label Enterprise Project Brief StatusArea view
AccessControl.authorizationCheck #MANDATORY view
ObjectModel.representativeKey StatusAreaUUID view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.sizeCategory #XL view
VDM.viewType #CONSUMPTION view

OData Services (1)

ServiceBindingVersionContractRelease
UI_ENTPROJECTBRIEF UI_ENTPROJECTBRIEF V2 C1 NOT_RELEASED

Fields (11)

KeyFieldSource TableSource FieldDescription
KEY StatusAreaUUID StatusAreaUUID
ProjectUUID ProjectUUID
StatusArea StatusArea
StatusAreaStatus StatusAreaStatus
StatusTrend StatusTrend
StatusAreaNote StatusAreaNote
StatusCriticality _StatusAreaStatus Criticality
StatusTrendCriticality _StatusAreaTrend Criticality
StatusDescription _StatusAreaStatus StatusDescription
StatusAreaDescription _StatusAreaCode StatusAreaDescription
StatusTrendDescription _StatusAreaTrend StatusTrendDescription 
@EndUserText.label: 'Enterprise Project Brief StatusArea'
@AccessControl.authorizationCheck: #MANDATORY

@ObjectModel: {
   semanticKey:       [ 'StatusAreaUUID' ],
   representativeKey: 'StatusAreaUUID',
   usageType:{
     serviceQuality:  #C,
     dataClass:       #MIXED,
     sizeCategory:    #XL
   }
 }

@VDM.viewType: #CONSUMPTION
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]

define view entity C_EntProjectBriefStatusAreaTP
  as projection on R_EntProjStatusAreaTP as StatusArea
{
      @UI.hidden: true
  key StatusAreaUUID,
      @UI.hidden: true
      ProjectUUID,
      @UI.identification: [{ position: 10 }]
      @UI.lineItem: [{ position: 10 }]
      @EndUserText.quickInfo: 'Status Area'
      @ObjectModel.filter.enabled: false
      @UI.textArrangement: #TEXT_ONLY  
      @Consumption.valueHelpDefinition: [{
                    entity : {name: 'I_PPM_StatusAreaCode', element: 'StatusArea'  }
              }]      
      @ObjectModel.text.element:['StatusAreaDescription']
      StatusArea,

      @UI.lineItem: [ { position: 20, importance: #HIGH, criticality: 'StatusCriticality', criticalityRepresentation: #WITHOUT_ICON } ]
      @EndUserText.quickInfo: 'Status'
      @ObjectModel.filter.enabled: false
      @Consumption.valueHelpDefinition: [{
                    entity : {name: 'I_PPM_StatusAreaStatus', element: 'Status'  }
              }]
      @UI.textArrangement: #TEXT_ONLY 
      @ObjectModel.text.element:['StatusDescription']
      StatusAreaStatus,

      @UI.lineItem: [ { position: 30, importance: #HIGH, criticality: 'StatusTrendCriticality', criticalityRepresentation: #WITHOUT_ICON } ]
      @EndUserText.quickInfo: 'Trend'
      @ObjectModel.filter.enabled: false
      @UI.textArrangement: #TEXT_ONLY 
      @Consumption.valueHelpDefinition: [{
                 entity : {name: 'I_PPM_StatusAreaTrend', element: 'StatusTrend'  }
           }]
      @ObjectModel.text.element:['StatusTrendDescription']
      StatusTrend,
      @UI.identification: [{ position: 40 }]
      @UI.lineItem: [{ position: 40 }]
      StatusAreaNote,
      //        @UI.hidden: true

      //        _StatusAreaCode.SortField, //   as StatusAreaSortNumber,

      @UI.hidden: true
      _StatusAreaStatus.Criticality as StatusCriticality,
      @UI.hidden: true
      _StatusAreaTrend.Criticality  as StatusTrendCriticality,
      
      @UI.hidden: true
      _StatusAreaStatus.StatusDescription,
      @UI.hidden: true
      _StatusAreaCode.StatusAreaDescription,
      @UI.hidden: true
      _StatusAreaTrend.StatusTrendDescription,  
      
      _EnterpriseProject : redirected to parent C_EntProjectBriefHeaderTP

}

Learn More