C_ChmlCmplncReqNewCmplncInfoTP

@EndUserText.label: 'Chemical Compliance Request New Chemical Compliance Info'

@AbapCatalog:
{
  sqlViewName: 'CCREQNCCITP',
  compiler.compareFilter: true,
  preserveKey: true
}

@AccessControl:
{
  authorizationCheck: #MANDATORY,
  // blocking of personal data not required

  personalData.blocking: #NOT_REQUIRED
}

@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #CONSUMPTION

@ObjectModel:
{
  transactionalProcessingDelegated: true,
  createEnabled: false,
  updateEnabled: true,
  deleteEnabled: false,
  semanticKey:  [ 'ChmlCmplncReqNewCmplncInfoUUID' ],
  usageType:
  {
    /*Service Quality - reflects the quality of service with respect to the expected performance of the CDS view:
      #A: may be consumed within business logic for high volume transactions or background processing
      #B: may be consumed within business logic for transactions or background processing
    */
    dataClass: #MIXED,
    sizeCategory: #XL,
    serviceQuality: #C
  }
}

@UI.presentationVariant: [{requestAtLeast: ['ChmlCmplncInfoType', 'ChmlCmplncProdUUID', 'ProdStewardshipRespUnit', 'DngrsGdsRespUnitName', 'ChmlCmplncInternalName', 'ChmlCmplncProdIsResearched']}]

define view C_ChmlCmplncReqNewCmplncInfoTP
  as select from I_ChmlCmplncReqNewCmplncInfoTP

  association [1..1] to C_ChmlCmplncReqProcMkt         as _ChmlCmplncReq            on $projection.ChmlCmplncRequestUUID = _ChmlCmplncReq.ChmlCmplncRequestUUID

  -- Combined name of CCI/UP
  association [0..1] to C_ChmlCmplncPrimMatl           as _PrimeMatUnpackaged       on $projection.ChmlCmplncProdUUID = _PrimeMatUnpackaged.ChmlCmplncInfoUUID

  -----------------------------------------------------------------------------------------------------------------------------------------------------------------
  -- Value Helps --
  -----------------------------------------------------------------------------------------------------------------------------------------------------------------
  association [0..1] to C_ChmlCmplncRespUnitProductVH  as _RespProductStewardshipVH on _RespProductStewardshipVH.ResponsibleUnit = $projection.ProdStewardshipRespUnit
  association [0..1] to C_ChmlCmplncRespUnitDngrsGdsVH as _RespDangerousGoodsVH     on _RespDangerousGoodsVH.ResponsibleUnit = $projection.DngrsGdsRespUnit

  association [0..1] to C_ChmlCmplncBaseProdVH         as _ChmlCmplncProdVH         on $projection.ChmlCmplncProdUUID = _ChmlCmplncProdVH.ChmlCmplncInfoUUID

{
      @UI.hidden: true
      @ObjectModel.readOnly: true
  key ChmlCmplncReqNewCmplncInfoUUID,

      @UI.hidden: true
      @ObjectModel.readOnly: true
      ChmlCmplncRequestUUID,

      @UI.hidden: true
      @ObjectModel.readOnly: true
      _ChmlCmplncReq.ChmlCmplncInfoUUID,

      @ObjectModel.readOnly: true
      _ChmlCmplncReq.Material,

      --CCI Type for new CCI
      ChmlCmplncInfoType                                                           as ChmlCmplncInfoType,

      --Referenced UP
      @ObjectModel.mandatory: true
      @Consumption.valueHelp: '_ChmlCmplncProdVH'
      @UI.textArrangement: #TEXT_ONLY
      ChmlCmplncProdUUID                                                           as ChmlCmplncProdUUID,

      --Combined Name of referenced UP
      @ObjectModel.readOnly: true
      _PrimeMatUnpackaged.ChmlCmplncInfoCombinedName                               as ChmlCmplncProdMaterialCombName,

      --Responsible Unit of Product Stewardship
      @UI:
      {
        textArrangement: #TEXT_FIRST
      }
      @ObjectModel:
       {
         mandatory: true,
         foreignKey.association: '_RespProductStewardshipVH',
         text.element:  [ 'ProdStewardshipRespUnitName' ]
       }
      cast(ProdStewardshipRespUnit as ehfnd_cci_responsible_unit preserving type ) as ProdStewardshipRespUnit,

      --Description of Responsible Unit of Product Stewardship
      @ObjectModel.readOnly: true
      @UI.hidden: true
      _RespProductStewardshipVH.ResponsibleUnitName                                as ProdStewardshipRespUnitName,

      -- Responsible Unit for Dangerous Goods
      @UI:
      {
        textArrangement: #TEXT_FIRST
      }
      @ObjectModel:
       {
         mandatory: true,
         foreignKey.association: '_RespDangerousGoodsVH',
         text.element:  [ 'DngrsGdsRespUnitName' ]
       }
      @Semantics.text: true
      DngrsGdsRespUnit,

      --Description of Responsible Unit of Dangerous Goods
      @ObjectModel.readOnly: true
      @Semantics.text: true
      _RespDangerousGoodsVH.ResponsibleUnitName                                    as DngrsGdsRespUnitName,

      ChmlCmplncInternalName                                                       as ChmlCmplncInternalName,

      ChmlCmplncProdIsResearched                                                   as ChmlCmplncProdIsResearched,

      --Indicator: Chemical Compliance Information is transported
      MaterialIsTransported,

      --Indicator: Chemical Compliance Information is sold
      MaterialIsSold,

      --Indicator: Chemical Compliance Information is produced
      MaterialIsProduced,

      --Indicator: Chemical Compliance Information is sourced
      MaterialIsSourced,

      --Product Categorization needed for create UP CCI as mandatory field
      ChmlCmplncProdCatztnPhrsUUID                                                 as ChmlCmplncProdCatztnPhrsUUID,

      /* Associations */
      @ObjectModel.association.type:  [ #TO_COMPOSITION_ROOT, #TO_COMPOSITION_PARENT ]
      _ChmlCmplncReq,

      _RespProductStewardshipVH,
      _RespDangerousGoodsVH,
      _ChmlCmplncProdVH
}