C_CollsInvoiceRelatedPrms2P

@Metadata: { allowExtensions: true }
@VDM: { usage: { type:     [ #TRANSACTIONAL_PROCESSING_SERVICE ] },
                 viewType: #CONSUMPTION }
@AccessControl: { authorizationCheck: #CHECK }
@ObjectModel: { usageType: { serviceQuality: #X,
                             sizeCategory:   #L,
                             dataClass:      #TRANSACTIONAL },
                representativeKey: 'CaseUniqueID',
                semanticKey: [ 'CaseUniqueID',
                               'CaseID' ] }
@EndUserText: { label: 'Promise To Pay Related to Invoice' }

define root view entity C_CollsInvoiceRelatedPrms2P
  as projection on I_CollsInvoiceRelatedPrms2P
{
      //I_CollsInvoiceRelatedObject

  key LogicalSystem,
  key ObjectType,
  key ObjectKey,
  key RelationToLinkedObject,
  key CaseUniqueID,
      ObjectClassification,
      ObjectIsConfirmed,
      ObjectIsVoided,

      @ObjectModel: { text: { element: [ 'CompanyCodeName' ] } }
      CompanyCode,

      AccountingDocument,
      FiscalYear,
      AccountingDocumentItem,

      // Promise to Pay data

      @ObjectModel: { text: { element: [ 'CustomerName' ] } }
      _CollsPromiseToPay.Customer,

      _CollsPromiseToPay.PromisedAmount,
      _CollsPromiseToPay.PaidAmount,
      _CollsPromiseToPay.PromiseToPayUUID,

      @ObjectModel: { text: { element: [ 'CurrencyName' ] } }
      _CollsPromiseToPay.Currency,

      _CollsPromiseToPay.DueDate,
      _CollsPromiseToPay.PromiseToPayDate,
      _CollsPromiseToPay.LastPaymentDate,

      @ObjectModel: { text: { element: [ 'PromiseToPayStatusName' ] } }
      _CollsPromiseToPay.PromiseToPayStatus,

      _CollsPromiseToPay.PromiseToPayLevel,
      _CollsPromiseToPay.PromiseToPayGivenByPersonName,
      _CollsPromiseToPay.ContactPersonEmailAddress,
      _CollsPromiseToPay.ContactPersonPhoneNumber,
      _CollsPromiseToPay.ContactPersonFaxNumber,
      _CollsPromiseToPay.ContactPersonFaxCountry,
      _CollsPromiseToPay.ContactPerson,
      _CollsPromiseToPay.NumberOfInstallments,
      _CollsPromiseToPay.PaidOnScheduleAmount,
      _CollsPromiseToPay.PaidOffScheduleAmount,
      _CollsPromiseToPay.NextInstallmentDueDate,
      _CollsPromiseToPay.NextInstallmentAmount,
      _CollsPromiseToPay.CaseID,
      _CollsPromiseToPay.CaseExternalReference,
      _CollsPromiseToPay.Prms2PToInvoiceGroupRefUUID,

      @ObjectModel: { text: { element: [ 'CreatedByUserName' ] } }
      @Consumption: { semanticObject: 'BusinessUser' }
      CaseCreatedBy,

      _CollsPromiseToPay.CaseCreatedOn,

      @ObjectModel: { text: { element: [ 'LastChangedByUserName' ] } }
      @Consumption: { semanticObject: 'BusinessUser' }
      CaseLastChangedBy,

      _CollsPromiseToPay.CaseLastChangedOn,

      @ObjectModel: { text: { element: [ 'ClosedByUserFullName' ] } }
      @Consumption: { semanticObject: 'BusinessUser' }
      CaseClosedBy,

      _CollsPromiseToPay.CaseClosedTime,

      // Text Elements

      _CollsPromiseToPay._CompanyCode.CompanyCodeName                          as CompanyCodeName,
      _CollsPromiseToPay._Customer.CustomerName                                as CustomerName,
      _CollsPromiseToPay._CollsPromiseToPayStatus._Text.PromiseToPayStatusName as PromiseToPayStatusName : localized,
      _CollsPromiseToPay._Country._Text.CountryName                            as CountryName            : localized,
      _CollsPromiseToPay._Currency._Text.CurrencyName                          as CurrencyName           : localized,
      _CollsPromiseToPay._CreatedByContactCard.UserDescription                 as CreatedByUserName,
      _CollsPromiseToPay._ChangedByContactCard.UserDescription                 as LastChangedByUserName,
      _CollsPromiseToPay._ClosedByContactCard.UserDescription                  as ClosedByUserFullName,

      // Exposed Associations

      _CaseAttribute,
      _CollsPromiseToPay,
      _CreatedByContactCard : redirected to C_RblsMgmtUserContactCard,
      _ChangedByContactCard : redirected to C_RblsMgmtUserContactCard,
      _ClosedByContactCard  : redirected to C_RblsMgmtUserContactCard

}