C_BkAcctInstntBalSetting

@EndUserText.label: 'Bank Account Instant Balance Setting'
@AccessControl.authorizationCheck: #MANDATORY
@Metadata.allowExtensions: true
@Search.searchable: true
@VDM : { viewType: #CONSUMPTION,
        usage.type: [ #TRANSACTIONAL_PROCESSING_SERVICE ] }
@ObjectModel: {
//    semanticKey: [ 'BankAccountInternalID', 'CompanyCode', 'HouseBank', 'HouseBankAccount' ],

    usageType: {
        serviceQuality: #C,
        sizeCategory:   #M,
        dataClass:      #TRANSACTIONAL }
}
@AccessControl.privilegedAssociations: [ '_CreatedByUserCntctCard', '_LastChangedByUserCntctCard' ]
define root view entity C_BkAcctInstntBalSetting
  as select from I_BkAcctInstntBalanceEnhanced
  association [1..1] to I_BkAcctInstntBalanceStatus as _BkAcctInstntBalanceStatus  on $projection.BkAcctInstntBalanceStatus = _BkAcctInstntBalanceStatus.BkAcctInstntBalanceStatus
  association [1..1] to I_HsBkInstantBalanceStatus  as _HsBkInstantBalanceStatus   on $projection.HouseBankInstantBalanceStatus = _HsBkInstantBalanceStatus.HouseBankInstantBalanceStatus
  association [0..1] to I_UserContactCard           as _CreatedByUserCntctCard     on $projection.CreatedByUser = _CreatedByUserCntctCard.ContactCardID
  association [0..1] to I_UserContactCard           as _LastChangedByUserCntctCard on $projection.LastChangedByUser = _LastChangedByUserCntctCard.ContactCardID
{
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
  key BankAccountInternalID,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.text.element: ['CompanyCodeName']
      @UI.textArrangement: #TEXT_LAST
      CompanyCode,
      @Semantics.text
      @UI.hidden: true
      _CompanyCode.CompanyCodeName,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      HouseBank,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.text.element: ['HouseBankAccountDescription']
      HouseBankAccount,

      @EndUserText: { label: 'Account Switch Status', quickInfo: 'Account Switch Status' }
      @ObjectModel.text.element: [ 'BkAcctInstntBalanceStatusText' ]
      @UI.textArrangement: #TEXT_ONLY
      @Consumption.valueHelpDefinition: [ { entity:  { name: 'I_BkAcctInstntBalanceStatus', element: 'BkAcctInstntBalanceStatus' } }]
      BkAcctInstntBalanceStatus,
      @UI.hidden: true
      _BkAcctInstntBalanceStatus._Text[1:Language = $session.system_language].BkAcctInstntBalanceStatusText,
      @Consumption.filter.hidden: true
      _BkAcctInstntBalanceStatus._Criticality.BkAcctInstntBalStsCritlty,

      @EndUserText: { label: 'House Bank Enablement', quickInfo: 'House Bank Enablement' }
      @ObjectModel.text.element: [ 'HsBankInstntBalanceStatusText' ]
      @UI.textArrangement: #TEXT_ONLY
      @Consumption.valueHelpDefinition: [ { entity:  { name: 'I_HsBkInstantBalanceStatus', element: 'HouseBankInstantBalanceStatus' } }]
      @Consumption.filter : { selectionType: #SINGLE, defaultValue: '1', multipleSelections: false }
      HouseBankInstantBalanceStatus,
      @UI.hidden: true
      _HsBkInstantBalanceStatus._Text[1:Language = $session.system_language].HsBankInstntBalanceStatusText,
      @Consumption.filter.hidden: true
      _HsBkInstantBalanceStatus._Criticality.HsBankInstntBalStatusCritlty,

      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      HouseBankAccountDescription,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      BankAccountNumber,
      @Consumption.filter.hidden: true
      BankInternalID,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.text.element: ['BankName']
      @UI.textArrangement: #TEXT_LAST
      BankNumber,
      @UI.hidden: true
      _BankData.BankName,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      @ObjectModel.text.element: ['CountryName']
      @UI.textArrangement: #TEXT_LAST
      BankCountry,
      @Semantics.text
      @UI.hidden: true
      _BankCountry._Text[1:Language = $session.system_language].CountryName as CountryName,
      BankAccountCurrency,
      @Search.defaultSearchElement: true
      @Search.fuzzinessThreshold: 0.8
      @Search.ranking: #HIGH
      IBAN,

      @UI.textArrangement: #TEXT_LAST
      @ObjectModel.text.element: ['CreatedByUserDescription']
      @Semantics.user.createdBy: true
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BusinessUserVH', element: 'UserID' } } ]
      @EndUserText: { label: 'Created By', quickInfo: 'Created By' }
      CreatedByUser,
      @UI.hidden: true
      _UserCreate.UserDescription                                           as CreatedByUserDescription,

      @EndUserText: { label: 'Created At', quickInfo: 'Created At' }
      @Consumption.filter.selectionType: #INTERVAL
      CreationDateTime,
      @UI.textArrangement: #TEXT_LAST
      @ObjectModel.text.element: ['LastChangedByUserDescription']
      @Semantics.user.createdBy: true
      @Consumption.valueHelpDefinition: [ { entity: { name: 'I_BusinessUserVH', element: 'UserID' } } ]
      @EndUserText: { label: 'Last Changed By', quickInfo: 'Last Changed By' }
      LastChangedByUser,
      @UI.hidden: true
      _UserChange.UserDescription                                           as LastChangedByUserDescription,
      @EndUserText: { label: 'Last Changed At', quickInfo: 'Last Changed At' }
      @Consumption.filter.selectionType: #INTERVAL
      LastChangeDateTime,

      @Aggregation.default:#SUM
      @UI.hidden: true
      1                                                                     as DummyMeasure,

      @Consumption.filter.hidden: true
      _CreatedByUserCntctCard,
      @Consumption.filter.hidden: true
      _LastChangedByUserCntctCard
}