C_CollsResubmissionDraft

DDL: C_COLLSRESUBMISSIONDRAFT Type: view_entity CONSUMPTION

Resubmission Drafts

C_CollsResubmissionDraft is a Consumption CDS View that provides data about "Resubmission Drafts" in SAP S/4HANA. It reads from 1 data source (R_CollsResubmissionDraftTP) and exposes 31 fields with key field ResubmissionUUID. It is exposed through 1 OData service (UI_PROCESSRECEIVABLES_MANAGE).

1 data source(s) Exposed by 1 service(s) 31 fields

Data Sources (1)

SourceAliasJoin Type
R_CollsResubmissionDraftTP R_CollsResubmissionDraftTP projection

Annotations (9)

NameValueLevelField
EndUserText.label Resubmission Drafts view
ObjectModel.representativeKey ResubmissionUUID view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.serviceQuality #C view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
VDM.viewType #CONSUMPTION view
Metadata.allowExtensions true view

OData Services (1)

ServiceBindingVersionContractRelease
UI_PROCESSRECEIVABLES_MANAGE UI_PROCESSRECEIVABLES_MAN V2 C1 NOT_TO_BE_RELEASED_STABLE

Fields (31)

KeyFieldSource TableSource FieldDescription
KEY ResubmissionUUID ResubmissionUUID
DraftUUID DraftUUID
BusinessPartner BusinessPartner
CollectionSegment CollectionSegment
ResubmissionDueDate ResubmissionDueDate
CollResubmissionDateTime CollResubmissionDateTime
NoCntctUntilResubmsnDateIsReq NoCntctUntilResubmsnDateIsReq
ResubmissionReason ResubmissionReason
ResubmissionStatus ResubmissionStatus
CreatedByUser CreatedByUser
CreationDateTime CreationDateTime
ChangedBy ChangedBy
ChangedOnDateTime ChangedOnDateTime
ObjectType ObjectType
ObjectKey ObjectKey
IsActiveEntity IsActiveEntity
HasActiveEntity HasActiveEntity
DraftCreationDateTime DraftCreationDateTime
DraftLastChangedDateTime DraftLastChangedDateTime
BusinessPartnerName _BusinessPartner BusinessPartnerName
CreatedByUserName _CreatedByContactCard UserDescription
ChangedByUserName _ChangedByContactCard UserDescription
virtualCompanyCodebukrs
virtualCompanyCodeNamebutxt
virtualAccountingDocumentfarp_belnr_d
virtualFiscalYearfis_gjahr
virtualAccountingDocumentItemfis_buzei
_BusinessPartner _BusinessPartner
_CollectionSegment _CollectionSegment
_ResubmissionReason _ResubmissionReason
_ResubmissionStatus _ResubmissionStatus 
@EndUserText: { label: 'Resubmission Drafts' }
@ObjectModel: { representativeKey: 'ResubmissionUUID',
                semanticKey:       [ 'ResubmissionUUID' ],
                usageType:         { dataClass:      #TRANSACTIONAL,
                                     sizeCategory:   #L,
                                     serviceQuality: #C } }
@AccessControl: { authorizationCheck: #CHECK,
                  privilegedAssociations: ['_CreatedByContactCard',
                                           '_ChangedByContactCard' ],
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED } }
@VDM: { viewType: #CONSUMPTION,
        usage: { type: [ #TRANSACTIONAL_PROCESSING_SERVICE ] } }
@Metadata: { allowExtensions: true }

define root view entity C_CollsResubmissionDraft
  as projection on R_CollsResubmissionDraftTP

{

          // VDM Fields

  key     ResubmissionUUID,
          DraftUUID,
          @ObjectModel: { text: { element: [ 'BusinessPartnerName' ] } }
          BusinessPartner,

          @ObjectModel: { text: { element: ['CollectionSegmentName'] } }
          CollectionSegment,

          ResubmissionDueDate,
          CollResubmissionDateTime,
          NoCntctUntilResubmsnDateIsReq,

          @ObjectModel: { text: { element: ['ResubmissionReasonName'] } }
          ResubmissionReason,

          @ObjectModel: { text: { element: ['ResubmissionStatusName'] } }
          ResubmissionStatus,

          @ObjectModel: { text: { element: ['CreatedByUserName'] } }
          CreatedByUser,

          CreationDateTime,

          @ObjectModel: { text: { element: ['ChangedByUserName'] } }
          ChangedBy,

          ChangedOnDateTime,
          ObjectType,
          ObjectKey,
          IsActiveEntity,
          HasActiveEntity,
          DraftCreationDateTime,
          DraftLastChangedDateTime,

          // Text Elements

          @Semantics: { text: true }
          _BusinessPartner.BusinessPartnerName             as BusinessPartnerName,

          @Semantics: { text: true }
          _CollectionSegment._Text.CollectionSegmentName   as CollectionSegmentName  : localized,

          @Semantics: { text: true }
          _ResubmissionReason._Text.ResubmissionReasonName as ResubmissionReasonName : localized,

          @Semantics: { text: true }
          _ResubmissionStatus._Text.ResubmissionStatusName as ResubmissionStatusName : localized,

          @Semantics: { text: true }
          _CreatedByContactCard.UserDescription            as CreatedByUserName,

          @Semantics: { text: true }
          @Semantics.name.fullName:null
          _ChangedByContactCard.UserDescription            as ChangedByUserName,

          @ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COLL_RSM_VE' }
  virtual DaysUntilResubmsnBasedCritlty : char1,

          @ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COLL_RSM_VE',
                          text: { element: [ 'CompanyCodeName' ] } }
  virtual CompanyCode                   : bukrs,

          @ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COLL_RSM_VE' }
          @Semantics: { text: true }
  virtual CompanyCodeName               : butxt,

          @ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COLL_RSM_VE' }
  virtual AccountingDocument            : farp_belnr_d,

          @ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COLL_RSM_VE' }
  virtual FiscalYear                    : fis_gjahr,

          @ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COLL_RSM_VE' }
  virtual AccountingDocumentItem        : fis_buzei,

          // Exposed Associations

          _BusinessPartner,
          _ChangedByContactCard : redirected to C_RblsMgmtUserContactCard,
          _CollectionSegment,
          _CreatedByContactCard : redirected to C_RblsMgmtUserContactCard,
          _ResubmissionReason,
          _ResubmissionStatus

}

Learn More