C_AsstmtMdlUserToAsstmtMdlTP

@EndUserText.label: 'Assortment User Assignment to Assortment Module'
@AccessControl.authorizationCheck: #CHECK
@Metadata.allowExtensions: true
@ObjectModel: {
    representativeKey: 'AssortmentModuleUser',
    semanticKey: ['AssortmentModuleName','AssortmentModuleUser'],
    usageType: {
        serviceQuality: #C,
        sizeCategory: #M,
        dataClass: #MASTER } }
@AccessControl: {
  privilegedAssociations: ['_User']
}
@VDM.viewType: #CONSUMPTION
@VDM.usage.type: [#TRANSACTIONAL_PROCESSING_SERVICE]
define root view entity C_AsstmtMdlUserToAsstmtMdlTP
  provider contract transactional_query
  as projection on I_AssMdlUserToExplctAssMdlTP_2
{
  key AssortmentModuleUUID,

      @ObjectModel.text.element: ['SiteName']
      @Consumption.valueHelpDefinition: [{
        entity.name:    'C_AssortmentModuleUserVH',
        entity.element: 'SiteCustomer'
      }]
  key AssortmentModuleUser,
  key ValidityStartDate,

      AssortmentModuleName,
      ValidityEndDate,
      LastChangeDateTime,
      LastChangedByUserName,

      @ObjectModel.text.element: ['SalesOrganizationName']
      SalesOrganization,
      @ObjectModel.text.element: ['DistributionChannelName']
      DistributionChannel,

      @Semantics: { text: true, address: {country}}
      _Site._Address._Country._Text.CountryName                : localized,

      @Semantics: {address: {city}}
      _Site._Address.CityName,

      @Semantics.text: true
      _Site.SiteName,

      _Site._SalesOrganization._Text.SalesOrganizationName     : localized,
      _Site._DistributionChannel._Text.DistributionChannelName : localized,

      _ExclusionRatio.AsstmtMdlProdExclusionPercent,

      /* Associations */
      //I_AssMdlUserToExplicitAssMdlTP

      _Exclusions,
      _ExplicitAssortmentModule,
      _Products,
      _Text,
      _User

}