C_DeviationTriggeringTasks

@AbapCatalog.sqlViewName: 'CDEVTRIGGER'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey:true

@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel.usageType:{ serviceQuality: #D,        // < 100 msec

                         sizeCategory:  #XL,         // < 10.000.000

                         dataClass: #MIXED }

@AccessControl.authorizationCheck: #CHECK
// #NOT_REQUIRED as a start

@AccessControl.personalData.blocking: #NOT_REQUIRED

@EndUserText.label: 'Deviation Triggering Tasks'

@Consumption.semanticObject: 'EHSTask'
@ObjectModel.semanticKey: 'EHSTaskTitle'
@ObjectModel.representativeKey: 'EHSTaskDefinitionUUID'
@Metadata.allowExtensions: true
@UI.presentationVariant: [{requestAtLeast: ['EHSTaskDefinitionStatus']}]

define view C_DeviationTriggeringTasks
  as select from I_EHSCombinedTaskDefAndInstce as EHSCombinedTaskDefAndInstce
    inner join   I_EHSTaskFollowUp            as EhsTaskFollowUps on EhsTaskFollowUps.EHSPlannedTaskUUID = EHSCombinedTaskDefAndInstce.EHSPlannedTaskUUID
  association [1..1] to I_EHSTaskTriggerCategoryText as _EHSTaskTriggerCategoryText on  $projection.TaskFollowCategoryCode   = _EHSTaskTriggerCategoryText.TaskFollowCategoryCode
                                                                                    and _EHSTaskTriggerCategoryText.Language = $session.system_language
  association [0..*] to I_EHSTaskDefinitionTypeText  as _EHSTaskDefinitionTypeText  on  $projection.EHSTaskDefinitionType = _EHSTaskDefinitionTypeText.EHSTaskDefinitionType
  association [0..1] to I_EHSTaskPriorityText        as _EHSTaskPriorityText        on  $projection.EHSTaskPriority   = _EHSTaskPriorityText.EHSTaskPriority
                                                                                    and _EHSTaskPriorityText.Language = $session.system_language
  association [0..1] to I_EHSTaskCalendarStatusText  as _EHSTaskCalendarStatusText  on  EHSCombinedTaskDefAndInstce.EHSTaskStatusValueForSorting = _EHSTaskCalendarStatusText.EHSTaskStatus
                                                                                    and _EHSTaskCalendarStatusText.Language       = $session.system_language

{
  key       EhsTaskFollowUps.EHSTaskFollowUpUUID,
  key       EHSCombinedTaskDefAndInstce.EHSPlannedTaskUUID,
  key       EHSCombinedTaskDefAndInstce.EHSTaskDefinitionUUID,
            EHSCombinedTaskDefAndInstce.WorkflowTaskInternalID,
            // WORKFLOW INFORMATION

            //            cast ( '' as abap.char(12) )                             as WorkflowTaskStatus,

            EHSCombinedTaskDefAndInstce.WorkflowTaskStatus,
            _EHSTaskCalendarStatusText.EHSTaskStatusName,
            @Consumption.filter.hidden: true

            EHSCombinedTaskDefAndInstce.EHSTaskStartDate,
            EHSCombinedTaskDefAndInstce.EHSTaskDueDate,
            EHSCombinedTaskDefAndInstce.EHSTaskInstceCompletionDate,
            EHSCombinedTaskDefAndInstce.EHSTaskTimeZone,
            
            EHSCombinedTaskDefAndInstce.EHSPlannedTaskID,       

            EHSCombinedTaskDefAndInstce.EHSTaskOwnerBP,
            EHSCombinedTaskDefAndInstce._EHSTaskOwnerUser.PersonFullName    as EHSTaskOwnerUserName,
            EHSCombinedTaskDefAndInstce._EHSTaskOwnerUser.PersonFullName,
            //EHSTaskPlannedInstance.EHSTaskAssignedBP,

            EHSCombinedTaskDefAndInstce._EHSTaskAssignedUser.PersonFullName as EHSTaskAssignedUserName,
            //  EHSTaskPlannedInstance.EHSTaskApprovingBP,


            // TASK DEFINITION

            @ObjectModel.filter.enabled: true
            @ObjectModel.sort.enabled: true
            EHSCombinedTaskDefAndInstce.EHSTaskTitle,
            @ObjectModel.text.association: '_EHSTaskDefinitionTypeText'
            EHSCombinedTaskDefAndInstce.EHSTaskDefinitionType,
            @ObjectModel: {
            foreignKey.association: '_EHSTaskPriority'
            }
            EHSCombinedTaskDefAndInstce.EHSTaskPriority,
            _EHSTaskPriorityText.EHSTaskPriorityName,
            @UI.hidden: true
            EHSCombinedTaskDefAndInstce.EHSTaskDefinitionStatus,
            EHSCombinedTaskDefAndInstce.EHSTaskDefinitionIsPaused,
            EHSCombinedTaskDefAndInstce.EHSTaskRecurrenceType,

            EHSCombinedTaskDefAndInstce.EHSLocationUUID,
          
            cast('' as ehfnd_loc_name)                                      as EHSLocationName,


            // HOST OBJECT

            EHSCombinedTaskDefAndInstce.EHSTaskHostSemanticObject,
            EHSCombinedTaskDefAndInstce.EHSTaskHostObjectInstance,
            @UI.hidden: true
            EHSCombinedTaskDefAndInstce.EHSTaskHostObjectInstanceUUID,
            EHSCombinedTaskDefAndInstce.EHSTaskHostObjectAdapterClass,
            EhsTaskFollowUps.TaskFollowCategoryCode,

            _EHSTaskTriggerCategoryText.EHSTriggerCategoryDesc,
            EhsTaskFollowUps.TaskFollowRefObjUUID,


            @Consumption.filter.hidden: true
            _EHSTaskOwnerUser,
            _EHSTaskDefinitionTypeText,
            EHSCombinedTaskDefAndInstce._EHSTaskPriority,
            
            // For authorization check

            EHSCombinedTaskDefAndInstce.EHSTaskOwnerUser,
            EHSCombinedTaskDefAndInstce._EHSTaskAdapterClass,
            EHSCombinedTaskDefAndInstce._IncidentAuthorizationFields,
            EHSCombinedTaskDefAndInstce._EHSCtrlImplmtnAuthznFields,
            EHSCombinedTaskDefAndInstce._EHSRskAssessmentAuthznFields,
            EHSCombinedTaskDefAndInstce._EHSCmplncScenAuthznFields,
            EHSCombinedTaskDefAndInstce._CmplncRqmtAuthznFields,
            EHSCombinedTaskDefAndInstce.IncidentHasAccessRestriction
}
where
  EhsTaskFollowUps.TaskFollowRefObjType = 'INCIDENT'