C_DeliveryNoteItem

@AbapCatalog.sqlViewName: 'CDELVNOTEITM'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Consumption view for Delivery Note Item'

@AbapCatalog.preserveKey: true

@VDM:
      {
        viewType: #CONSUMPTION,
        private: false
      }
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.personalData.blocking:#REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE
define view C_DeliveryNoteItem
  as select from I_DeliveryDocumentItem
  association [1..1] to I_DeliveryDocument  as _DeliveryDocument           on  $projection.DeliveryDocument = _DeliveryDocument.DeliveryDocument
  association [0..1] to I_SalesDocumentItem as _ReferenceSalesDocumentItem on  $projection.ReferenceSDDocument         = _ReferenceSalesDocumentItem.SalesDocument
                                                                           and $projection.ReferenceSDDocumentItem     = _ReferenceSalesDocumentItem.SalesDocumentItem
                                                                           and $projection.ReferenceSDDocumentCategory = 'C'
  association [0..1] to I_MaterialType as _MaterialType on $projection.MaterialTypePrimary = _MaterialType.MaterialType
{
  key DeliveryDocument,
  key DeliveryDocumentItem,
      _ReferenceSalesDocumentItem.TransactionCurrency,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
       @OData.v2.amount.noDecimalShift: true
      cast ( div ( _ReferenceSalesDocumentItem.NetAmount , _ReferenceSalesDocumentItem.OrderQuantity ) as abap.dec( 11, 2 ))
                                                             as NetPriceAmount,
      @Semantics.amount.currencyCode: 'TransactionCurrency'
       @OData.v2.amount.noDecimalShift: true
      ActualDeliveryQuantity  * div ( _ReferenceSalesDocumentItem.NetAmount , _ReferenceSalesDocumentItem.OrderQuantity )
                                                             as NetValueAmount,
      @ObjectModel.foreignKey.association: '_Material'
      Material,
      MaterialByCustomer,
      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      ItemGrossWeight,
      @Semantics.quantity.unitOfMeasure: 'ItemWeightUnit'
      ItemNetWeight,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_ItemWeightUnit'
      ItemWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'ItemVolumeUnit'
      ItemVolume,
      @Semantics.unitOfMeasure: true
      @ObjectModel.foreignKey.association: '_ItemVolumeUnit'
      ItemVolumeUnit,
      ActualDeliveryQuantity,
      DeliveryQuantityUnit,
      Batch,
      HigherLvlItmOfBatSpltItm,
      @ObjectModel.foreignKey.association: '_SalesDocument' 
      _ReferenceSalesDocumentItem._Partner.SalesDocument     as PartnerSalesDocument,
      @ObjectModel.foreignKey.association: '_SalesDocumentItem' 
      _ReferenceSalesDocumentItem._Partner.SalesDocumentItem as PartnerSalesDocumentItem,
      _ReferenceSalesDocumentItem.PurchaseOrderByCustomer    as PurchaseOrderByCustomer,
      Plant,
      StorageLocation,
      ReferenceSDDocument,
      ReferenceSDDocumentItem,
      ReferenceSDDocumentCategory,
      MaterialTypePrimary,
      CustEngineeringChgStatus,                                         

      _DeliveryDocument,
      _ReferenceSalesDocumentItem,
      _Plant,
      _StorageLocation,
      _Material,
      _ReferenceSalesDocumentItem._Partner._SalesDocument, 
      _ReferenceSalesDocumentItem._Partner._SalesDocumentItem,
      _MaterialType,
      _ItemWeightUnit,
      _ItemVolumeUnit
      
}