C_CN_CustVH

@AbapCatalog.sqlViewName: 'CVCNCUSTVH'
@ClientHandling.algorithm: #SESSION_VARIABLE
@AccessControl.personalData.blocking: #REQUIRED
@AbapCatalog.compiler.compareFilter: true
@AccessControl.authorizationCheck: #CHECK
@VDM.viewType: #CONSUMPTION
@EndUserText.label: 'Customer Value Help'

@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass:  #MIXED
@ObjectModel.dataCategory:#VALUE_HELP
define view C_CN_CustVH
  as select from I_Customer
{
  key Customer                                                                       as Customer,
      //_CustomerToBusinessPartner name changed

      case when _CustomerToBusinessPartner._BusinessPartner.BusinessPartnerCategory = '1' then cast(_CustomerToBusinessPartner._BusinessPartner.BusinessPartnerName as /cpd/pws_ws_cust_name)
               when _CustomerToBusinessPartner._BusinessPartner.BusinessPartnerCategory = '2'
                 then
                 cast(substring(rtrim(replace(concat(_CustomerToBusinessPartner._BusinessPartner.OrganizationBPName1, concat(' &@', _CustomerToBusinessPartner._BusinessPartner.OrganizationBPName2)), '&@', ''),' '),1,80) as /cpd/pws_ws_cust_name)  //KF: diffierent with S4

               when _CustomerToBusinessPartner._BusinessPartner.BusinessPartnerCategory = '3'
                 then
                 cast(substring(rtrim(replace(concat(_CustomerToBusinessPartner._BusinessPartner.GroupBusinessPartnerName1, concat(' &@', _CustomerToBusinessPartner._BusinessPartner.GroupBusinessPartnerName2)), '&@', ''),' '),1,80) as /cpd/pws_ws_cust_name)   //KF: diffierent with S4

               else cast('' as /cpd/pws_ws_cust_name)
             end                                                                     as CustomerName,
      cast(_CustomerToBusinessPartner._BusinessPartner.SearchTerm1 as rssearch_term) as CustomerSearchText,
      //cast(_StandardAddress.Country as land1_gp)              as Country,

      cast(_AddressRepresentation.Country as land1_gp)                               as Country,
      //_StandardAddress.PostalCode                             as PostalCode,

      _AddressRepresentation.PostalCode                                              as PostalCode,
      //_StandardAddress.CityName                               as CustomerCityName

      _AddressRepresentation.CityName                                                as CustomerCityName,
      
      //CE2308 DPP BP data controller assignment adoption

      @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController1,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController2,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController3,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController4,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController5,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController6,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController7,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController8,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController9,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataController10,
      @UI.hidden: true
      @Consumption.hidden: true
      I_Customer.DataControllerSet
}
where
       IsBusinessPurposeCompleted != 'X'
  and(
       IsBusinessPurposeCompleted != 'X'
    or IsBusinessPurposeCompleted is null
  )