C_EntProjWrkPckgProjectStatus

@AbapCatalog.sqlViewName: 'CENTPREPRJWPSTAT'
@ClientDependent: true
@Metadata.allowExtensions: true
@AbapCatalog.compiler.compareFilter: true 

@AccessControl.authorizationCheck: #CHECK
@ObjectModel.representativeKey: 'TaskUUID'
@ObjectModel: {
    usageType: {
       serviceQuality:  #D,
       dataClass:       #MIXED,
       sizeCategory:    #L
    }
}
  
@VDM: {
    viewType: #CONSUMPTION
} 
@EndUserText.label: 'WBS Element object page processing status'

define view C_EntProjWrkPckgProjectStatus     
  as select from I_PPM_ProjectTask as Task
  association [1..1] to I_PPM_ProcessingStatusText as _StatText on $projection.ProcessingStatus = _StatText.ProcessingStatus
{
    @ObjectModel: {
        text: {
            element: ['ProcessingStatusText']
        }
    } 
    
key TaskUUID,
    ProcessingStatus                    as ProcessingStatus,

    @UI.hidden: false
    _StatText.ProcessingStatusText       as ProcessingStatusText,

    cast(concat('PR', WBSElementInternalID) as j_objnr)  as WBSElementInternalID,
    
    @ObjectModel.virtualElement: true
    @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_PPM_WPKG_GET_SYSSTAT'
    @UI.hidden: false
    cast('' as text1000)         as SystemStatus,
    
    // Assoziations for Auth-check

      Task._AuthUser,
      Task._AuthSubst,
      Task._AuthRole,
      Task._AuthGroup,
      
     Task.ControllingArea as ControllingArea,
     Task.ProfitCenter as ProfitCenter,
     
     @UI.hidden: true
     Task.CompanyCode,
     @UI.hidden: true
     Task.FunctionalArea,
     @UI.hidden: true
     Task.Plant,
     @UI.hidden: true
     Task.ResponsibleCostCenter,
     @UI.hidden: true
     _Root.EnterpriseProjectType,
     @UI.hidden: true
     _Root.ProjectProfileCode
    
}
where
    _StatText.Language = $session.system_language