C_CollabnApplMngCarrInvcNote

DDL: C_COLLABNAPPLMNGCARRINVCNOTE Type: view_entity CONSUMPTION

Carrier Invoice Notes

C_CollabnApplMngCarrInvcNote is a Consumption CDS View that provides data about "Carrier Invoice Notes" in SAP S/4HANA. It reads from 1 data source (I_TextCollection) and exposes 15 fields with key field TextCollectionContentUUID. It has 1 association to related views. It is exposed through 1 OData service (UI_COLLABNAPPLFRTINVC). It is used in 1 Fiori application: Manage Freight Invoices.

1 data source(s) Exposed by 1 service(s) Used in 1 Fiori app(s) 15 fields

Data Sources (1)

SourceAliasJoin Type
I_TextCollection TextCollectionRoot from

Associations (1)

CardinalityTargetAliasCondition
[0..1] I_User _TextCollectionTextCrtedByUser $projection.TextCollectionTextCrtedByUser = _TextCollectionTextCrtedByUser.UserID

Annotations (8)

NameValueLevelField
AccessControl.authorizationCheck #PRIVILEGED_ONLY view
AccessControl.personalData.blocking #BLOCKED_DATA_EXCLUDED view
EndUserText.label Carrier Invoice Notes view
Metadata.ignorePropagatedAnnotations true view
ObjectModel.usageType.serviceQuality #C view
ObjectModel.usageType.sizeCategory #XL view
ObjectModel.usageType.dataClass #MIXED view
VDM.viewType #CONSUMPTION view

OData Services (1)

ServiceBindingVersionContractRelease
UI_COLLABNAPPLFRTINVC UI_COLLABNAPPLFRTINVC V2 C1 NOT_RELEASED

Fiori Apps (1)

App IDApp NameTypeDescription
F7106 Manage Freight Invoices Transactional Manage Freight Invoices is a collaboration application where service provider representatives of a carrier organization manage invoices submitted to the shipper.

Manage Freight Invoices

Business Role: Logistics Service Provider Representative

With this app, as a carrier or a logistic service provider, you can manage invoices that you've submitted to the shippers.

Fields (15)

KeyFieldSource TableSource FieldDescription
KEY TextCollectionContentUUID TextCollectionContent TextCollectionContentUUID
TextCollectionTypeUUID TextCollectionType TextCollectionTypeUUID
TextCollectionUUID I_TextCollection TextCollectionUUID
TextCollectionSchema I_TextCollection TextCollectionSchema
TextCollectionType TextCollectionType TextCollectionType
HostDocumentBusinessObjectUUID I_TextCollection HostDocumentBusinessObjectUUID
HostDocumentBusObjNodeUUID I_TextCollection HostDocumentBusObjNodeUUID
HostDocumentUUID I_TextCollection HostDocumentUUID
TextCollectionTextCrtedByUser TextCollectionType TextCollectionTextCrtedByUser
UserDescription _TextCollectionTextCrtedByUser UserDescription
TextCollectionTextCrtedDteTime TextCollectionType TextCollectionTextCrtedDteTime
TextCollectionTextChgdDateTime TextCollectionType TextCollectionTextChgdDateTime
Language TextCollectionType Language
TextCollectionContentText TextCollectionContent TextCollectionContentText
_CollabnApplCarrierInvoice _CollabnApplCarrierInvoice 
@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@EndUserText.label: 'Carrier Invoice Notes'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.usageType:{
    serviceQuality: #C,
    sizeCategory: #XL,
    dataClass: #MIXED
}
@VDM.viewType: #CONSUMPTION
@VDM.usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
define view entity C_CollabnApplMngCarrInvcNote
  as select from            I_TextCollection          as TextCollectionRoot
    left outer to many join I_TextCollectionType      as TextCollectionType       on TextCollectionRoot.TextCollectionUUID = TextCollectionType.TextCollectionUUID
    left outer to one join  I_TextCollectionContent   as TextCollectionContent    on TextCollectionType.TextCollectionTypeUUID = TextCollectionContent.TextCollectionTypeUUID

  association        to parent C_CollabnApplCarrierInvoice as _CollabnApplCarrierInvoice     on $projection.HostDocumentUUID = _CollabnApplCarrierInvoice.SuplrFrtInvcReqUUID
  association [0..1] to I_User                             as _TextCollectionTextCrtedByUser on $projection.TextCollectionTextCrtedByUser = _TextCollectionTextCrtedByUser.UserID

{
  key TextCollectionContent.TextCollectionContentUUID   as TextCollectionContentUUID,

      TextCollectionType.TextCollectionTypeUUID         as TextCollectionTypeUUID,

      TextCollectionRoot.TextCollectionUUID             as TextCollectionUUID,

      TextCollectionRoot.TextCollectionSchema           as TextCollectionSchema,

      TextCollectionType.TextCollectionType             as TextCollectionType,

      TextCollectionRoot.HostDocumentBusinessObjectUUID as HostDocumentBusinessObjectUUID,

      TextCollectionRoot.HostDocumentBusObjNodeUUID     as HostDocumentBusObjNodeUUID,

      @UI.hidden: true
      TextCollectionRoot.HostDocumentUUID               as HostDocumentUUID,

      @Semantics.user.createdBy: true
      @ObjectModel.text.element: ['UserDescription']
      @UI.hidden: true
      TextCollectionType.TextCollectionTextCrtedByUser  as TextCollectionTextCrtedByUser,
      @Semantics.text: true
      _TextCollectionTextCrtedByUser.UserDescription,

      @Semantics.systemDate.createdAt: true
      @Semantics.dateTime: true
      TextCollectionType.TextCollectionTextCrtedDteTime as TextCollectionTextCrtedDteTime,

      @Semantics.systemDate.lastChangedAt: true
      @Semantics.dateTime: true
      TextCollectionType.TextCollectionTextChgdDateTime as TextCollectionTextChgdDateTime,

      TextCollectionType.Language                       as Language,

      TextCollectionContent.TextCollectionContentText   as TextCollectionContentText,

      //Association

      _CollabnApplCarrierInvoice
}
where
       TextCollectionRoot.DocumentHasText                                            = 'X'
  and  TextCollectionRoot.HostDocumentBusinessObjectUUID                             = hextobin('80E0ED0A0DD11DDEB4EA8E4375A74E6B')
  and  TextCollectionRoot.HostDocumentBusObjNodeUUID                                 = hextobin('80E0ED0A0DD11DEEB4EA8E44A108915B')
  and  TextCollectionType.TextCollectionTypeIsInternal                               = ' '

Learn More