C_CAInvcgDocPrintReceiver

@VDM.viewType: #CONSUMPTION
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@AccessControl.personalData.blocking: #REQUIRED
@AccessControl.authorizationCheck: #MANDATORY
@EndUserText.label: 'Rechnungsempfänger'
@Metadata.ignorePropagatedAnnotations: true

@UI.presentationVariant: [ {
     requestAtLeast: ['CAInvoicingDocument', 'CACorrespondence', 'CAInvcgProcess', 'CAInvcgDocDuplicateIsEnabled', 'CAInvcgDocPrntOutpCtrlIsEnbld', 'CorrespondencePrintDate' ]
} ]

define view entity C_CAInvcgDocPrintReceiver
  as select from I_CACorrespondenceHeader as _CACorrespondenceHeader
{
         //      @UI.hidden: true

         @UI.lineItem: [ { type: #FOR_ACTION, position: 10, dataAction: 'MPC_EXT:ACTION_PRINT_DUPLICATE', label: 'Drucken Duplikat' } ]
  key    CACorrespondence,

         //      @UI.hidden: true

         //      @UI.lineItem: [ { type: #FOR_ACTION, position: 10, dataAction: 'MPC_EXT:ACTION_PRINT_DUPLICATE', label: 'Drucken Duplikat' } ]

  key    cast( Correspondence2ndEntityData as invdocno_kk )       as CAInvoicingDocument,
         @UI.hidden: true
         cast( Correspondence1stEntityData as inv_process_kk )    as CAInvcgProcess,

         @ObjectModel.text.element: ['CompanyCodeName']
         CompanyCode,
         @UI.hidden: true
         _CompCode.CompanyCodeName,

         @Consumption.hidden: true
         _BusinessPartner.BusinessPartnerCategory,
         @Consumption.hidden: true
         PersonNumber,
         @Consumption.hidden: true
         BusinessPartnerAddressID,

         @UI.lineItem: [ { position: 10 } ]
         @ObjectModel.text.element: ['BusinessPartnerFullName']
         cast( BusinessPartner as ftr_recipient preserving type ) as CorrespondenceRecipient,

         @UI.hidden: true
         _BusinessPartner.BusinessPartnerFullName                 as BusinessPartnerFullName,

         @UI.lineItem: [ { position: 20 } ]
         @ObjectModel.virtualElement: true
         @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
         cast('' as address_text_kk)                              as CorrespncAddrShortWthStrText,

         //         @UI.lineItem: [ { position: 30 } ]

         @ObjectModel.virtualElement: true
         @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
         cast('' as number_of_duplicates_kk)                      as CAInvcgDocNrOfPrntDpl,

         @UI.lineItem: [ { position: 40 } ]
         @ObjectModel.virtualElement: true
         @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
         cast('' as date_of_last_duplicate_kk)                    as CAInvcgDocLastPrintDplDate,

         // Action control: Duplicate

         @UI.hidden: true
         @ObjectModel.virtualElement: true
         @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_CINV_SADL_EXIT_INVDOC_DSP'
         cast( 'X' as xfeld )                                     as CAInvcgDocDuplicateIsEnabled,

         // Print Date

         @UI.lineItem: [ { position: 50 } ]
         CorrespondencePrintDate,

         @UI.hidden: true
         _CASendControl._Text[1: Language=$session.system_language].CACorrespncDispatchControlName,

         @ObjectModel.text.element: ['CACorrespncDispatchControlName']
         CACorrespncDispatchControl,

         @UI.hidden: true
         _CorrespncRole._Text[1: Language=$session.system_language].CACorrespondenceRoleText,
         @ObjectModel.text.element: ['CACorrespondenceRoleText']
         CorrespondenceRole,

         _BusinessPartner,
         _CASendControl,
         _CorrespncRole
}
where
  CACorrespondenceType = '0042'