C_ChmlCmplncInfoTransptPrmssn

DDL: C_CHMLCMPLNCINFOTRANSPTPRMSSN SQL: CCCITRANSPTP Type: view CONSUMPTION

Chml Cmplnc Info Transport Permission

C_ChmlCmplncInfoTransptPrmssn is a Consumption CDS View that provides data about "Chml Cmplnc Info Transport Permission" in SAP S/4HANA. It reads from 2 data sources (I_ChmlCmplncInfo, I_Country) and exposes 10 fields with key fields ChmlCmplncInfoUUID, Country. It has 1 association to related views.

2 data source(s) 10 fields

Data Sources (2)

SourceAliasJoin Type
I_ChmlCmplncInfo ChmlCmplncInfo cross
I_Country Country from

Associations (1)

CardinalityTargetAliasCondition
[0..*] C_DngrsGdsChkRuleTransptPrmssn _DngrsGdsChkRuleTransptPrmssn Country.Country = _DngrsGdsChkRuleTransptPrmssn.Country and ChmlCmplncInfo.ChmlCmplncInfoUUID = _DngrsGdsChkRuleTransptPrmssn.ChmlCmplncInfoUUID

Annotations (11)

NameValueLevelField
AbapCatalog.sqlViewName CCCITRANSPTP view
AbapCatalog.compiler.compareFilter true view
AbapCatalog.preserveKey true view
AccessControl.authorizationCheck #MANDATORY view
EndUserText.label Chml Cmplnc Info Transport Permission view
VDM.viewType #CONSUMPTION view
ClientHandling.algorithm #SESSION_VARIABLE view
ObjectModel.usageType.dataClass #MASTER view
ObjectModel.usageType.sizeCategory #L view
ObjectModel.usageType.serviceQuality #C view
Search.searchable true view

Fields (10)

KeyFieldSource TableSource FieldDescription
KEY ChmlCmplncInfoUUID I_ChmlCmplncInfo ChmlCmplncInfoUUID
KEY Country I_Country Country
CountryName
TransportPermission
TransportPermissionName
TransportPermissionCriticality
CountryHasGeneralModeOfTranspt
CountryHasCargoModeOfTranspt
CountryHasPssngrModeOfTranspt
_DngrsGdsChkRuleTransptPrmssn _DngrsGdsChkRuleTransptPrmssn 
@AbapCatalog.sqlViewName: 'CCCITRANSPTP'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Chml Cmplnc Info Transport Permission'

@VDM.viewType: #CONSUMPTION

@ClientHandling.algorithm: #SESSION_VARIABLE

@ObjectModel:
{
  usageType:
  {
    dataClass: #MASTER,
    sizeCategory: #L, // < 10.000.000

    serviceQuality: #C // <= 15 msec

  }
}
@Search.searchable: true

define view C_ChmlCmplncInfoTransptPrmssn
  as select from I_Country        as Country
    cross join   I_ChmlCmplncInfo as ChmlCmplncInfo

  association [0..*] to C_DngrsGdsChkRuleTransptPrmssn as _DngrsGdsChkRuleTransptPrmssn on Country.Country                   = _DngrsGdsChkRuleTransptPrmssn.Country
                                                                                       and ChmlCmplncInfo.ChmlCmplncInfoUUID = _DngrsGdsChkRuleTransptPrmssn.ChmlCmplncInfoUUID
{
  key ChmlCmplncInfo.ChmlCmplncInfoUUID,
  key Country.Country                                                   as Country,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      Country._Text[1: Language = $session.system_language].CountryName as CountryName,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHDGM_CCI_TRANS_PRMSSN_EXIT'
      cast( '' as ehdgm_transport_permission )                          as TransportPermission,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHDGM_CCI_TRANS_PRMSSN_EXIT'
      cast( '' as val_text )                                            as TransportPermissionName,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHDGM_CCI_TRANS_PRMSSN_EXIT'
      cast( 0 as int1)                                                as TransportPermissionCriticality,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHDGM_CCI_TRANS_PRMSSN_EXIT'
      cast( '' as boole_d)                                              as CountryHasGeneralModeOfTranspt,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHDGM_CCI_TRANS_PRMSSN_EXIT'
      cast( '' as boole_d)                                              as CountryHasCargoModeOfTranspt,

      @ObjectModel.virtualElement
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_EHDGM_CCI_TRANS_PRMSSN_EXIT'
      cast( '' as boole_d)                                              as CountryHasPssngrModeOfTranspt,

      _DngrsGdsChkRuleTransptPrmssn
}

Learn More