C_Dischannelvaluehelp

DDL: C_DISCHANNELVALUEHELP Type: view CONSUMPTION

Distribution Channel by Sales Org.

C_Dischannelvaluehelp is a Consumption CDS View that provides data about "Distribution Channel by Sales Org." in SAP S/4HANA. It reads from 1 data source (I_SlsOrganizationDistrChnl) and exposes 5 fields with key fields SalesOrganization, DistributionChannel. It has 1 association to related views. It is exposed through 1 OData service (UI_TRDGCONTR_MANAGEV4).

1 data source(s) Exposed by 1 service(s) 5 fields

Data Sources (1)

SourceAliasJoin Type
I_SlsOrganizationDistrChnl SlsOrganizationDistrChnl from

Associations (1)

CardinalityTargetAliasCondition
[0..*] I_DistributionChannelText _Text $projection.DistributionChannel = _Text.DistributionChannel

Annotations (14)

NameValueLevelField
AbapCatalog.sqlViewName CSDISCHSORGVH view
AbapCatalog.compiler.compareFilter true view
ClientDependent true view
AccessControl.authorizationCheck #NOT_REQUIRED view
EndUserText.label Distribution Channel by Sales Org. view
VDM.viewType #CONSUMPTION view
ObjectModel.usageType.dataClass #CUSTOMIZING view
ObjectModel.usageType.serviceQuality #A view
ObjectModel.usageType.sizeCategory #S view
UI.headerInfo.typeName Distribution Channel view
UI.headerInfo.typeNamePlural Distribution Channels view
Search.searchable true view
Consumption.valueHelpDefault.fetchValues #AUTOMATICALLY_WHEN_DISPLAYED view
Consumption.ranked true view

OData Services (1)

ServiceBindingVersionContractRelease
UI_TRDGCONTR_MANAGEV4 UI_TRDGCONTR_MANAGEV4 V4 C1 NOT_RELEASED

Fields (5)

KeyFieldSource TableSource FieldDescription
KEY SalesOrganization I_SlsOrganizationDistrChnl SalesOrganization
KEY DistributionChannel I_SlsOrganizationDistrChnl DistributionChannel
DistributionChannelName
_DistributionChannel I_SlsOrganizationDistrChnl _DistributionChannel
_SalesOrganization I_SlsOrganizationDistrChnl _SalesOrganization 
@AbapCatalog: {
   sqlViewName: 'CSDISCHSORGVH',
   compiler.compareFilter: true
}

@ClientDependent: true 
@AccessControl.authorizationCheck: #NOT_REQUIRED
@EndUserText.label: 'Distribution Channel by Sales Org.' 

@VDM: {
  viewType: #CONSUMPTION
}
@ObjectModel:{
  usageType:{
    dataClass: #CUSTOMIZING,
    serviceQuality: #A,
    sizeCategory: #S
  }
}

@UI.headerInfo:{ 
  typeName:       'Distribution Channel',
  typeNamePlural: 'Distribution Channels'
}

@Search.searchable: true

@Consumption:{
  valueHelpDefault:{
    fetchValues:#AUTOMATICALLY_WHEN_DISPLAYED
  },
  ranked: true
}

define view C_Dischannelvaluehelp 
  as select from I_SlsOrganizationDistrChnl as SlsOrganizationDistrChnl
  
  association [0..*] to I_DistributionChannelText as _Text on $projection.DistributionChannel = _Text.DistributionChannel

{   
    @ObjectModel.foreignKey.association: '_SalesOrganization'
    @Search: {
       defaultSearchElement: true,
       ranking: #LOW
    }
    @UI: {
      selectionField: [{ position: 30 }],
      lineItem:[ {position:30, importance: #HIGH} ],
      textArrangement: #TEXT_FIRST
    }
    key SlsOrganizationDistrChnl.SalesOrganization,
    
    @ObjectModel.foreignKey.association: '_DistributionChannel'
    @ObjectModel.text.element: ['DistributionChannelName']
    @Search: {
       defaultSearchElement: true,
       ranking: #HIGH,
       fuzzinessThreshold: 0.9
    }
    @UI: {
      selectionField: [{ position: 10 }],
      lineItem:[ {position:10, importance: #HIGH } ]
    } 
    key SlsOrganizationDistrChnl.DistributionChannel,
    
    @Semantics.text :true
    @Search: {
       defaultSearchElement: true,
       ranking: #LOW,
       fuzzinessThreshold: 0.8 }
    @UI: {
      selectionField: [{ position: 20 }],
      lineItem:[ {position:20, importance: #HIGH } ]
    } 
    _Text[1:Language=$session.system_language].DistributionChannelName,
    
    @Search.defaultSearchElement: false
    SlsOrganizationDistrChnl._DistributionChannel,
    @Search.defaultSearchElement: false
    SlsOrganizationDistrChnl._SalesOrganization

}

Learn More