C_DFS_AllwncPlan

/*
 NOTE #1:
      Because we used this Class for the hierarchy, no further classes, as virtuell fields
       classes can be used. This will lead to app crashes.
 NOTE #2: 2105
      PrivilegedAssociations is not supported in this release. See Jira https://sapjira.wdf.sap.corp/browse/FIORITECHE1-4465

      This coursing problems with View which have the annotation @AccessControl.authorizationCheck: #PRIVILEGED_ONLY (e.g. User Status Annotation)
      For that reason the User Function is deactived (hidden)
*/

@EndUserText.label: 'Projection View Allowance Plan'
@AccessControl.authorizationCheck: #CHECK
@Metadata.allowExtensions: true
@UI: { headerInfo: { typeName: 'Allowance Plan',
               typeNamePlural: 'Allowance Plans',
                        title: { type: #STANDARD, value: 'DfsAllwncPlanDescription' } }
                    }
@Search.searchable: true
//@ObjectModel.semanticKey: [ 'DfsAllwncPlanUUID' ]

//@ObjectModel.usageType.dataClass: #MIXED

//@ObjectModel.usageType.serviceQuality: #C

//@ObjectModel.usageType.sizeCategory: #L


  @ObjectModel: {
      semanticKey: [ 'DfsAllwncPlanUUID' ],
        usageType: { dataClass: #MIXED,
                     serviceQuality: #C,
                     sizeCategory: #L }
//   modelingPattern:       #TRANSACTIONAL_INTERFACE,

// supportedCapabilities: [#TRANSACTIONAL_PROVIDER]                

     }



@VDM.viewType:#CONSUMPTION
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]

//@AccessControl: {

//    privilegedAssociations: [ '_StatusObjectUserStatus', '_StatusAttributes', '_StatusObject' ]

//}


@ObjectModel.query.implementedBy: 'ABAP:CL_DFS_ALLWNCPLAN_HIER'

@OData.hierarchy.recursiveHierarchy: [ {
  elementWithHierarchy:      'DfsAllwncPlanUUID',
  nodeElement:               'HierarchyNode',
//  externalKeyElement:        'DemoHierarchyNode',

  parentNodeElement:         'HierarchyParentNode',
  distanceFromRootElement:   'HierarchyLevel',
  drillStateElement:         'DrillDownState',
  descendantCountElement:    'HierarchyDescendantCount',
  preorderRankElement:       'HierarchyNodeOrdinalNumber'
} ]


define root view entity C_DFS_AllwncPlan 
provider contract transactional_query
  as projection on R_DFS_AllwncPlanTP as _AllowancePlan
{
  key DfsAllwncPlanUUID,
      DfsAllwncPlanID,
      @UI.hidden: true
      Language,
      DfsAllwncPlanDescription,
      DfsAllwncPlanPreviousPlanUUID,
      
      _PreviousPlan.DfsAllwncPlanID                  as DfsAllwncPlanPreviousPlanID,
      @UI.hidden: true
      @Consumption.filter.hidden: true
      _PreviousPlan.DfsAllwncPlanUUID                  as DfsAllwncPlnPrevPlnTgtUUID,

      DfsAllwncPlanValdtyStrtDate,
      DfsAllwncPlanValdtyEndDate,

      @Semantics.text: true
      _FlxMtPlObj.FlxblMatlPlngObjDescription        as FlxblMatlPlngObjDescription,

      @ObjectModel: { text.element: ['FlxblMatlPlngObjDescription'],
                      foreignKey.association:'_FlxMtPlObj'}
      FlxblMatlPlngObjectID,
      FlxblMatlPlngObjectUUID,
      @Semantics.text: true
      _FlxMtPlObjVariant.FlxblMatlPlngObjVariantDesc as FlxblMatlPlngObjVariantDesc,

      @ObjectModel: { text.element: ['FlxblMatlPlngObjVariantDesc'] }
      //      ,foreignKey.association:'_FlxMtPlObjVariant'

      //  cast( FlxblMatlPlngObjVariantID as abap.sstring( 6 ) ) as FlxblMatlPlngObjVariantID,

      FlxblMatlPlngObjVariantID,


      FlxblMatlPlngObjVariantUUID,

      @UI.hidden: true
      @Consumption.filter.hidden: true
      _ProductText.ProductName,

      @ObjectModel: { text.element: ['ProductName']}
      Product,

      DfsAllwncPlanStatusObject,
      DfsAllwncPlanStatusCode,

      @UI.hidden: true
      @Consumption.filter.hidden: true
      @Consumption.valueHelpDefinition: [{ entity: {name: 'C_DFS_AllwncPlanUserStatusVH',  element: 'StatusProfile' } }]
      DfsAllwncPlanStatusProfile,
      StatusCriticality,
      Status,
      DfsAllwncPlanAllowedQuantity,
      DfsAllwncPlanUsedQuantity,
      DfsAllwncPlanQuantityUnit,

      @UI.hidden: true
      @Consumption.filter.hidden: true
      _UsageType.FrcElmntOrgUsageTypeDesc,
      @ObjectModel: { text.element: ['FrcElmntOrgUsageTypeDesc']}
      FrcElmntOrgUsageType,

      @UI.hidden: true
      @Consumption.filter.hidden: true
      _BaseType._Text.DfsAllwncPlanBaseTypeDesc     : localized,
      @ObjectModel: { text.element: ['DfsAllwncPlanBaseTypeDesc']}
      DfsAllwncPlanBaseType,

      @UI.hidden: true
      @Consumption.filter.hidden: true
      _MultiLevel._Text.DfsAllwncPlanMultiLevelDesc : localized, 

      @ObjectModel: { text.element: ['DfsAllwncPlanMultiLevelDesc']}
      DfsAllwncPlanMultiLevel,
      DfsAllwncPlanIsFUPHidden,
      DfsAllwncPlanIsReqHidden,

//      @Semantics.text: true

//      _FrcElmntOrg.FrcElmntOrgName,

      //due to performance reasons the fields are not read in the stack

      //names of FE will be read in the redefinition of CL_RAP_DYNAMIC_HIER_QUERY for the hierarchy 

      FrcElmntOrgName,


      @ObjectModel: { text.element: ['FrcElmntOrgName'],
                      foreignKey.association:'_FrcElmntOrg'}
      ForceElementOrgID,
      ForceElementOrgUUID,
      DfsAllwncPlanIsCompleted,
      DfsAllwncPlanCompletedStatus,
      DfsAllwncPlanComment,
      DfsAllwncReqID,
      DfsAllwncReqUUID,

      // Field group: Administrative Information

      DfsAllwncPlanCreationDateTime,
      DfsAllwncPlanCreatedByUser,
      DfsAllwncPlanChangeDateTime,
      DfsAllwncPlanLastChgdByUser,


      // Hierarchy

      @UI.hidden: true
      HierarchyNode,
      @UI.hidden: true
      HierarchyParentNode,
      @UI.hidden: true
      HierarchyLevel,
      @UI.hidden: true
      HierarchyDescendantCount,
      @UI.hidden: true
      DrillDownState,
      @UI.hidden: true
      HierarchyNodeOrdinalNumber,

      /* Associations */
      @ObjectModel.filter.enabled: false
      _AllwncPlanToFe : redirected to composition child C_DFS_AllwncPlanToFe,
       @ObjectModel: { filter.enabled: false,
                       sort.enabled: false }
      _PreviousPlan   : redirected to C_DFS_AllwncPlan,
      @ObjectModel: { filter.enabled: false,
                    sort.enabled: false }
      _FrcElmntOrg,
      @ObjectModel: { filter.enabled: false,
                       sort.enabled: false }
      _ValdtyEndDate,
      @ObjectModel: { filter.enabled: false,
                  sort.enabled: false }
      _ValdtyStrtDate,
      @ObjectModel: { filter.enabled: false,
                      sort.enabled: false }
      _StatusObject,
      @ObjectModel: { filter.enabled: false,
                       sort.enabled: false }
      _StatusAttributes,
      @ObjectModel: { filter.enabled: false,
                   sort.enabled: false }
      _LastChangedByUserContactCard,
      @ObjectModel: { filter.enabled: false,
                       sort.enabled: false }
      _CreatedByUserContactCard,
      @Consumption.filter.hidden: true
      @ObjectModel.filter.enabled: false
      _StatusObjectUserStatus,
      @ObjectModel: { filter.enabled: false,
                       sort.enabled: false }
      _FlxMtPlObj,
      @ObjectModel: { filter.enabled: false,
                      sort.enabled: false }
      _FlxMtPlObjVariant,
      @ObjectModel: { filter.enabled: false,
                      sort.enabled: false }
      _MultiLevel,
      @ObjectModel: { filter.enabled: false,
                      sort.enabled: false }
      _BaseType,
      @ObjectModel: { filter.enabled: false,
                      sort.enabled: false }
      _UsageType,
      @ObjectModel: { filter.enabled: false,
                       sort.enabled: false }
      _ProductText

}