C_CharcAttribCodeGroupVH

@AbapCatalog.viewEnhancementCategory: [#NONE]
@AccessControl.authorizationCheck: #CHECK
@EndUserText.label: 'Characteristic Attribute Code Group'
@Metadata.ignorePropagatedAnnotations: true
@ObjectModel.dataCategory: #VALUE_HELP
@ObjectModel.usageType:{
  serviceQuality: #C,
  sizeCategory: #S,
  dataClass: #MIXED
}
@VDM.viewType: #CONSUMPTION
@Search.searchable: true
@Consumption.ranked: true
@ObjectModel.representativeKey: 'CharacteristicAttributeCode'
define view entity C_CharcAttribCodeGroupVH
  as select from            I_InspectionCharacteristic   as _InspectionCharacteristic
    inner join              I_CharcAttribSelectedCodeSet as _CharcAttribSelectedCodeSet on  _InspectionCharacteristic.SelectedCodeSetPlant = _CharcAttribSelectedCodeSet.SelectedCodeSetPlant
                                                                                        and _InspectionCharacteristic.SelectedCodeSet      = _CharcAttribSelectedCodeSet.SelectedCodeSet
    inner join              I_CharcAttribSelectedSetCode as _CharcAttribSelectedSetCode on  _CharcAttribSelectedCodeSet.SelectedCodeSetPlant = _CharcAttribSelectedSetCode.SelectedCodeSetPlant
                                                                                        and _CharcAttribSelectedCodeSet.SelectedCodeSet      = _CharcAttribSelectedSetCode.SelectedCodeSet
    left outer to many join I_CharcAttributeCode         as _CharcAttributeCode         on  _CharcAttributeCode.CharacteristicAttributeCodeGrp = _CharcAttribSelectedSetCode.CharacteristicAttributeCodeGrp
                                                                                        and _CharcAttributeCode.CharacteristicAttributeCode    = _CharcAttribSelectedSetCode.CharacteristicAttributeCode
   association [1..1] to I_InspectionValuationRsltText as _InspectionValuationRsltText  on $projection.InspectionValuationResult = _InspectionValuationRsltText.InspectionValuationResult

{
  key _InspectionCharacteristic.InspectionLot,
  key _InspectionCharacteristic.InspPlanOperationInternalID,
  key _InspectionCharacteristic.InspectionCharacteristic,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.text.element: ['CharacteristicAttributeCodeGrp']
  key _CharcAttribSelectedSetCode.CharacteristicAttributeCode,
      @Semantics.text: true
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #LOW }
  key _CharcAttribSelectedSetCode.CharacteristicAttributeCodeGrp,
      @Search: { defaultSearchElement: true, fuzzinessThreshold: 0.8, ranking: #LOW }
      _CharcAttributeCode.CharacteristicAttributeCodeTxt,
      @EndUserText.label: 'Valuation'
      @ObjectModel.text.element: ['InspectionValuationResultText']
      _CharcAttribSelectedSetCode.CharcAttributeValuation as InspectionValuationResult,
      @Semantics.text: true
      @EndUserText.label: 'Valuation Text'
      _InspectionValuationRsltText.InspectionValuationResultText,
      @UI.hidden: true
      _InspectionCharacteristic._InspectionLot.Plant as Plant,
      @UI.hidden: true
      _InspectionCharacteristic._InspectionLot.InspectionLotType as InspectionLotType,
      @UI.hidden: true
      _InspectionCharacteristic._InspectionLot.MatlQualityAuthorizationGroup as MatlQualityAuthorizationGroup,
      @UI.hidden: true
      @Semantics.booleanIndicator: true
      _InspectionCharacteristic._InspectionLot.IsBusinessPurposeCompleted as IsBusinessPurposeCompleted,

       @UI.hidden: true
      _CharcAttribSelectedCodeSet.SelectedCodeSetPlant as SelectedCodeSetPlant,
       @UI.hidden: true
      _CharcAttribSelectedCodeSet.InspectionSelectedSetStatus as InspectionSelectedSetStatus,
       @UI.hidden: true
       _CharcAttribSelectedCodeSet.SelectedCodeSet as SelectedCodeSet,
      _InspectionValuationRsltText
} where
_InspectionValuationRsltText.Language = $session.system_language