C_CollectionContactTP

DDL: C_COLLECTIONCONTACTTP Type: view_entity CONSUMPTION

Collection Contact - Consumption

C_CollectionContactTP is a Consumption CDS View that provides data about "Collection Contact - Consumption" in SAP S/4HANA. It reads from 1 data source (R_CollectionContactTP) and exposes 23 fields with key fields RelationshipNumber, BusinessPartnerCompany, BusinessPartnerPerson, CollectionSegment. It is exposed through 2 OData services (UI_COLLECTION_CONTACT_MANAGE, UI_PROCESSRECEIVABLES_MANAGE).

1 data source(s) Exposed by 2 service(s) 23 fields

Data Sources (1)

SourceAliasJoin Type
R_CollectionContactTP R_CollectionContactTP projection

Annotations (9)

NameValueLevelField
EndUserText.label Collection Contact - Consumption view
ObjectModel.representativeKey BusinessPartnerPerson view
ObjectModel.usageType.dataClass #TRANSACTIONAL view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.serviceQuality #X view
VDM.viewType #CONSUMPTION view
AccessControl.authorizationCheck #CHECK view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
Metadata.allowExtensions true view

OData Services (2)

ServiceBindingVersionContractRelease
UI_COLLECTION_CONTACT_MANAGE UI_COLL_CONTACT_MANAGE V2 C1 NOT_TO_BE_RELEASED_STABLE
UI_PROCESSRECEIVABLES_MANAGE UI_PROCESSRECEIVABLES_MAN V2 C1 NOT_TO_BE_RELEASED_STABLE

Fields (23)

KeyFieldSource TableSource FieldDescription
KEY RelationshipNumber RelationshipNumber
KEY BusinessPartnerCompany BusinessPartnerCompany
KEY BusinessPartnerPerson BusinessPartnerPerson
KEY CollectionSegment CollectionSegment
BusinessPartnerPersonForEdit BusinessPartnerPersonForEdit
FirstName FirstName
LastName LastName
PhoneNumber PhoneNumber
MobileNumber MobileNumber
FaxNumber FaxNumber
EmailAddress EmailAddress
ContactPersonFunction ContactPersonFunction
ContactPersonDepartment ContactPersonDepartment
BusinessPartnerName _BusinessPartnerCompany BusinessPartnerName
virtualCustomerkunnr
_BpContactToAddress _BpContactToAddress
_BPContactToFuncAndDept _BPContactToFuncAndDept
_BusinessPartnerCompany _BusinessPartnerCompany
_BusinessPartnerPerson _BusinessPartnerPerson
_CollectionSegment _CollectionSegment
_ContactPersonDepartment _ContactPersonDepartment
_ContactPersonFunction _ContactPersonFunction
_CollectionsBPQuickView _CollectionsBPQuickView 
@EndUserText: { label: 'Collection Contact - Consumption' }
@ObjectModel: { representativeKey: 'BusinessPartnerPerson',
	            semanticKey:       [ 'RelationshipNumber',
	                                 'BusinessPartnerCompany',
                             		 'BusinessPartnerPerson',
                                     'CollectionSegment' ],
	            usageType:         { dataClass:      #TRANSACTIONAL,
		                             sizeCategory:   #L,
		                             serviceQuality: #X } }
@VDM: { viewType: #CONSUMPTION,
        usage:    { type: [ #TRANSACTIONAL_PROCESSING_SERVICE ] } }
@AccessControl: { authorizationCheck: #CHECK,
                  personalData: { blocking: #BLOCKED_DATA_EXCLUDED } }
@Metadata: { allowExtensions: true }

define root view entity C_CollectionContactTP
  provider contract transactional_query
  as projection on R_CollectionContactTP
{
          // VDM Fields

  key     RelationshipNumber,

          @ObjectModel: { text: { element: [ 'BusinessPartnerName' ] } }
  key     BusinessPartnerCompany,

          @ObjectModel: { text: { element: [ 'ContactPersonName' ] } }
  key     BusinessPartnerPerson,

          @ObjectModel: { text: { element: [ 'CollectionSegmentName' ] } }
  key     CollectionSegment,

          BusinessPartnerPersonForEdit,
          FirstName,
          LastName,
          PhoneNumber,
          MobileNumber,
          FaxNumber,
          EmailAddress,

          @ObjectModel: { text: { element: [ 'ContactPersonFunctionName' ] } }
          ContactPersonFunction,

          @ObjectModel: { text: { element: [ 'ContactPersonDepartmentName' ] } }
          ContactPersonDepartment,

          // Text Elements

          @Semantics: { text: true }
          _BusinessPartnerCompany.BusinessPartnerName                as BusinessPartnerName,

          @Semantics: { text: true }
          _CollectionSegment._Text.CollectionSegmentName             as CollectionSegmentName       : localized,

          @Semantics: { text: true }
          _ContactPersonFunction._Text.ContactPersonFunctionName     as ContactPersonFunctionName   : localized,

          @Semantics: { text: true }
          _ContactPersonDepartment._Text.ContactPersonDepartmentName as ContactPersonDepartmentName : localized,

          // Virtual Elements

          @ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COLL_CONT_VE' }
  virtual CollsCntctIsDfltCntctPersn : udm_is_default_contact,

          @ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COLL_CONT_VE' }
  virtual ContactPersonName          : businesspartnername,

          @ObjectModel: { virtualElementCalculatedBy: 'ABAP:CL_COLL_CONT_VE' }
  virtual Customer                   : kunnr,

          // Exposed Associations

          _BpContactToAddress,
          _BPContactToFuncAndDept,
          _BusinessPartnerCompany,
          _BusinessPartnerPerson,
          _CollectionSegment,
          _ContactPersonDepartment,
          _ContactPersonFunction,
          _CollectionsBPQuickView

}

Learn More