C_CADocumentBPItemTP

@EndUserText.label: 'Contr Acct Business Partner Item'

@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #REQUIRED

@ObjectModel.usageType.dataClass: #TRANSACTIONAL
@ObjectModel.usageType.sizeCategory: #XXL
@ObjectModel.usageType.serviceQuality: #C
@ObjectModel.semanticKey: ['CADocumentNumber', 'CARepetitionItemNumber', 'CABPItemNumber', 'CASubItemNumber']

@VDM.viewType: #CONSUMPTION
@VDM.usage.type:[#TRANSACTIONAL_PROCESSING_SERVICE]

@Metadata.allowExtensions: true
define view entity C_CADocumentBPItemTP
  as projection on R_CADocumentBPItemTP
  
  association [1..1] to C_CADocBPItemClrgProcData      as _ClearingData on  $projection.CADocumentNumber       = _ClearingData.CADocumentNumber
                                                                        and $projection.CARepetitionItemNumber = _ClearingData.CARepetitionItemNumber
                                                                        and $projection.CABPItemNumber         = _ClearingData.CABPItemNumber
                                                                        and $projection.CASubItemNumber        = _ClearingData.CASubItemNumber
  
  association [0..*] to C_CADocumentBPItemBusLockEnhcd as _BusLock  on  $projection.CADocumentNumber       = _BusLock.CADocumentNumber
                                                                    and $projection.CABPItemNumber         = _BusLock.CABPItemNumber
                                                                    and $projection.CARepetitionItemNumber = _BusLock.CARepetitionItemNumber
                                                                    and $projection.CASubItemNumber        = _BusLock.CASubItemNumber

  association [0..*] to C_CADocumentIssue              as _DocIssue on  (
      _DocIssue.CADocumentIssueType                                                                          = '03'
      and $projection.CADocumentNumber                                                                       = _DocIssue.CADocumentNumber
    )
                                                                    or  (
                                                                        _DocIssue.CADocumentIssueType        = '01'
                                                                        and _DocIssue.CADocumentNumber       = $projection.CADocumentNumber
                                                                        and _DocIssue.CARepetitionItemNumber = $projection.CARepetitionItemNumber
                                                                        and _DocIssue.CABPItemNumber         = $projection.CABPItemNumber
                                                                        and _DocIssue.CASubItemNumber        = $projection.CASubItemNumber
                                                                      )
{
  key     CADocumentNumber,
  key     CARepetitionItemNumber,
  key     CABPItemNumber,
  key     CASubItemNumber,
  

          @ObjectModel.text.element: ['CompanyCodeName']
          CompanyCode,
          @Semantics.text: true
          _CompCode.CompanyCodeName,

          BusinessArea,
          BusinessPlace,
          Segment,
          ProfitCenter,
          Division,
          PersonnelNumber,
          PartnerCompany,
          @Consumption.valueHelpDefinition: [{entity: { name: 'C_CAContractPartnerValueHelp', element: 'BusinessPartner'}}]
          @ObjectModel.foreignKey.association: '_BusinessPartner'
          BusinessPartner,

          @Consumption.valueHelpDefinition: [{entity: { name: 'C_CAContractVH', element: 'CAContract'}, label: 'Contract', qualifier: 'CAContract'}]
          CAContract,

          CAProviderContractItemNumber,
          CAAdditionalContract,

          @ObjectModel.text.element: ['ContractAccountName']
          ContractAccount,
          @Semantics.text: true
          _CAPartner.ContractAccountName,

          CASubApplication,
          AltvContractAcctForCollvBills,
          CAReconciliationAccount,
          CAApplicationArea,
          @ObjectModel.foreignKey.association: '_MainTransaction'
          CAMainTransaction,
          @ObjectModel.foreignKey.association: '_SubTransaction'
          CASubTransaction,
          CAAccountDeterminationCode,
          CADoubtfulOrValueAdjmtCode,
          CAAccountAssignmentCategory,
          CAAccountAssignment,
          @ObjectModel.foreignKey.association: '_DocType'
          @ObjectModel.text.element: ['CADocumentTypeName']
          CADocumentType,
          _DocType._Text[1:Language=$session.system_language].CADocumentTypeName,
          CAIsDownPaymentRequest,
          CAItemIsOnlyForSettlement,
          CAStatisticalItemCode,
          CABPItemText,
          CANumberOfRepetitionItems,
          CARepetitionGroup,
          CAStartDateOfBillingPeriod,
          CAEndDateOfBillingPeriod,
          CAGroupingCodeForBPItems,
          CAPeriodCode,
          CAChangeIsForbidden,
          CAInterestCode,
          CARoundingItemCode,
          CAReceivingCountry,
          CAInternalPostingReasonCode,
          CAWorkflowCheckReason,
          CAWorkflowCheckProcess,
          CANegativePostingControlCode,
          CAPartnerSettlementStatus,
          CAIsPartOfJointLiability,
          CASubstituteDocumentNumber,
          CASubstituteDocumentCategory,
          CAStatisticalCodeOfOriginItem,
          CADocumentNumberOfOriginItem,
          CAReferenceDocument,
          DocumentDate,
          CAPostingDate,
          CANetDueDate,
          CADeferralDate,
          TransactionCurrency,
          CompanyCodeCurrency,
          AdditionalCurrency1,
          AdditionalCurrency2,
          CAExchangeRate,
          ExchRateIsIndirectQuotation,
          CAAmountInLocalCurrency,
          CAAmountInTransactionCurrency,
          CAAmountInSecondCurrency,
          CAAmountInThirdCurrency,
          CACashDiscountDueDate,
          CACashDiscountRate,
          CAEligibleAmountForCshDiscount,
          CACashDiscAmountInClearingCrcy,
          TaxCode,
          CASupplementaryTaxCode,
          CATaxAmountInLocalCurrency,
          CATaxAmountInTransCurrency,
          CATaxAmountInSecondCurrency,
          CATaxAmountInThirdCurrency,
          CADownPaymentTaxAccount,
          CADownPaymentOffsetTaxAccount,
          TaxJurisdiction,
          CATaxDate,
          WithholdingTaxCode,
          CAWithholdingTaxSupplement,
          CAWithholdingTaxCategory,
          CABaseAmountForWithholdingTax,
          CAWithholdingTaxAmount,
          CAWithholdingTaxPercentage,
          WithholdingTaxCertificate,
          CAOtherTaxCode,
          CAGroupingCodeForTaxItems,
          CATaxPortionInLocalCurrency,
          CATaxPortionInTransCurrency,
          CATaxIsCalculatedExternally,

          CAPaymentMethod,
          CAPaymentCompanyCode,
          CAGroupingForPayment,
          CAPaymentSpecificationCategory,

          @ObjectModel.foreignKey.association: '_ClearingStatus'
          CAClearingStatus,
          CAClearingDate,
          CAClearingDocumentNumber,
          CAPostingDateOfClearingDoc,

          CAClearingReason,
          CAClearingCurrency,
          CAClearingAmountInClearingCrcy,
          CATaxAmountInClearingCrcy,
          CAValueDateForClearing,
          CAClearingRestrictionCode,
          CAClearingPostingIsReset,
          CAItemIsWithdrawn,
          CAItemIsExcludedFromDunning,
          CADunningProcedure,
          CAGrpgCodeForTransfToCollAgcy,
          CAIsIncludedInCollectionCase,
          CashPlanningGroup,
          PlanningLevel,
          CAAdditionalDaysForCashMgmt,
          PlannedAmtInTransactionCrcy,
          CAAltvBPForPayment,
          CABankOfAltvBPForPayment,
          CAAddressOfAltvBPForPayment,
          CACardOfAltvBPForPayment,
          CAGLPostingCurrency,
          CAGLPostingAmount,
          CAGLPostingTaxAmount,
          CAIsSeparateLineItemInGL,
          CAIsCashFlowItem,
          CACashFlowAccount,
          CACashFlowCompanyCode,
          CAPaymentPreNotificationCode,
          CASEPAPreNotificationNumber,
          CASEPAPreNotifOriginCode,
          CASEPAPreNotifExecutionDate,
          CASEPAPreNotificationRqmtCode,
          CARevenueDistrFinalRecipient,
          CARevenueDistrCurrentStatus,
          CARevenueDistrLastStatus,
          CACurrentFactoringStatusOfRbl,
          CAFactoringCheckStsForClrgInfo,
          SEPAMandateCAInternalID,
          ChartOfAccounts,
          ControllingArea,
          Country,

          CADocumentOriginCode,



          _SubTransaction._Text[1:Language=$session.system_language].CASubTransactionName,


          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FKK_CADOCUMENT_BPITEM_EXIT'
  virtual CADocumentBPItemLongDesc       : opdesc_kk,
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FKK_CADOCUMENT_BPITEM_EXIT'
  virtual CADocumentBPItemShortDesc      : opdesc_kk,
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FKK_CADOCUMENT_BPITEM_EXIT'
  virtual CADocumentBPItemNavigationDesc : opdesc_kk,
          @UI.hidden: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FKK_CADOCUMENT_BPITEM_EXIT'
  virtual UICT_HideDisputeCreationButton : boole_d,
          @UI.hidden: true
          @ObjectModel.virtualElementCalculatedBy: 'ABAP:CL_FKK_CADOCUMENT_BPITEM_EXIT'
  virtual CAContractSemanticObject       : vtref_semobj_kk,

          /* Associations */
          _BPItemBusLock,
          _DocHeader : redirected to parent C_CADocumentTP,
          _BusLock,
          _DocIssue,
          _AcctAssgmtCat,
          _AcctDetnCode,
          _AdditionalCurrency1,
          _AdditionalCurrency2,
          _AltvBPForPayment,
          _ApplArea,
          _BusinessArea,
          _BusinessPartner,
          _CAHeader,
          _CAHeaderCollvBills,
          _CAHeaderFinalRec,
          _CAPartner,
          _CARevnDistrCurSts,
          _CARevnDistrLastSts,
          _CARoundingItemCode,
          _SEPAPreNotifOrignCd,
          _SEPAPreNotifRqmtCode,
          _CashFlowAccount,
          _CASubApplication,
          _ClearingCurrency,
          _ClearingDocHeader,
          _ClearingReason,
          _ClearingStatus,
          _ClrgRstrcnCode,
          _Currency,
          _CompanyCodeCurrency,
          _CompCode,
          _CompCodeCashFlow,
          _CompCodePayt,
          _ControllingArea,
          _ChartOfAccounts,
          _Country,
          _DbtflOrValAdjmtCode,
          _Division,
          _DocType,
          _DunningProcedure,
          _FactoringRblStatus,
          _FctrngClrgChkStatus,
          _GLPostingCurrency,
          _InterestCode,
          _IntPostingReasonCode,
          _MainTransaction,
          _NgtvPostingCtrlCode,
          _OffsetTaxAccount,
          _OriginDocHeader,
          _OriglStstclItemCode,
          _OtherTaxCode,
          _PartnerCompany,
          _PaytMethod,
          _PaytPreNotifCode,
          _PaytSpecCategory,
          _PeriodCode,
          _ProfitCenter,
          _ProviderContract,
          _PrtnSettlementStatus,
          _ReceivingCountry,
          _ReconAccount,
          _Segment,
          _StatisticalItemCode,
          _SubstitDocCategory,
          _SubstitDocHeader,
          _SubTransaction,
          _TaxAccount,
          _WhldgTaxSuplmnt,
          _CAWithholdingTaxCat,
          _WithholdingTaxCode,
          _WorkflowCheckProcess,
          _WorkflowCheckReason,
          @ObjectModel.sort.enabled: false
          @ObjectModel.filter.enabled: false
          _ClearingData

}