C_CollectionsContactDraft

DDL: C_COLLECTIONSCONTACTDRAFT Type: view_entity CONSUMPTION

Collections Contacts Drafts

C_CollectionsContactDraft is a Consumption CDS View that provides data about "Collections Contacts Drafts" in SAP S/4HANA. It reads from 1 data source (R_CollectionsContactDraftTP) and exposes 25 fields with key fields RelationshipNumber, BusinessPartnerCompany, BusinessPartnerPerson, CollectionSegment, DraftUUID. It is exposed through 1 OData service (UI_PROCESSRECEIVABLES_MANAGE).

1 data source(s) Exposed by 1 service(s) 25 fields

Data Sources (1)

SourceAliasJoin Type
R_CollectionsContactDraftTP R_CollectionsContactDraftTP projection

Annotations (9)

NameValueLevelField
EndUserText.label Collections Contacts Drafts view
ObjectModel.representativeKey BusinessPartnerPerson view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.serviceQuality #D view
VDM.viewType #CONSUMPTION view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
Metadata.allowExtensions true view

OData Services (1)

ServiceBindingVersionContractRelease
UI_PROCESSRECEIVABLES_MANAGE UI_PROCESSRECEIVABLES_MAN V2 C1 NOT_TO_BE_RELEASED_STABLE

Fields (25)

KeyFieldSource TableSource FieldDescription
KEY RelationshipNumber RelationshipNumber
KEY BusinessPartnerCompany BusinessPartnerCompany
KEY BusinessPartnerPerson BusinessPartnerPerson
KEY CollectionSegment CollectionSegment
KEY DraftUUID DraftUUID
FirstName FirstName
LastName LastName
PhoneNumber PhoneNumber
MobileNumber MobileNumber
FaxNumber FaxNumber
EmailAddress EmailAddress
ContactPersonFunction ContactPersonFunction
ContactPersonDepartment ContactPersonDepartment
IsActiveEntity IsActiveEntity
HasActiveEntity HasActiveEntity
DraftCreationDateTime DraftCreationDateTime
DraftLastChangedDateTime DraftLastChangedDateTime
BusinessPartnerName _BusinessPartnerCompany BusinessPartnerName
_BpContactToAddress _BpContactToAddress
_BPContactToFuncAndDept _BPContactToFuncAndDept
_BusinessPartnerCompany _BusinessPartnerCompany
_BusinessPartnerPerson _BusinessPartnerPerson
_CollectionSegment _CollectionSegment
_ContactPersondepartment _ContactPersondepartment
_ContactPersonFunction _ContactPersonFunction 
@EndUserText: { label: 'Collections Contacts Drafts' }
@ObjectModel: { representativeKey: 'BusinessPartnerPerson',
                semanticKey:       [ 'RelationshipNumber',
                                     'BusinessPartnerCompany',
                                     'BusinessPartnerPerson',
                                     'CollectionSegment' ],
                usageType:         { dataClass:      #TRANSACTIONAL,
                                     sizeCategory:   #L,
                                     serviceQuality: #D } }
@VDM: { viewType: #CONSUMPTION,
        usage:    { type: [ #TRANSACTIONAL_PROCESSING_SERVICE ] } }
@AccessControl: { authorizationCheck: #CHECK,
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED } }
@Metadata: { allowExtensions: true }

define root view entity C_CollectionsContactDraft
  as projection on R_CollectionsContactDraftTP
{

          // VDM Fields

  key     RelationshipNumber,

          @ObjectModel: { text: { element: [ 'BusinessPartnerName' ] } }
  key     BusinessPartnerCompany,

          @ObjectModel: { text: { element: [ 'ContactPersonName' ] } }
  key     BusinessPartnerPerson,

          @ObjectModel: { text: { element: [ 'CollectionSegmentName' ] } }
  key     CollectionSegment,

  key     DraftUUID,
          FirstName,
          LastName,
          PhoneNumber,
          MobileNumber,
          FaxNumber,
          EmailAddress,

          @ObjectModel: { text: { element: [ 'ContactPersonFunctionName' ] } }
          ContactPersonFunction,

          @ObjectModel: { text: { element: [ 'ContactPersonDepartmentName' ] } }
          ContactPersonDepartment,

          IsActiveEntity,
          HasActiveEntity,
          DraftCreationDateTime,
          DraftLastChangedDateTime,

          // Text Elements

          _BusinessPartnerCompany.BusinessPartnerName                as BusinessPartnerName,
          _CollectionSegment._Text.CollectionSegmentName             as CollectionSegmentName       : localized,
          _ContactPersonFunction._Text.ContactPersonFunctionName     as ContactPersonFunctionName   : localized,
          _ContactPersondepartment._Text.ContactPersonDepartmentName as ContactPersonDepartmentName : localized,

          @ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COLL_CONT_VE' }
  virtual ContactPersonName          : businesspartnername,

          @ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COLL_CONT_VE' }
  virtual CollsCntctIsDfltCntctPersn : udm_is_default_contact,

          // Exposed Associations

          _BpContactToAddress,
          _BPContactToFuncAndDept,
          _BusinessPartnerCompany,
          _BusinessPartnerPerson,
          _CollectionSegment,
          _ContactPersondepartment,
          _ContactPersonFunction
          
}

Learn More