C_CollabnApplFreightQuotation

@AbapCatalog.sqlViewName: 'CCOLLABNFQ'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl: {authorizationCheck: #CHECK,
                 personalData.blocking:#('TRANSACTIONAL_DATA')}
@AccessControl.privilegedAssociations: ['_CollabnApplFrtQuotationNote']
@ClientHandling.algorithm: #SESSION_VARIABLE
@VDM.viewType: #CONSUMPTION

@ObjectModel.representativeKey: 'FreightQuotationUUID'
@ObjectModel.semanticKey: ['FreightQuotation']
@ObjectModel.usageType.dataClass:#TRANSACTIONAL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL

@Metadata.allowExtensions: true
@Metadata.ignorePropagatedAnnotations: true
@EndUserText.label: 'Freight Quotation'
define root view C_CollabnApplFreightQuotation
  as select from P_CollabnApplFreightQuotation
  association [1..*] to C_CollabnApplFrtOrdQtanStop   as _TransportationOrderStop     on  $projection.RefTransportationOrderUUID = _TransportationOrderStop.RefTransportationOrderUUID
                                                                                      and $projection.FreightQuotationUUID       = _TransportationOrderStop.TenderingResponseUUID
  association [0..*] to C_CollabnApplFrtQuotationNote as _CollabnApplFrtQuotationNote on  $projection.TransportationOrderUUID = _CollabnApplFrtQuotationNote.TransportationOrderUUID
  association [1]    to I_TransportationOrderStop     as _SourceStop                  on  $projection.RefTransportationOrderUUID    = _SourceStop.TransportationOrderUUID
                                                                                      and _SourceStop.TranspOrdStopSequencePosition = 'F'
  association [1]    to I_TransportationOrderStop     as _DestinationStop             on  $projection.RefTransportationOrderUUID         = _DestinationStop.TransportationOrderUUID
                                                                                      and _DestinationStop.TranspOrdStopSequencePosition = 'L'

{
  key FreightQuotationUUID,
      FreightRequestForQuotationUUID,
      TransportationOrderUUID,
      RefTransportationOrderUUID,
      FreightRequestForQuotation,
      TenderingUUID,
      FreightQuotation,
      TenderingResponseSqncNumber,
      TenderingRequestedCarrier,
      _RefTransportationOrder.TransportationOrderCategory,
      _RefTransportationOrder.TransportationOrderType,

      @Semantics.text: true
      _TenderingAwardStatus._Text[1: Language = $session.system_language ].TenderingAwardStatusDesc                                         as TenderingAwardStatusDesc,
      @ObjectModel.text.element: ['TenderingAwardStatusDesc']
      @Consumption.valueHelpDefinition: [{ entity: {name: 'C_TenderingAwardStatusVH'  , element: 'TenderingAwardStatus'}}]
      TenderingAwardStatus,
      cast (case when TenderingAwardStatus = 'AW' then 3
                 when TenderingAwardStatus = 'RE' then 1
                 when TenderingAwardStatus = 'PE' then 2
                 when TenderingAwardStatus = 'EP' then 2 end as tndrg_awardstatus_criticality )                                             as TndrgAwardStatusCriticality,

      @Semantics.text: true
      _TenderingResponseCode._Text[1: Language = $session.system_language ].TenderingResponseCodeDesc                                       as TenderingResponseCodeDesc,
      @ObjectModel.text.element: ['TenderingResponseCodeDesc']
      @Consumption.valueHelpDefinition: [{ entity: {name: 'C_TenderingResponseCodeVH'  , element: 'TenderingResponseCode'}}]
      TenderingResponseCode,
      @Semantics.text: true
      _TenderingRejectionReason._Text[1: Language = $session.system_language]. TenderingRejectionReasonDesc                                 as TenderingRejectionReasonDesc,
      @ObjectModel.text.element: ['TenderingRejectionReasonDesc']
      TenderingRejectionReason,

      TenderingSubmissionDateTime,
      @Semantics.currencyCode: true
      TndrgRspSubmdAmtCrcy,
      @Semantics.amount.currencyCode: 'TndrgRspSubmdAmtCrcy'
      TndrgRspSubmdAmt,

      @Consumption.filter.hidden: true
      _RefTransportationOrder.TranspOrdDistanceUnit                                                                                         as TranspOrdDistanceUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdDistanceUnit'
      _RefTransportationOrder.TranspOrdDistance                                                                                             as TranspOrdDistance,
      @Consumption.filter.hidden: true
      _RefTransportationOrder.TranspOrdNetDurationUnit                                                                                      as TranspOrdNetDurationUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdNetDurationUnit'
      _RefTransportationOrder.TranspOrdNetDuration                                                                                          as TranspOrdNetDuration,
      @ObjectModel.text.element: ['MeansOfTransportDesc']
      _RefTransportationOrder.MeansOfTransport                                                                                              as TranspMeansOfTransport,
      @Semantics.text: true
      _RefTransportationOrder._MeansOfTransport._Text[1: Language = $session.system_language].MeansOfTransportDesc                          as MeansOfTransportDesc,
      @Consumption.valueHelpDefinition: [{ entity: {name: 'C_TranspPurchasingOrgVH' , element: 'OrganizationalUnitExternalID'}}]
      @ObjectModel.text.element: ['PurchasingOrganizationName']
      _RefTransportationOrder.PurchasingOrgExternalID,
      @Semantics.text: true
      _RefTransportationOrder._PurchasingOrganization._OrganizationalUnitText[1:Language = $session.system_language].OrganizationalUnitName as PurchasingOrganizationName,
      @Consumption.valueHelpDefinition: [{ entity: {name: 'I_TransportationLocationVH'  , element: 'Location'}}]
      @ObjectModel.text.element: ['SourceLocationDescription']
      cast (_SourceStop.LocationId    as /scmtms/source_location)                                                                           as SourceLocation,
      @Semantics.text: true
      _SourceStop._Locationdescr.LocationDescription                                                                                        as SourceLocationDescription,
      _SourceStop._Locationdescr.AddressObjectDescription                                                                                   as SourceLocationAddressDesc,
      @Consumption.hidden: true
      cast ( _SourceStop.TranspOrdStopPlanTranspDteTme as log_created_on preserving type )                                                  as TranspOrdDepartureDateTime,
      @Consumption.valueHelpDefinition: [{ entity: {name: 'I_TransportationLocationVH'  , element: 'Location'}}]
      @ObjectModel.text.element: ['DestinationLocationDescription']
      cast (_DestinationStop.LocationId as /scmtms/destination_location)                                                                    as DestinationLocation,
      @Semantics.text: true
      _DestinationStop._Locationdescr.LocationDescription                                                                                   as DestinationLocationDescription,
      _DestinationStop._Locationdescr.AddressObjectDescription                                                                              as DestinationLocationAddressDesc,

      @Consumption.hidden: true
      cast ( _DestinationStop.TranspOrdStopPlanTranspDteTme  as log_created_on preserving type )                                            as TranspOrdArrivalDateTime,

      //Visibility settings

      _TenderingVisibilitySettings.TenderingSubmdPriceVisibility,
      TenderingManager,

      _RefTransportationOrder.TranspOrdGrossWeightUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdGrossWeightUnit'
      _RefTransportationOrder.TranspOrdGrossWeight,

      _RefTransportationOrder.TranspOrdGrossVolumeUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdGrossVolumeUnit'
      _RefTransportationOrder.TranspOrdGrossVolume,

      _RefTransportationOrder.TranspOrdQuantityUnit,
      @Semantics.quantity.unitOfMeasure: 'TranspOrdQuantityUnit'
      _RefTransportationOrder.TranspOrdQuantity,

      @Consumption.filter.hidden: true
      @ObjectModel.text.element: ['TranspOrderDngrsGdsStsDesc'] 
      _RefTransportationOrder.TranspOrderDngrsGdsSts                                                                                        as TranspOrderDngrsGdsSts,
      @Semantics.text: true
      _RefTransportationOrder._TranspOrdDngrsGdsStatus._Text[1: Language = $session.system_language].TranspOrderDngrsGdsStsDesc             as TranspOrderDngrsGdsStsDesc,

      /* Associations */
      _TransportationOrderStop,
      _CollabnApplFrtQuotationNote,
      _TenderingManager

}