C_CollabnApplFreightRFQNote

@AccessControl.authorizationCheck: #PRIVILEGED_ONLY
@AccessControl.personalData.blocking: #BLOCKED_DATA_EXCLUDED
@VDM.viewType: #CONSUMPTION

@VDM.usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
@ObjectModel.representativeKey: 'TextCollectionContentUUID'
@ObjectModel.semanticKey: ['TextCollectionContentUUID']
@ObjectModel.usageType.dataClass: #MASTER
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL

@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true

@EndUserText.label: 'Freight RFQ Notes'
define view entity C_CollabnApplFreightRFQNote
  as select from            I_TextCollection            as TextCollectionRoot
    left outer to many join I_TextCollectionType        as TextCollectionType    on TextCollectionRoot.TextCollectionUUID = TextCollectionType.TextCollectionUUID
    left outer to one join  I_TextCollectionContent     as TextCollectionContent on TextCollectionType.TextCollectionTypeUUID = TextCollectionContent.TextCollectionTypeUUID
  association [0..*] to C_CollabnApplFreightRFQ         as _CollabnApplFreightRFQ  on $projection.TransportationOrderUUID = _CollabnApplFreightRFQ.TransportationOrderUUID
  association [0..1] to I_User                          as _TextCollectionTextCrtedByUser on $projection.TextCollectionTextCrtedByUser = _TextCollectionTextCrtedByUser.UserID
{
  key TextCollectionContent.TextCollectionContentUUID   as TextCollectionContentUUID,

      TextCollectionType.TextCollectionTypeUUID         as TextCollectionTypeUUID,

      TextCollectionRoot.TextCollectionUUID             as TextCollectionUUID,

      TextCollectionRoot.TextCollectionSchema           as TextCollectionSchema,

      TextCollectionType.TextCollectionType             as TextCollectionType,

      TextCollectionRoot.HostDocumentUUID               as TransportationOrderUUID,

      TextCollectionRoot.HostDocumentBusinessObjectUUID as HostDocumentBusinessObjectUUID,

      TextCollectionRoot.HostDocumentBusObjNodeUUID     as HostDocumentBusObjNodeUUID,

      @Semantics.user.createdBy: true
      @ObjectModel.text.element: ['UserDescription']
      @UI.hidden: true
      TextCollectionType.TextCollectionTextCrtedByUser  as TextCollectionTextCrtedByUser,
      @Semantics.text: true
      _TextCollectionTextCrtedByUser.UserDescription,

      @Semantics.systemDate.createdAt: true
      @Semantics.dateTime: true
      TextCollectionType.TextCollectionTextCrtedDteTime as TextCollectionTextCrtedDteTime,

      @Semantics.systemDate.lastChangedAt: true
      @Semantics.dateTime: true
      TextCollectionType.TextCollectionTextChgdDateTime as TextCollectionTextChgdDateTime,

      TextCollectionType.Language                       as Language,

      TextCollectionContent.TextCollectionContentText   as TextCollectionContentText,

      //Association

      _CollabnApplFreightRFQ
}
where
      TextCollectionRoot.DocumentHasText                = 'X'
  and TextCollectionRoot.HostDocumentBusinessObjectUUID = hextobin('80E0ED0A0C021DEE8CE07DB4266D17C4')
  and TextCollectionRoot.HostDocumentBusObjNodeUUID     = hextobin('80E0ED0A0C021DDE8CE07DB5DFAD0818')
  and TextCollectionType.TextCollectionTypeIsInternal   = ' '