C_EntProjTeamRoleStaffIntTP

DDL: C_ENTPROJTEAMROLESTAFFINTTP Type: view_entity CONSUMPTION

Enterprise Project Role Staffing Internal

C_EntProjTeamRoleStaffIntTP is a Consumption CDS View that provides data about "Enterprise Project Role Staffing Internal" in SAP S/4HANA. It reads from 1 data source (R_EntProjTeamRoleStaffIntTP) and exposes 10 fields with key field ProjectEntitlementUUID. It has 1 association to related views. It is exposed through 1 OData service (UI_ENTPROJECTCONTROL).

1 data source(s) Exposed by 1 service(s) 10 fields

Data Sources (1)

SourceAliasJoin Type
R_EntProjTeamRoleStaffIntTP R_EntProjTeamRoleStaffIntTP projection

Associations (1)

CardinalityTargetAliasCondition
[0..1] C_PPM_ProjectMemberContactCard _Manager _Manager.BusinessPartnerUUID = $projection.BusinessPartnerUUID

Annotations (8)

NameValueLevelField
EndUserText.label Enterprise Project Role Staffing Internal view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
ObjectModel.usageType.dataClass #MIXED view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #L view
VDM.viewType #CONSUMPTION view
Metadata.ignorePropagatedAnnotations true view

OData Services (1)

ServiceBindingVersionContractRelease
UI_ENTPROJECTCONTROL UI_ENTPROJECTCONTROL V2 C1 NOT_RELEASED

Fields (10)

KeyFieldSource TableSource FieldDescription
KEY ProjectEntitlementUUID ProjectEntitlementUUID
ProjectUUID ProjectUUID
TeamMemberUUID TeamMemberUUID
BusinessPartnerUUID BusinessPartnerUUID
BusinessPartner BusinessPartner
ProjectRoleType ProjectRoleType
PersonFullName _BusinessPartner PersonFullName
_BusinessPartner _BusinessPartner
_Manager _Manager
_EnterpriseProjectForUser _EnterpriseProjectForUser 
@EndUserText.label: 'Enterprise Project Role Staffing Internal'
@AccessControl: {
    authorizationCheck:     #CHECK,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}
@ObjectModel: {
    usageType: {
      dataClass:       #MIXED,
      serviceQuality:  #C,
      sizeCategory:    #L
    }
}

@VDM: {
    viewType: #CONSUMPTION
}

@Metadata.ignorePropagatedAnnotations:true
define view entity C_EntProjTeamRoleStaffIntTP

  as projection on R_EntProjTeamRoleStaffIntTP
  association [0..1] to C_PPM_ProjectMemberContactCard as _Manager on _Manager.BusinessPartnerUUID = $projection.BusinessPartnerUUID
{
      @Consumption.filter.hidden: true
  key ProjectEntitlementUUID,
      @Consumption.filter.hidden: true
      ProjectUUID,
      @Consumption.filter.hidden: true
      TeamMemberUUID,

      @UI.textArrangement: #TEXT_ONLY
      @Consumption.valueHelpDefinition: [{ entity:  { name: 'C_PPM_TeamMemberSearchHelp', element: 'BusinessPartnerUUID' } ,
                                            additionalBinding: [{ localElement: 'BusinessPartner',
                                                                  element: 'BusinessPartner',
                                                                  usage: #RESULT}] } ]
      @ObjectModel:{ text: { element: [ 'PersonFullName' ] },
                             foreignKey.association: '_Manager' }
      @EndUserText: {
        label: 'Project Manager',
        quickInfo: 'Project Manager' }
      BusinessPartnerUUID,

      @Consumption.valueHelpDefinition: [{ entity:  { name: 'C_PPM_TeamMemberSearchHelp', element: 'BusinessPartner' } ,
                                           additionalBinding: [{ localElement: 'BusinessPartnerUUID',
                                                                 element: 'BusinessPartnerUUID',
                                                                 usage: #RESULT}] } ]
      @EndUserText: {
        label: 'Project Manager',
        quickInfo: 'Project Manager' }
      @ObjectModel: {  text.element:  [ 'PersonFullName' ] }

      @UI.textArrangement: #TEXT_ONLY
      @Consumption.filter.hidden: true
      BusinessPartner,
      
      @Consumption.filter.hidden: true
      ProjectRoleType,

      @Consumption.filter.hidden: true
      @Semantics.name.fullName: true
      _BusinessPartner.PersonFullName,
      @Consumption.filter.hidden: true
      _BusinessPartner,
      @Consumption.filter.hidden: true
      _Manager,
      @Consumption.filter.hidden: true
      _EnterpriseProject : redirected to parent C_EnterpriseProjectControlTP,
      _EnterpriseProjectForUser

}
where
  ProjectRoleType = 'YP_RL_0001'

Learn More