C_DwnPaytReqToBeVerifiedInbox

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #MANDATORY
@AccessControl.privilegedAssociations: ['_UserContactCard']
@EndUserText.label: 'Verify Supplier Down Payment Request'
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #L,
  dataClass: #MIXED
}
@UI.headerInfo: {
  title: {
    value: 'AccountingDocument',
    type: #STANDARD
  },
  description: {
    value: 'AccountingDocumentTypeName',
    type: #STANDARD
  }
}
@VDM.viewType: #CONSUMPTION

define root view entity C_DwnPaytReqToBeVerifiedInbox
  as select from           C_TaskToDwnPaytReqToBeVerified as _Task
    left outer to one join I_DwnPaytReqToBeVerifiedWl     as _AccountingDocument on  _Task.CompanyCode        = _AccountingDocument.CompanyCode
                                                                                 and _Task.AccountingDocument = _AccountingDocument.AccountingDocument
                                                                                 and _Task.FiscalYear         = _AccountingDocument.FiscalYear
  association [1..*] to C_DwnPaytReqItemToBeVerified as _Item                       on  $projection.CompanyCode        = _Item.CompanyCode
                                                                                    and $projection.AccountingDocument = _Item.AccountingDocument
                                                                                    and $projection.FiscalYear         = _Item.FiscalYear
  association [0..1] to I_AccountingDocumentCategory as _AccountingDocumentCategory on  $projection.AccountingDocumentCategory = _AccountingDocumentCategory.AccountingDocumentCategory
  association [0..1] to I_UserContactCard            as _UserContactCard            on  $projection.ParkedByUser = _UserContactCard.ContactCardID

{
  key _Task.WorkflowTaskInternalID,
      @UI.facet: [
        {
          targetQualifier: 'Amount',
          type: #DATAPOINT_REFERENCE,
          purpose: #HEADER
        },
        {
          purpose: #HEADER,
          type: #FIELDGROUP_REFERENCE,
          targetQualifier: 'Submitter'
        },
        {
          id:       'Header',
          purpose:  #STANDARD,
          type: #FIELDGROUP_REFERENCE,
          targetQualifier: 'HeaderFields',
          label:    'Document Header',
          position: 10 },
        {
          id:       'Items',
          purpose:  #STANDARD,
          label:    'Journal Entry Line Items',
          position: 20,
          type:     #LINEITEM_REFERENCE,
          targetElement: '_Item'
        }
        ]
      @ObjectModel.text.element: ['CompanyCodeName']
      @UI.textArrangement: #TEXT_LAST
      @UI: { fieldGroup:[ {
        qualifier: 'HeaderFields',
        position: 11} ] }
  key _AccountingDocument.CompanyCode,
  @UI: { fieldGroup:[ {
        qualifier: 'HeaderFields',
        position: 12} ] }
  key _AccountingDocument.FiscalYear,
      @UI: { fieldGroup:[ {
      qualifier: 'HeaderFields',
      position: 10} ] }
  key _AccountingDocument.AccountingDocument,
      @UI: { fieldGroup:[ {
        qualifier: 'HeaderFields',
        position: 40} ] }
      _AccountingDocument.DocumentDate,
      @UI: { fieldGroup:[ {
      qualifier: 'HeaderFields',
      position: 30} ] }
      _AccountingDocument.PostingDate,
      _AccountingDocument.AccountingDocumentCategory,
      @UI: { fieldGroup:[ {
      qualifier: 'HeaderFields',
      position: 20} ] }
      @ObjectModel.text.element: ['AccountingDocumentTypeName']
      @UI.textArrangement: #TEXT_LAST
      _AccountingDocument.AccountingDocumentType,
      @Semantics.text: true
      _AccountingDocument.AccountingDocumentTypeName,
      _AccountingDocument.TransactionCurrency,
      _AccountingDocument.AccountingDocCreatedByUser,
      _AccountingDocument.AccountingDocCreatedByUserName,
      @UI: { fieldGroup:[ {
      qualifier: 'Submitter',
      type: #AS_CONTACT,
      value: '_UserContactCard',
      label: 'Submitted By',
      position: 10} ] }
      //@EndUserText.label: 'Submitted By'

      @ObjectModel.text.element:  [ 'ParkedByUserName' ]
      @Semantics.user.createdBy: true
      @Semantics.contact.type: #PERSON
      @ObjectModel.foreignKey.association: '_UserContactCard'
      _AccountingDocument.ParkedByUser,
      _AccountingDocument.ParkedByUserName,
      _AccountingDocument.TechnicalWrkflwObject,
      @UI.dataPoint: {
      qualifier: 'Amount'
      }
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      _AccountingDocument.AmountInTransactionCurrency,
      _AccountingDocument.AcctgDocumentWorkflowStatus,
      @UI: { fieldGroup:[ {
        qualifier: 'HeaderFields',
        position: 60} ] }
      _AccountingDocument.AccountingDocumentHeaderText,
      @UI: { fieldGroup:[ {
      qualifier: 'HeaderFields',
      position: 70} ] }
      _AccountingDocument.DocumentReferenceID,
      @Semantics.text: true
      @UI.hidden: true
      _AccountingDocument.CompanyCodeName,
      _AccountingDocument.WorkflowInternalID,
      @UI: { identification:[ { position: 10} ] }
      _AccountingDocumentCategory._Text[1:Language = $session.system_language ].AccountingDocumentCategoryName,
      _Item,
      _UserContactCard
}