C_ControlGroupingByLanguage

@VDM.viewType: #CONSUMPTION
@AbapCatalog.sqlViewName: 'CCTRLGRPGLANG'
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations:  [ '_CreatedByUser' , '_LastChangedByUser' ]
@ClientHandling.algorithm: #SESSION_VARIABLE
@Metadata.allowExtensions: true

// enable entity set CRUD operation

@ObjectModel.createEnabled: true
@ObjectModel.updateEnabled: true
@ObjectModel.deleteEnabled: true

@ObjectModel.usageType.sizeCategory: 'L'
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.dataClass: #MIXED
@UI.headerInfo: {
    typeName: 'Control Grouping',
    typeNamePlural: 'Control Groupings',
    title: { type: #STANDARD, value: 'ControlGrouping' },
    description: { type: #STANDARD, value: 'TEXT: LegalRegulation' }
}
define view C_ControlGroupingByLanguage
  as select from I_ControlGrouping as ControlGrouping
    cross join   I_Language        as _LanguageJoin
  association [0..1] to I_ControlGroupingTextByLang as _Text on  _Text.LegalRegulation = ControlGrouping.LegalRegulation
                                                             and _Text.ControlGrouping = ControlGrouping.ControlGrouping
                                                             and _Text.Language        = _LanguageJoin.Language
{
      //      @UI.lineItem: [{position: 10 , value: 'ControlGrouping' }]

      @ObjectModel.text.control: #('ASSOCIATED_TEXT_UI_HIDDEN')
      @Consumption.valueHelpDefinition: [{
        entity:  {
          name: 'I_TrdClassfctnLglRglnVH',
          element: 'LegalRegulation' }
        }]
  key ControlGrouping.LegalRegulation,
      @ObjectModel.text.association: '_Text'

  key ControlGrouping.ControlGrouping,
      @ObjectModel.text.control: #('ASSOCIATED_TEXT_UI_HIDDEN')
  key _LanguageJoin.Language,
      CreatedByUser,
      CreationDateTime,
      LastChangedByUser,
      LastChangeDateTime,

      ControlGrouping._LegalRegulation,
      ControlGrouping._LegalRegulationText,
      _Text,
      _CreatedByUser,
      _LastChangedByUser
}