C_CollabnApplTranspOrderStop

@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.sqlViewName: 'CCOLLABNAPPLSTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #('TRANSACTIONAL_DATA')
@AccessControl.privilegedAssociations: ['_TransportationOrderItem']
@VDM.viewType: #CONSUMPTION
@ObjectModel.representativeKey: 'TransportationOrderStopUUID'
@ObjectModel.semanticKey: ['TransportationOrderStop']
@ObjectModel.usageType.dataClass:#TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Transportation Order Stop'
define view C_CollabnApplTranspOrderStop
  as select from I_TransportationOrderStop as TransportationOrderStop
   inner join   P_CollabnApplCarrierUser as CollabnApplCarrierUser on CollabnApplCarrierUser.UserID = $session.user
  
  association [0..1] to C_CollabnApplFreightOrdForConf as _CollabnApplFreightOrdForConf  on $projection.TransportationOrderUUID = _CollabnApplFreightOrdForConf.TransportationOrderUUID
  association [0..*] to C_CollabnApplTranspOrderItem   as _TransportationOrderItem       on $projection.TransportationOrderStopUUID = _TransportationOrderItem.SourceStopUUID
                                                                                         or $projection.TransportationOrderStopUUID = _TransportationOrderItem.DestinationStopUUID
  association [0..1] to I_TranspOrdStopSqncPosition    as _TranspOrdStopSequencePosition on $projection.TranspOrdStopSequencePosition = _TranspOrdStopSequencePosition.TranspOrdStopSequencePosition
  association [0..1] to I_CollabnApplFrtOrdStopCat     as _CollabnApplFrtOrdStopCat      on $projection.TranspOrdStopCategory = _CollabnApplFrtOrdStopCat.TranspOrdStopCategory
{
  key TransportationOrderStop.TransportationOrderStopUUID,
      TransportationOrderStop.TransportationOrderUUID,
      TransportationOrderStop.TransportationOrderStop,
      TransportationOrderStop._TransportationOrder.TransportationOrderCategory                                                as TransportationOrderCategory,
      TransportationOrderStop._TransportationOrder.TransportationOrderType                                                    as TransportationOrderType,      
      @Semantics.text:true
      _CollabnApplFrtOrdStopCat._Text[1: Language = $session.system_language ].TranspOrdStopCategoryDesc                      as TranspOrdStopCategoryDesc,
      @ObjectModel.text.element: ['TranspOrdStopCategoryDesc']
      TransportationOrderStop.TranspOrdStopCategory,

      @Semantics.text:true
      _TranspOrdStopSequencePosition._Text[1: Language = $session.system_language ].TranspOrdStopSequencePosDesc              as TranspOrdStopSequencePosDesc,
      @ObjectModel.text.element: ['TranspOrdStopSequencePosDesc']
      TransportationOrderStop.TranspOrdStopSequencePosition,

      @ObjectModel.text.element: ['LocationDescription']
      TransportationOrderStop.LocationId,
      @Semantics.text:true
      TransportationOrderStop._Locationdescr.LocationDescription                                                              as LocationDescription,
      TransportationOrderStop._Locationdescr.AddressObjectDescription                                                         as AddressObjectDescription,
      @Semantics.dateTime: true
      TransportationOrderStop.TranspOrdStopAccptblStrtDteTme,
      @Semantics.dateTime: true
      TransportationOrderStop.TranspOrdStopAccptblEndDteTme,
      @Semantics.dateTime: true
      TransportationOrderStop.TranspStopCarrConfStrtDteTme,
      @Semantics.dateTime: true
      TransportationOrderStop.TranspStopCarrConfEndDteTme,
      @Semantics.dateTime: true
      ( case when TransportationOrderStop.TranspOrdStopReqStartDteTme is initial
             then TransportationOrderStop.TranspOrdStopPlanTranspDteTme
             else TransportationOrderStop.TranspOrdStopReqStartDteTme  end )                                                  as TranspOrdStopReqStartDteTme,
      @Semantics.dateTime: true
      ( case when TransportationOrderStop.TranspOrdStopReqEndDteTme is initial
             then TransportationOrderStop.TranspOrdStopPlanTranspDteTme
             else TransportationOrderStop.TranspOrdStopReqEndDteTme  end )                                                    as TranspOrdStopReqEndDteTme,

      _CollabnApplFreightOrdForConf.Carrier,
      _CollabnApplFreightOrdForConf.TranspOrdResponsiblePerson,

      /*Association*/
      _CollabnApplFreightOrdForConf._FrtOrderResponsiblePerson,
      _TransportationOrderItem

} where ( TransportationOrderStop.TranspOrdStopCategory = 'I' or TransportationOrderStop.TranspOrdStopCategory = 'O' )
    and CollabnApplCarrierUser.BusinessPartnerCompany = _CollabnApplFreightOrdForConf.Carrier