C_ESJISalesOrderQuery

@EndUserText.label: 'Incoming Sales Orders'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CESJISLSORDERQ'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.sizeCategory: #XL
@AccessControl.personalData.blocking: #NOT_REQUIRED
define view C_ESJISalesOrderQuery
  with parameters
    P_Language : sylangu
  as select from    I_SalesOrder
    left outer join I_SDDocStandardPartner as StandardPartner on StandardPartner.SDDocument = SalesOrder
  association [0..*] to C_ESJISalesOrderItemQuery  as _ESJISalesOrderItemQuery on $projection.SalesOrder = _ESJISalesOrderItemQuery.SalesOrder
  association [0..1] to C_ESJIMaxDelivCreationDate as _MaxDelivCreationDate    on $projection.SalesOrder = _MaxDelivCreationDate.SalesDocument
  association [0..1] to C_ESJICustomerQuery        as _SoldToParty             on _SoldToParty.Customer = $projection.SoldToParty
{
      //Keys

      key SalesOrder,
      'BUS2032'                                                                       as ObjectType,

      //Category

      SalesOrderType,
      _SalesOrderType._Text[1: Language=$parameters.P_Language].SalesDocumentTypeName as SalesOrderTypeName,

      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      TotalNetAmount,
      @Semantics.currencyCode: true
      TransactionCurrency,
      cast (currency_conversion(
      amount => TotalNetAmount,
      source_currency => TransactionCurrency,
      target_currency => cast ('EUR' as abap.cuky( 5 )),
      exchange_rate_date => CreationDate,
      exchange_rate_type => cast('M' as kurst ),
      error_handling => #CNV_ERROR_HANDLING.SET_TO_NULL,
      round => #CDSBoolean.true,
      decimal_shift => #CDSBoolean.true,
      decimal_shift_back => #CDSBoolean.true
      ) as net_amount_in_dsp_crcy)                                                    as NetAmountInDisplayCurrency,
      //Admin

      CreatedByUser,
      @Semantics.date.creationDate
      CreationDate,
      @Semantics.date.creationDate
      CreationTime,
      @Semantics.date.modificationDate
      LastChangeDate,

      //Orgnization

      @output.labelElement: 'SalesOrganizationName'
      SalesOrganization,
      _SalesOrganization._Text[1: Language=$parameters.P_Language].SalesOrganizationName,
      DistributionChannel,
      _DistributionChannel._Text[1: Language=$parameters.P_Language].DistributionChannelName,
      OrganizationDivision                                                            as Division,
      _OrganizationDivision._Text[1: Language=$parameters.P_Language].DivisionName,
      SalesGroup,
      SalesOffice,

      //Partner

      I_SalesOrder.SoldToParty,
      StandardPartner._SoldToParty.CustomerName as SoldToPartyName ,
      //    Country,

      //    Region,

      //    CityName,


      StandardPartner.ShipToParty,
      StandardPartner._ShipToParty.CustomerName as ShipToPartyName,
      StandardPartner.ResponsibleEmployee,
      StandardPartner._ResponsibleEmployee.PersonFullName as ResponsibleEmployeeName,
      StandardPartner.SalesEmployee,
      StandardPartner._SalesEmployee.PersonFullName as SalesEmployeeName,

      //Sales

      SalesOrderDate,
      SDDocumentReason,
      PurchaseOrderByCustomer,
      CustomerPurchaseOrderDate,

      //Pricing


      PricingDate,

      //Shipping

      RequestedDeliveryDate,
      _MaxDelivCreationDate.DeliveryCreationDate,
      ShippingCondition,
      CompleteDeliveryIsDefined,
      DeliveryBlockReason,
      _DeliveryBlockReason._Text[1: Language=$parameters.P_Language].DeliveryBlockReasonText,

      IncotermsClassification,
      _IncotermsClassification._Text[1: Language=$parameters.P_Language].IncotermsClassificationName,
      IncotermsTransferLocation,

      //Billing

      HeaderBillingBlockReason,
      _HeaderBillingBlockReason._Text[1: Language=$parameters.P_Language].BillingBlockReasonDescription,


      //Payment

      CustomerPaymentTerms,
      _CustomerPaymentTerms._Text[1: Language=$parameters.P_Language].CustomerPaymentTermsName,
      BusinessArea,

      //Status

      OverallSDProcessStatus,
      _OverallSDProcessStatus._Text[1: Language = $parameters.P_Language].OverallSDProcessStatusDesc,

      OverallSDDocumentRejectionSts,
      _OverallSDDocumentRejectionSts._Text[1: Language=$parameters.P_Language].OvrlSDDocumentRejectionStsDesc,

      TotalBlockStatus,
      _TotalBlockStatus._Text[1: Language=$parameters.P_Language].TotalBlockStatusDesc,

      OverallDelivConfStatus,
      OverallTotalDeliveryStatus,
      _OverallTotalDeliveryStatus._Text[1: Language=$parameters.P_Language].OverallTotalDeliveryStatusDesc,

      OverallDeliveryStatus,
      _OverallDeliveryStatus._Text[1: Language=$parameters.P_Language].OverallDeliveryStatusDesc,

      OverallDeliveryBlockStatus,
      _OverallDeliveryBlockStatus._Text[1: Language=$parameters.P_Language].OverallDelivBlockStatusDesc,

      OverallBillingBlockStatus,
      _OverallBillingBlockStatus._Text[1: Language=$parameters.P_Language].OverallBillingBlockStatusDesc,

      OverallTotalSDDocRefStatus,
      TotalCreditCheckStatus,
      _TotalCreditCheckStatus._Text[1: Language=$parameters.P_Language].TotalCreditCheckStatusDesc,
      _ESJISalesOrderItemQuery,
      _SoldToParty
}