C_CmmdtyOrderFillPacketLog

@AbapCatalog.sqlViewName: 'CCMDTYFLPKTLOG'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Consumption View for Order Error Log'
@VDM.viewType: #CONSUMPTION
@Search.searchable: false
@ObjectModel.semanticKey    : ['CommodityOrderFillPacketID']
@ObjectModel.usageType: {
        serviceQuality : #D,
        sizeCategory   : #L,
        dataClass      : #TRANSACTIONAL   }
@Metadata.allowExtensions: true
@ClientHandling: {
   type:      #CLIENT_DEPENDENT,
   algorithm: #SESSION_VARIABLE }

@UI.presentationVariant:{
    groupBy   : [  'CmmdtyOrderRequestMessageType' ],
    sortOrder:{
        by: 'CmmdtyOrderFillPacket',
        direction: #ASC
    }}

-- Header Title for Follow On Messages
@UI.headerInfo : {
  typeNamePlural: 'Follow-On System Messages',
  typeName      : 'Follow-On System Message'
}



define view C_CmmdtyOrderFillPacketLog
  as select from    I_CommodityOrdFillPacketLog    as FillPacketLog

  --Association To get Fill Packet Info
  //   left outer join I_CommodityOrderFillPacket  as FillPacket on FillPacketLog.CommodityOrderFillPacketUUID = FillPacket.CommodityOrderFillPacketUUID

    left outer join I_CmmdtyOrdFillPacketCommodity as FillPacket on FillPacketLog.CommodityOrderFillPacketUUID = FillPacket.CommodityOrderFillPacketUUID
  --Association To Get Message Type Text
  association [1..1] to I_RSHMessageType as _MessageTypeText on $projection.CmmdtyOrderRequestMessageType = _MessageTypeText.SystemMessageType


{

      @UI.hidden: true
  key FillPacketLog.CmmdtyOrderFillPacketMsgUUID                                                                                             as CmmdtyOrderFillPacketMsgUUID,

      @UI.hidden: true
      FillPacketLog.CommodityOrderFillPacketUUID                                                                                             as CommodityOrderFillPacketUUID,

      @UI.hidden: true
      FillPacket.CommodityOrderRequestUUID                                                                                                   as CommodityOrderRequestUUID,

      @UI.hidden: true
      -- System Message Criticality Colors
      case   SystemMessageType
      when 'E' then 1
      when 'W' then 2
      else 0
      end                                                                                                                                    as Criticality,

      -- System Message Type
      @UI.lineItem: { position: 20, criticality:'Criticality', criticalityRepresentation: #WITHOUT_ICON}
      @ObjectModel.text.element: 'SystemMessageTypeCriticality'
      cast( FillPacketLog.SystemMessageType    as cmmfdor_ordreqmsgtype  preserving type )                                                   as CmmdtyOrderRequestMessageType,

      @UI.hidden: true
      @ObjectModel.readOnly: true
      _MessageTypeText.SystemMessageTypeCriticality                                                                                          as SystemMessageTypeCriticality,

      -- Commodity Order Fill Packet
      @UI.lineItem.position: 05
      FillPacket.CommodityOrderFillPacketID                                                                                                  as CommodityOrderFillPacketID,

      -- Commodity Order Fill Packet Sequence Number
      @UI.lineItem.position: 10
      FillPacketLog.CmmdtyOrderFillPacket                                                                                                    as CmmdtyOrderFillPacket,

      -- Message Creation Date & Time
      @UI.lineItem.position: 40
      FillPacketLog.CreationDateTime                                                                                                         as CmmdtyOrdReqMessageDateTime,

      -- System Message Source
      @UI.lineItem.position: 30
      FillPacketLog.CmmdtyOrderFillMessageSource                                                                                             as CmmdtyOrderReqMessageSource,

      -- System Message Text
      @UI.lineItem.position: 50
      cast( FillPacketLog.SystemMessageText     as cmmfdor_ordreqmsgtext  preserving type )                                                  as CmmdtyOrderRequestMessageText,

      -- System Message ID (for Error Analysis)
      @UI.lineItem.position: 60
      @UI.lineItem.exclude: true
      FillPacketLog.SystemMessageIdentification                                                                                              as SystemMessageIdentification,

      -- System Message Number (for Error Analysis)
      @UI.lineItem.position: 70
      @UI.lineItem.exclude: true
      FillPacketLog.SystemMessageNumber                                                                                                      as SystemMessageNumber,


      -------------------------Associations--------------------------------------


      @Consumption.filter.hidden: true
      _MessageTypeText


}
-- Merge the Status of the bgRFC queue for the corrersponding Qrder Request in case it is in Error State
union select from I_CmmdtyOrderReqQueueErrLog

--Association To Get Message Type Text
association [1..1] to I_RSHMessageType as _MessageTypeText on $projection.CmmdtyOrderRequestMessageType = _MessageTypeText.SystemMessageType
{
  key CmmdtyOrderFillPacketMsgUUID,
      CommodityOrderFillPacketUUID,
      CommodityOrderRequestUUID,
      Criticality,
      @ObjectModel.text.element: 'SystemMessageTypeCriticality'
      CmmdtyOrderRequestMessageType,
      _MessageTypeText.SystemMessageTypeCriticality                                                                                          as SystemMessageTypeCriticality,
      CommodityOrderFillPacketID,
      CmmdtyOrderFillPacket,
      CmmdtyOrdReqMessageDateTime,
      CmmdtyOrderReqMessageSource,
      CmmdtyOrderRequestMessageText,
      SystemMessageIdentification,
      SystemMessageNumber,

      _MessageTypeText
}