C_EntProjBriefRoleStaffingTP

@AccessControl: {
    authorizationCheck:     #MANDATORY,
    personalData.blocking:  #BLOCKED_DATA_EXCLUDED
}
@VDM: {
    viewType: #CONSUMPTION
}

@ObjectModel: {
    representativeKey: 'ProjectEntitlementUUID',
    usageType: {
      dataClass:       #MIXED,
      serviceQuality:  #C,
      sizeCategory:    #L
    }
}

@UI.headerInfo: {
 typeName:         'Responsibilities',
 typeNamePlural:   'Resource Assignments',
 title:        { value: 'PersonFullName' },
 description:  { value: 'PersonFullName' }
}


@UI.presentationVariant: [{ groupBy:  ['ProjectRoleTypeText'] ,
                            visualizations: [{type: #AS_LINEITEM }],
                            sortOrder: [ {by: 'PersonFullName',direction: #ASC} ] }]

@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]

@EndUserText.label: 'Enterprise Project Brief role staffing'

define view entity C_EntProjBriefRoleStaffingTP
  as projection on R_EntProjTeamRoleStaffIntTP

 {
      @UI.hidden: true
  key ProjectEntitlementUUID,
      @UI.hidden: true
      ProjectUUID, 
       
      @UI.hidden: true
      TeamMemberUUID,
 
      @UI.hidden: true
      ProjectRoleUUID,
 
      @UI.lineItem: [{position: 20, importance: #HIGH}] 
      @EndUserText.label:'Role' 
      @UI.textArrangement: #TEXT_ONLY
      @Consumption.valueHelpDefinition: [{
        entity : {name: 'C_PPM_ProjectRoleValueHelp', element: 'ProjectRoleType'  }
              }] 
      @ObjectModel.text.element:['ProjectRoleTypeText']
      ProjectRoleType,
      
      @UI.hidden: true
      _ProjectRoleTypeText.ObjectName as ProjectRoleTypeText,
       
 
      @UI.lineItem: [{position: 10, importance: #HIGH}] 
      @EndUserText: {
          label: 'Resource',
          quickInfo: 'Resource'
      }
      @UI.textArrangement: #TEXT_FIRST
      @Consumption.valueHelpDefinition:
       [  { entity: {   element: 'BusinessPartner', name: 'C_PPM_TeamMemberSearchHelp'  }}]
      @ObjectModel.text.element: ['PersonFullName']
      BusinessPartner,
     
      @UI.hidden: true
      BusinessPartnerUUID,
      
  
      @UI.hidden: true
      _TeamMember._BusinessPartner.PersonFullName,
      
  
      @UI.lineItem: [{ position: 30 }]
      @Semantics:   { eMail: { address: true, type:  [ #PREF, #WORK ] } }
      @EndUserText: { label: 'E-Mail Address', quickInfo: 'E-Mail Address' }  // special request from Helga

      @UI.textArrangement: #TEXT_ONLY
      @ObjectModel: {  text.element: [ 'DefaultEmailAddress' ]  }
      BusinessPartnerUUID as EmailByBusinessPartnerUUID,
      @UI.hidden: true
      _WorkplaceAddress.DefaultEmailAddress,
      
      @UI.lineItem: [{ position: 40, label: 'Phone' }]
      @EndUserText: { label: 'Phone', quickInfo: 'Phone' }
      @UI.textArrangement: #TEXT_ONLY
      @ObjectModel: {  text.element: [ 'NormalizedPhoneNumber' ]  }
      BusinessPartnerUUID as PhoneByBusinessPartnerUUID,
      @UI.hidden: true
      _WorkplaceAddress.NormalizedPhoneNumber,
      
      @UI.lineItem: [{ position: 50, label: 'Building' }]
      @EndUserText: { label: 'Building', quickInfo: 'Building' }
      @UI.textArrangement: #TEXT_ONLY
      @ObjectModel: {  text.element: [ 'WorkplaceBuilding' ]  }
      BusinessPartnerUUID as BuildingByBusinessPartnerUUID,
      @UI.hidden: true
      _WorkplaceAddress.Building      as WorkplaceBuilding,
      
      @UI.lineItem: [{ position: 60, label: 'Room' }]
      @EndUserText: { label: 'Room', quickInfo: 'Room' }
      @ObjectModel: {  text.element: [ 'RoomNumber' ]  }
      @UI.textArrangement: #TEXT_ONLY 
      BusinessPartnerUUID as RoomNmbrByBusinessPartnerUUID,
      
      @UI.hidden: true
      _WorkplaceAddress.RoomNumber,

      @Semantics.user.createdBy: true
      @UI.hidden: true
      CreatedByUser,
      @UI.hidden: true
      @Semantics.systemDateTime.createdAt: true
      CreationDateTime,
      @UI.hidden: true
      @Semantics.user.lastChangedBy: true
      LastChangedByUser,
      @Semantics.systemDateTime.lastChangedAt: true
      @UI.hidden: true
      LastChangeDateTime,
      //Association

      _TeamMember,
      _Role, 
      _ProjectRoleTypeText,
      _WorkplaceAddress,
      _EnterpriseProject : redirected to parent C_EntProjectBriefHeaderTP,
      _EnterpriseProjectForUser
}
where
  ProjectRoleType <> 'YP_RL_0001'