C_CSPRStore

@AbapCatalog.sqlViewName: 'CCSPRSTORE'
@EndUserText.label: 'Count Products with RFID: Store'

@AbapCatalog.preserveKey: true
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.privilegedAssociations: ['_StorageLocation','_Settings']
@AccessControl.personalData.blocking: #NOT_REQUIRED
@ClientHandling.algorithm: #SESSION_VARIABLE

@VDM.viewType: #CONSUMPTION
@ObjectModel: {
    representativeKey: 'Store',
    usageType.serviceQuality: #C,
    usageType.sizeCategory: #M,
    usageType.dataClass: #MIXED
}
define view C_CSPRStore
  as select from I_Site

  association [0..1] to I_RetailStoreUserAssignment    as _RetailStoreUserAssignment    on  $projection.Store = _RetailStoreUserAssignment.Store
                                                                                        and _RetailStoreUserAssignment.AssignedUser = $session.user
  association [0..*] to I_RetailStoreApplicationStore  as _RetailStoreApplicationStore  on  $projection.Store                                           = _RetailStoreApplicationStore.Store
                                                                                        and _RetailStoreApplicationStore.RetailStoreApplicationCategory = '2'
  association [0..1] to C_CSPRSettings                 as _Settings                     on  $projection.Store = _Settings.Store
  association [0..*] to C_CSPRStorageLocation          as _StorageLocation              on  $projection.Store = _StorageLocation.Store
  association [0..1] to C_CSPRCountSubmitAuthorization as _RFIDCountSubmitAuthorization on  $projection.Store = _RFIDCountSubmitAuthorization.Store
  association [0..1] to C_CSPRCountForceSubmitAuthzn   as _RFIDCountForceSubmitAuthzn   on  $projection.Store = _RFIDCountForceSubmitAuthzn.Store
  association [0..1] to C_CSPRCountDeleteAuthorization as _RFIDCountDeleteAuthorization on  $projection.Store = _RFIDCountDeleteAuthorization.Store
{
  key Site                as Store,

      SiteName            as StoreName,

      AddressID           as AddressID,

      @ObjectModel.readOnly: true
      @ObjectModel.virtualElement:true
      @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_RETAIL_ST_ADDRESS_FORMAT'
      cast('' as char200) as FormattedAddress,

      case when _RetailStoreUserAssignment.Store is not null then 'X'
           else ''
      end                 as RetailStoreIsAssignedToUser,

      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _Settings,
      @ObjectModel.association.type: [#TO_COMPOSITION_CHILD]
      _StorageLocation,
      _RetailStoreApplicationStore,
      _RFIDCountSubmitAuthorization,
      _RFIDCountForceSubmitAuthzn,
      _RFIDCountDeleteAuthorization
}
where
  SiteCategory = 'A'