C_ChmlCmplncUse

@EndUserText.label: 'Chemical Compliance Use'

@AbapCatalog:
{
  sqlViewName: 'CCCUSE',
  compiler.compareFilter: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #CONSUMPTION

@ObjectModel:
{
  representativeKey: 'ProdCmplncLegalArea',
  semanticKey:  [ 'ChmlCmplncInfoUUID', 'ProdCmplncLegalArea' ],
  usageType:
  {
    /*Service Quality - reflects the quality of service with respect to the expected performance of the CDS view:
      #A: may be consumed within business logic for high volume transactions or background processing
      #B: may be consumed within business logic for transactions or background processing
    */
    dataClass: #MIXED,
    sizeCategory: #M,
    serviceQuality: #C
  }
}

@Metadata.allowExtensions: true

define view C_ChmlCmplncUse
  as select from P_ChmlCmplncUse as ChmlCmplncUse

  -- needed for DCL
  association [0..1] to I_ChmlCmplncInfo as _ChmlCmplncInfo on $projection.ChmlCmplncInfoUUID = _ChmlCmplncInfo.ChmlCmplncInfoUUID --Join data from Use Draft

{
      @UI.hidden: true
  key ChmlCmplncUse.ChmlCmplncInfoUUID      as ChmlCmplncInfoUUID,

      @ObjectModel.text.element: ['ProdCmplncLegalAreaName']
  key ProdCmplncLegalArea                   as ProdCmplncLegalArea,

      @Semantics.text: true
      _ProdCmplncLegalArea._Text[1: Language= $session.system_language].ProdCmplncLegalAreaName as ProdCmplncLegalAreaName,

      ProdCmplncUseUUID                     as ProdCmplncUseUUID,

      @ObjectModel.text.element: ['ProdCmplncUseProcgStsText']
      ProdCmplncUseProcgSts                 as ProdCmplncUseProcgSts,

      coalesce(
        _ProcessingStatus._Text[ 1: Language = $session.system_language ].PCPrptyProcgStsText,
        _ProcessingStatus._Text[ 1: Language = 'E' ].PCPrptyProcgStsText
      )                                     as ProdCmplncUseProcgStsText,

      ProdCmplncUseProcgStsCritlty          as ProdCmplncUseProcgStsCritlty,

      --Navigation Link UUID
      ProdCmplncUseUUID                     as ProdCmplncUseNavgnLinkUUID,

      --Delete allowed?
      @Semantics.booleanIndicator: true
      ProdCmplncUseDeleteIsAllwd            as ProdCmplncUseDeleteIsAllwd,

      --Release allowed?
      @Semantics.booleanIndicator: true
      ProdCmplncUseReleaseIsAllwd           as ProdCmplncUseReleaseIsAllwd,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_USE_MLTVALUE_CALC_EXT'
      @ObjectModel.readOnly: true
      cast('' as ehfnd_spcfc_uses_ph_text ) as ProdCmplncSpcfcUsePhraseText,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHFND_USE_MLTVALUE_CALC_EXT'
      @ObjectModel.readOnly: true
      cast('' as ehfnd_restr_uses_ph_text ) as ProdCmplncRstrcdUsePhraseText,

      _ChmlCmplncInfo

}
where
  ProdCmplncUseProcgSts is not initial