@AbapCatalog.sqlViewName: 'CCHGRCDEQUIBM'
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #NOT_REQUIRED
@EndUserText.label: 'Change Record Reference Object Equip BOM'
@VDM.viewType: #CONSUMPTION
@AbapCatalog.preserveKey:true
@ObjectModel.usageType: {serviceQuality: #C,
dataClass: #MIXED,
sizeCategory: #XXL}
@ClientHandling.algorithm: #SESSION_VARIABLE
@ObjectModel: {
semanticKey: ['Equipment','Plant','BillOfMaterialVariantUsage','BillOfMaterialVariant'],
createEnabled: true,
deleteEnabled:'EXTERNAL_CALCULATION',
updateEnabled,
transactionalProcessingDelegated: true
}
@UI.headerInfo:{
typeName: 'Equipment BOM',
typeNamePlural: 'Equipment BOMs',
imageUrl: 'ProductImageURL',
title:{value:'Equipment'}
}
@UI.presentationVariant.requestAtLeast: [ 'ChangeRecordType', 'ChangeRecordLifecycleStatus', 'ChangeRecordReferenceType', 'BillOfMaterial' ]
define view C_ChgRecdRefEquipBOM
as select from I_ChgRecdRefEquipBOMTP as ChangeRecordReferenceEBMTP
association [1..1] to C_ChangeRecordObjPg as _ChangeRecordObjPg on $projection.ChangeRecordUUID = _ChangeRecordObjPg.ChangeRecordUUID
association [0..1] to C_ChgRecdEquipBOMVH as _ChangeRecordEquiBOMVH on $projection.Equipment = _ChangeRecordEquiBOMVH.Equipment
and $projection.Plant = _ChangeRecordEquiBOMVH.Plant
and $projection.BillOfMaterialVariantUsage = _ChangeRecordEquiBOMVH.BillOfMaterialVariantUsage
and $projection.BillOfMaterialVariant = _ChangeRecordEquiBOMVH.BillOfMaterialVariant
association [0..1] to I_PlantStdVH as _Plant on $projection.Plant = _Plant.Plant
association [0..1] to I_BillOfMaterialUsage as _BillOfMaterialVariantUsage on $projection.BillOfMaterialVariantUsage = _BillOfMaterialVariantUsage.BillOfMaterialVariantUsage
and _BillOfMaterialVariantUsage.Language = $session.system_language
association [1..1] to C_ChgRecdRlvnceEquipBOMVH as _ChangeRecordItemRelVH on $projection.ChangeRecordItemRelevance = _ChangeRecordItemRelVH.ChangeRecordItemRelevance
and $projection.ChangeRecordType = _ChangeRecordItemRelVH.ChangeRecordType
association [1..1] to C_ChgRecordItemProcgStatusVH as _ProcessingStatusVH on $projection.ChangeRecordItemProcgStatus = _ProcessingStatusVH.ChgRecdNextItemProcgStatus
and $projection.ChgRecdCurrentItemProcgStatus = _ProcessingStatusVH.ChgRecdCurrentItemProcgStatus
and $projection.ChangeRecordLifecycleStatus = _ProcessingStatusVH.ChangeRecordLifecycleStatus
association [0..*] to I_ChgRecdItemProcgStatusText as _ProcessingStatusTxt on $projection.ChangeRecordItemProcgStatus = _ProcessingStatusTxt.ChangeRecordItemProcgStatus
association [0..*] to C_ChangeRecdDigSignStatusVH as _DigSignStatusText on $projection.ChgRecdItmDSgntr = _DigSignStatusText.ChgRecdDigitalSignatureStatus
{
--------------------------------------------
// @UI.facet: [
// ----Facets
// {type: #COLLECTION, position: 10, id: 'BOMInfo', label: 'Material BOM Information'},
// {type: #IDENTIFICATION_REFERENCE, position: 10, id: 'BOMRef', parentId: 'BOMInfo', isSummary, isPartOfPreview },
// ----Facets: Attachments
// {type: #COLLECTION, position: 10, id: 'Attachments', label: 'Attachments'}
// ]
--------------------------------------------
@UI.hidden: true
@ObjectModel.readOnly: true
key ChangeRecordReferenceUUID,
// @UI.hidden: true
// @ObjectModel.readOnly: true
// _ChangeRecordStdBOMVH.BillOfMaterialHeaderUUID as BillOfMaterialHeaderUUID,
@UI.hidden: true
@UI.lineItem:[
{ position:5,
importance:#HIGH }
]
@UI.identification: {position: 5, importance: #HIGH}
@Semantics.imageUrl: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_OBJECT_THUMBNAIL_VE'
cast( '' as productimageurl ) as ProductImageURL,
@UI.lineItem:[{
position:10,
importance:#HIGH }
]
@UI.identification: {position: 10, importance: #HIGH}
@Consumption.valueHelpDefinition: [{
entity: { name: 'C_ChgRecdEquipBOMVH',
element: 'Equipment' },
additionalBinding:[{ localElement: 'Plant',
element: 'Plant' },
{ localElement: 'BillOfMaterialVariantUsage',
element: 'BillOfMaterialVariantUsage' },
{ localElement: 'BillOfMaterialVariant',
element: 'BillOfMaterialVariant' }]
}]
Equipment,
@UI.lineItem:[{
position:40,
importance:#HIGH }
]
@UI.identification: {position: 40, importance: #HIGH}
@ObjectModel.foreignKey.association: '_Plant'
Plant,
@UI.lineItem:[{
position:45,
importance:#MEDIUM }
]
@UI.identification: {position: 45, importance: #HIGH}
@ObjectModel.text.element: [ 'BillOfMaterialVariantUsageDesc' ]
BillOfMaterialVariantUsage,
@UI.hidden:true
@ObjectModel.readOnly:true
_BillOfMaterialVariantUsage.BillOfMaterialVariantUsageDesc,
@UI.lineItem:[{
position:50,
importance:#HIGH }
]
@UI.identification: {position:50, importance: #HIGH}
BillOfMaterialVariant,
@UI.lineItem:[{position:110,importance:#MEDIUM }]
@UI.identification: {position: 110, importance: #MEDIUM}
@ObjectModel.readOnly: true
@Consumption.semanticObject: 'ChangeMaster'
ChangeNumber,
@UI.lineItem:[{ position:45, importance:#MEDIUM }]
@UI.identification: [{position: 70, importance: #MEDIUM }]
@EndUserText.label: 'Processing Status'
@Consumption.valueHelpDefinition: [{association: '_ProcessingStatusVH'}]
@ObjectModel.foreignKey.association: '_ProcessingStatusVH'
@UI.textArrangement: #TEXT_FIRST
ChangeRecordItemProcgStatus,
@UI.hidden: true
@ObjectModel.readOnly: true
ChgRecdCurrentItemProcgStatus,
@ObjectModel.readOnly: true
@UI.hidden: true
_ChangeRecordObjPg.ChangeRecordLifecycleStatus as ChangeRecordLifecycleStatus,
@UI.hidden: true
@ObjectModel.readOnly: true
_ChangeRecordObjPg.ChangeRecordItemIsNotEditable,
@UI.hidden: true
@ObjectModel.readOnly: true
_ChangeRecordObjPg.ChangeRecordItmIsAddDelEnabled,
@UI.hidden: true
@ObjectModel.readOnly: true
_ChangeRecordObjPg.ChangeRecordType as ChangeRecordType,
@UI.hidden: true
ChangeRecordUUID,
@UI.hidden: true
ChangeRecordReferenceType,
@UI.hidden: true
ChangeRecordReferenceSubtype,
@UI.hidden: true
ParentChangeRecordRefUUID,
@UI.lineItem:[{
position:120,
importance:#MEDIUM }
]
@Consumption: { valueHelp: '_ChangeRecordItemRelVH' }
@ObjectModel: {foreignKey.association: '_ChangeRecordItemRelVH' }
@UI.identification: {position:120, importance: #MEDIUM}
@UI.textArrangement: #TEXT_ONLY
@ObjectModel.mandatory: true
ChangeRecordItemRelevance,
@UI.hidden: true
ChangeRecordReference,
// @ObjectModel.readOnly:true
// @UI.hidden: true
// _ChangeRecordObjPg.ChgRecdItemProcgStatusIsEnbld,
// For BOM Navigation
@UI.hidden: true
BillOfMaterial,
@UI.hidden: true
@ObjectModel.readOnly: true
_ChangeRecordObjPg.ChangeRecordStatus,
@Semantics.user.createdBy: true
@ObjectModel.readOnly: true
@UI.identification: {position: 125, importance: #MEDIUM}
CreatedByUser,
@UI.hidden: true
CreationDateTime,
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CREATIONDATE_CONVERT'
@ObjectModel.readOnly: true
@UI.identification: {position: 130, importance: #MEDIUM}
cast( '00000000' as /plmb/created_on ) as CreationDate,
@Semantics.user.lastChangedBy: true
@ObjectModel.readOnly: true
@UI.identification: {position: 135, importance: #MEDIUM}
LastChangedByUser,
@UI.hidden: true
BillOfMaterialCategory,
@UI.hidden: true
LastChangeDateTime,
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_CHANGEDATE_CONVERT'
@ObjectModel.readOnly: true
@UI.identification: {position: 140, importance: #MEDIUM}
cast( '00000000' as /plmb/changed_on ) as LastChangeDate,
@UI.hidden: true
ChangeRecordVirtualRefInd,
@UI.hidden: true
@UI.lineItem:[{importance:#MEDIUM, hidden: true } ]
@EndUserText.label: 'Digital Signature Status'
@ObjectModel.foreignKey.association: '_DigSignStatusText'
@Consumption: { valueHelp: '_DigSignStatusText' }
ChgRecdItmDSgntr,
@UI.identification: {position: 145, importance: #MEDIUM}
ChgRecdReasonForChange,
@UI.identification: {position: 150, importance: #MEDIUM}
ExpdCompltnDte,
@UI.identification: {position: 155, importance: #MEDIUM}
@Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChangeRecdAuthznGrpVH' , element: 'ChgRecdNmbrAuthznGrp'}}]
ChgRecdAuthznGrpText,
@UI.identification: {position: 160, importance: #MEDIUM}
@Consumption.valueHelpDefinition: [{ entity : { name : 'C_ChgRecdChgNmbrStatusVH' , element: 'ChgRecdNmbrChgSts'}}]
ChgRecdNmbrChgSts,
@UI.lineItem:[{
hidden: true,
importance:#LOW }
]
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
cast( '' as boolean) as DigitalSignUserIsAuthorized,
@ObjectModel.readOnly: true
@UI.identification: [{importance: #LOW, position: 165 }]
@EndUserText.label: 'Digital Signature Status'
_DigSignStatusText.ChgRecdDigSignStatusTxt as ChgRecdDigSignStatusTxt,
@UI.lineItem:[{
hidden: true,
importance:#LOW }
]
@UI.hidden: true
@ObjectModel.readOnly: true
@ObjectModel.virtualElement : true
@ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CR_I_DSGNTR_ENABLE'
cast( '' as boolean) as ChgRecdObjDgtlSgntrEnable,
_Plant,
_BillOfMaterialVariantUsage,
_ChangeRecordItemRelVH,
_ChangeRecordEquiBOMVH,
_ProcessingStatusVH,
@ObjectModel.association.type: [ #TO_COMPOSITION_ROOT,#TO_COMPOSITION_PARENT ]
_ChangeRecordObjPg,
_ProcessingStatusTxt,
_DigSignStatusText
}