C_ChgRecdRefRateRtgTskList

@AbapCatalog.sqlViewName: 'CCHGRECREFRRT'
@EndUserText.label: 'Change Recrd Obj Ref Rate Rout Task List'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType: {serviceQuality: #C,
                         dataClass: #MIXED,
                         sizeCategory: #L}
@ClientHandling.algorithm: #SESSION_VARIABLE
@AbapCatalog.preserveKey:true
@AccessControl.personalData.blocking: #NOT_REQUIRED

@ObjectModel: {
   semanticKey: ['BillOfOperationsType','BillOfOperationsGroup','BillOfOperationsVariant'],
   createEnabled: true,
   deleteEnabled: 'EXTERNAL_CALCULATION',
   updateEnabled,
   transactionalProcessingDelegated: true
}

@Metadata.allowExtensions: true

define view C_ChgRecdRefRateRtgTskList
  as select from I_ChgRecdRefRateRtgTskListTP as ChgRecdRefRateRtgTskListTP

  association [1..1] to C_ItmRelRefRateRtgTskListVH  as _ChangeRecordItemRelVH   on  $projection.ChangeRecordItemRelevance = _ChangeRecordItemRelVH.ChangeRecordItemRelevance
                                                                                 and $projection.ChangeRecordType          = _ChangeRecordItemRelVH.ChangeRecordType

  association [1..1] to C_ChangeRecordObjPg          as _ChangeRecordObjPg       on  $projection.ChangeRecordUUID = _ChangeRecordObjPg.ChangeRecordUUID

  association [1..1] to C_ChgRecdRefRateRtgTskListVH as _RefRateRtgaskListVH     on  $projection.BillOfOperationsType    = _RefRateRtgaskListVH.BillOfOperationsType
                                                                                 and $projection.BillOfOperationsGroup   = _RefRateRtgaskListVH.BillOfOperationsGroup
                                                                                 and $projection.BillOfOperationsVariant = _RefRateRtgaskListVH.BillOfOperationsVariant
  association [1..1] to C_ChgRecordItemProcgStatusVH as _ProcessingStatusVH      on  $projection.ChangeRecordItemProcgStatus   = _ProcessingStatusVH.ChgRecdNextItemProcgStatus
                                                                                 and $projection.ChgRecdCurrentItemProcgStatus = _ProcessingStatusVH.ChgRecdCurrentItemProcgStatus
                                                                                 and $projection.ChangeRecordLifecycleStatus   = _ProcessingStatusVH.ChangeRecordLifecycleStatus
  association [0..*] to I_ChgRecdItemProcgStatusText as _ProcessingStatusTxt     on  $projection.ChangeRecordItemProcgStatus = _ProcessingStatusTxt.ChangeRecordItemProcgStatus

  association [1..1] to I_BillOfOperations           as _BillOfOperations        on  $projection.BillOfOperationsType    = _BillOfOperations.BillOfOperationsType
                                                                                 and $projection.BillOfOperationsGroup   = _BillOfOperations.BillOfOperationsGroup
                                                                                 and $projection.BillOfOperationsVariant = _BillOfOperations.BillOfOperationsVariant

  association [1..*] to C_RefRateRtgTskListMatVH     as _RefRateRtgTskListMatVH  on  $projection.BillOfOperationsType    = _RefRateRtgTskListMatVH.BillOfOperationsType
                                                                                 and $projection.BillOfOperationsGroup   = _RefRateRtgTskListMatVH.BillOfOperationsGroup
                                                                                 and $projection.BillOfOperationsVariant = _RefRateRtgTskListMatVH.BillOfOperationsVariant

  association [0..*] to I_ChangeRecordRefObjIcons    as _ChangeRecordRefObjIcons on  $projection.ChangeRecordUUID          = _ChangeRecordRefObjIcons.ChangeRecordUUID
                                                                                 and $projection.ChangeRecordReferenceType = _ChangeRecordRefObjIcons.ChangeRecordReferenceType
  association [0..*] to C_ChangeRecdDigSignStatusVH  as _DigSignStatusText       on  $projection.ChgRecdItmDSgntr = _DigSignStatusText.ChgRecdDigitalSignatureStatus

{
          @ObjectModel.readOnly: true
  key     ChangeRecordReferenceUUID,
          @Semantics.imageUrl: true
          @ObjectModel.readOnly: true
          _ChangeRecordRefObjIcons[ChangeRecordType = ChangeRecordType].ChangeRecordRefObjIcon as ChangeRecordRefObjIcon,

          @Consumption.valueHelpDefinition: [
                                             { entity: {name: 'C_ChgRecdRefRateRtgTskListVH',
                                                        element: 'BillOfOperationsGroup'},
                                               additionalBinding: [{ localElement: 'BillOfOperationsVariant', element: 'BillOfOperationsVariant' }],
                                               label: 'Ref Rate Routing Task List'
                                               },
                                             { entity: {name: 'C_RefRateRtgTskListMatVH',
                                                        element: 'BillOfOperationsGroup'},
                                               additionalBinding: [{ localElement: 'BillOfOperationsVariant', element: 'BillOfOperationsVariant' }],
                                               label: 'Ref Rate Routing Task List by Material',
                                               qualifier: 'SecondaryValueHelp'
                                             }
                                             ]

          @ObjectModel.mandatory: true
          @ObjectModel.text.element:  [ 'BillOfOperationsDesc' ]
          @UI.lineItem:[{importance:#HIGH } ]
          ChgRecdRefRateRtgTskListTP.BillOfOperationsGroup                                     as BillOfOperationsGroup,

          @ObjectModel.readOnly: true
          _BillOfOperations._BillOfOperationsChangeState[1: ValidityStartDate <= $session.system_date and ValidityEndDate >= $session.system_date].BillOfOperationsDesc,

          ChgRecdRefRateRtgTskListTP.BillOfOperationsType                                      as BillOfOperationsType,

          @UI.lineItem:[{importance:#HIGH } ]
          ChgRecdRefRateRtgTskListTP.BillOfOperationsVariant,


          @ObjectModel.readOnly: true
          @UI.identification: [{importance: #MEDIUM }]
          _ChangeRecordObjPg.ChangeRecordType                                                  as ChangeRecordType,
          @ObjectModel.readOnly:true
          @UI.identification: [{importance: #MEDIUM }]
          _ChangeRecordObjPg.ChgRecdItemProcgStatusIsEnbld,
          @ObjectModel.readOnly: true
          @UI.identification: [{importance: #MEDIUM }]
          _ChangeRecordObjPg.ChangeRecordLifecycleStatus                                       as ChangeRecordLifecycleStatus,
          @ObjectModel.readOnly: true
          @UI.identification: [{importance: #MEDIUM }]
          _ChangeRecordObjPg.ChangeRecordStatus,
          ChangeRecordUUID,
          @UI.identification: [{importance: #MEDIUM }]
          ChangeRecordReferenceType,
          ParentChangeRecordRefUUID,

          @ObjectModel.foreignKey.association: '_ChangeRecordItemRelVH'
          @Consumption.valueHelp: '_ChangeRecordItemRelVH'
          @ObjectModel.mandatory: true
          @UI.identification: [{importance: #MEDIUM }]
          ChangeRecordItemRelevance,

          @Consumption.valueHelpDefinition: [{association: '_ProcessingStatusVH'}]
          @ObjectModel.foreignKey.association: '_ProcessingStatusVH'
          @UI.identification: [{importance: #MEDIUM }]
          ChangeRecordItemProcgStatus,
          @ObjectModel.readOnly: true
          @UI.identification: [{importance: #MEDIUM }]
          ChgRecdCurrentItemProcgStatus,

          @ObjectModel.readOnly: true
          @Consumption.semanticObject: 'ChangeMaster'
          @UI.identification: [{importance: #MEDIUM }]
          ChangeNumber,

          @ObjectModel.readOnly: true
          @UI.identification: [{importance: #MEDIUM }]
          _ChangeRecordObjPg.ChangeRecordItemIsNotEditable,

          @ObjectModel.readOnly: true
          @UI.identification: [{importance: #MEDIUM }]
          _ChangeRecordObjPg.ChangeRecordItmIsAddDelEnabled,

          @UI.identification: [{importance: #MEDIUM }]
          ChangeRecordReference,

          @UI.identification: [{importance: #MEDIUM }]
          @Semantics.user.createdBy: true
          CreatedByUser,

          CreationDateTime,
          @ObjectModel.virtualElement : true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CREATIONDATE_CONVERT'
          @ObjectModel.readOnly: true
          @UI.identification: [{importance: #MEDIUM }]
          cast( '00000000' as /plmb/created_on )                                               as CreationDate,
          @Semantics.user.lastChangedBy: true
          @UI.identification: [{importance: #MEDIUM }]
          LastChangedByUser,

          LastChangeDateTime,
          @ObjectModel.virtualElement : true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CHANGEDATE_CONVERT'
          @ObjectModel.readOnly: true
          @UI.identification: [{importance: #MEDIUM }]
          cast( '00000000' as /plmb/changed_on )                                               as LastChangeDate,

          @UI.hidden: true
          @UI.lineItem:[{importance:#HIGH, hidden: true }   ]
          @EndUserText.label: 'Digital Signature Status'
          @ObjectModel.foreignKey.association: '_DigSignStatusText'
          @Consumption: { valueHelp: '_DigSignStatusText' }
          ChgRecdItmDSgntr,

          @UI.identification: [{importance: #MEDIUM }]
          ChgRecdReasonForChange,

          @UI.identification: [{importance: #MEDIUM }]
          ExpdCompltnDte,

          @UI.identification: [{importance: #MEDIUM }]
          @Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChangeRecdAuthznGrpVH' , element: 'ChgRecdNmbrAuthznGrp'}}]
          ChgRecdAuthznGrpText,

          @UI.identification: [{importance: #MEDIUM }]
          @Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChgRecdChgNmbrStatusVH' , element: 'ChgRecdNmbrChgSts'}}]
          ChgRecdNmbrChgSts,



          @UI.lineItem:[{
              hidden: true,
              importance:#LOW }
            ]
          @UI.hidden: true
          @ObjectModel.readOnly: true
          @ObjectModel.virtualElement : true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
          cast( '' as boolean)                                                                 as DigitalSignUserIsAuthorized,

          @ObjectModel.readOnly: true
          @UI.identification: [{importance: #LOW, position: 90 }]
          @EndUserText.label: 'Digital Signature Status'
          _DigSignStatusText.ChgRecdDigSignStatusTxt                                           as ChgRecdDigSignStatusTxt,


          @UI.lineItem:[{
          hidden: true,
          importance:#LOW }
          ]
          @UI.hidden: true
          @ObjectModel.readOnly: true
          @ObjectModel.virtualElement : true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
          cast( '' as boolean)                                                                 as ChgRecdObjDgtlSgntrEnable,

          @ObjectModel.association.type: [ #TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT ]
          _ChangeRecordObjPg,
          _ChangeRecordItemRelVH,
          _ProcessingStatusVH,
          _RefRateRtgaskListVH,
          _RefRateRtgTskListMatVH,
          _ProcessingStatusTxt,
          _BillOfOperations,
          _DigSignStatusText
}