C_DspPaytCardCustomerCard

@AbapCatalog: {
    sqlViewName: 'CDPCDCUSCNTCT',
    compiler.compareFilter: true
}
@AccessControl: {
    authorizationCheck: #CHECK,
    personalData.blocking: #REQUIRED
}
@ClientHandling.algorithm: #SESSION_VARIABLE
@EndUserText.label: 'Payment Card - Customer Contact Card'

@ObjectModel.usageType: {
    dataClass: #MIXED,
    serviceQuality: #C,
    sizeCategory: #L
}
@Search.searchable: true
@VDM: {
    viewType: #CONSUMPTION,
    private: false
}
@Consumption.ranked: true
define view C_DspPaytCardCustomerCard
  as select from I_Customer as Customer
{
      @Semantics.contact.type: #ORGANIZATION
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.85,
        ranking: #HIGH
      }
      @ObjectModel.text.element:  [ 'FullName' ]
  key Customer.Customer,

      @Semantics.name.fullName: true
      Customer.CustomerFullName                                       as FullName,
      
      @UI.hidden: true
      Customer.AuthorizationGroup,

      @UI.hidden: true
      Customer.CustomerAccountGroup,

      -- ADDRESS

      @Semantics.address: {
        type:  [ #WORK ],
        street: true
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.85,
        ranking: #LOW
      }
      @EndUserText.quickInfo: 'Street'
      Customer.StreetName,

      @Semantics.address: {
        type:  [ #WORK ],
        streetNoNumber: true
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 1,
        ranking: #LOW
      }
      Customer._StandardAddress.HouseNumber,

      @Semantics.address: {
        type:  [ #WORK ],
        city: true
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.85,
        ranking: #LOW
      }
      Customer.CityName,

      @Semantics.address: {
        type:  [ #WORK ],
        zipCode: true
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 1,
        ranking: #LOW
      }
      Customer.PostalCode,

      @Semantics.address: {
        type:  [ #WORK ],
        country: true
      }
      @Search: {
        defaultSearchElement: true,
        fuzzinessThreshold: 0.90,
        ranking: #LOW
      }
      cast(Customer.Country as paymentcardcountryregion preserving type ) as Country,

      -- END ADDRESS


      @Semantics.telephone.type:  [ #WORK ]
      @Consumption.filter.hidden: true
      Customer._StandardAddress._DefaultPhoneNumber.PhoneNumber       as PhoneNumber,

      @Semantics.telephone.type:  [ #CELL ]
      @Consumption.filter.hidden: true
      Customer._StandardAddress._DefaultMobilePhoneNumber.PhoneNumber as MobilePhoneNumber,

      @EndUserText.label: 'Email'      
      @Semantics.eMail.type:  [ #WORK ]
      @Consumption.filter.hidden: true
      Customer._StandardAddress._DefaultCorpEmailAddress.EmailAddress     as EmailAddress,
      
      // Fields added For Data Controller in DCL .... NOT TO BE CONSUMED.

      @UI.hidden: true
      @Consumption.filter.hidden: true
      DataControllerSet,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      DataController1,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      DataController2,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      DataController3,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      DataController4,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      DataController5,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      DataController6,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      DataController7,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      DataController8,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      DataController9,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      DataController10,

      @UI.hidden: true
      @Consumption.filter.hidden: true      
      IsBusinessPurposeCompleted
      
}