C_AR_StRpPurchaseVATRateDetC

@AbapCatalog.sqlViewName: 'CARPURVATRATEDC'
@AbapCatalog.compiler.compareFilter: true
@AbapCatalog.preserveKey: true
@AccessControl.authorizationCheck: #CHECK
@AccessControl.personalData.blocking: #BLOCKED_DATA_INCLUDED
@VDM.viewType: #CONSUMPTION
@ClientHandling.algorithm: #SESSION_VARIABLE
@Analytics.dataCategory: #CUBE
@Analytics.internalName: #LOCAL
@ObjectModel.usageType.sizeCategory: #XL
@ObjectModel.usageType.serviceQuality: #D
@ObjectModel.usageType.dataClass: #MIXED
@Metadata.allowExtensions:true
@EndUserText.label: 'Argentina Purchase VAT Rates Detail - Cube'
@Consumption.dbHints: ['USE_HEX_PLAN','NO_SUBPLAN_SHARING']
define view C_AR_StRpPurchaseVATRateDetC
  with parameters
    P_RptgAmountIsInTransCrcy : fiar_use_transaction_currency

  as select from           P_AR_PurchaseVATRateDetail2
                 ( P_RptgAmountIsInTransCrcy : $parameters.P_RptgAmountIsInTransCrcy ) as PurchaseVATRateDetail

    left outer to one join I_AR_VAT                                                                                   on  I_AR_VAT.CompanyCode         = PurchaseVATRateDetail.CompanyCode
                                                                                                                      and I_AR_VAT.AR_VATRateInPercent = PurchaseVATRateDetail.TaxRate
                                                                                                                      and I_AR_VAT.AR_Regime           = '3685'

    left outer to one join I_Ar_FrgnNatlTxCode                                         as Ar_FrgnNatlTxCode           on  Ar_FrgnNatlTxCode.Country                  = PurchaseVATRateDetail.BusinessPartnerCountry
                                                                                                                      and Ar_FrgnNatlTxCode.NFPartnerIsNaturalPerson = PurchaseVATRateDetail.IsNaturalPerson
{
  key PurchaseVATRateDetail.CompanyCode,
  key PurchaseVATRateDetail.FiscalYear,
  key PurchaseVATRateDetail.AccountingDocument,
  key cast( cast(PurchaseVATRateDetail.TaxRate as abap.numc(16)) as fitaxrate) as TaxRate,
  key PurchaseVATRateDetail.StatryRptCategory,
  key PurchaseVATRateDetail.StatryRptgEntity,
  key PurchaseVATRateDetail.StatryRptRunID,
      PurchaseVATRateDetail.PostingDate,
      PurchaseVATRateDetail.DocumentDate,
      PurchaseVATRateDetail.ReportingDate,
      cast (I_AR_VAT.AR_VATRateCode as j_1avat_code)                           as AR_VATRateCode,
      PurchaseVATRateDetail.AccountingDocumentType,

      PurchaseVATRateDetail.AR_OfficialDocumentType,

      PurchaseVATRateDetail.AR_OfficialDocumentClass,
      PurchaseVATRateDetail.DocumentReferenceID,
      PurchaseVATRateDetail.AR_PrintCharacter,

      cast(
        case
          when
              PurchaseVATRateDetail.AR_OfficialDocumentType = '033' or
              PurchaseVATRateDetail.AR_OfficialDocumentType = '090' or
              PurchaseVATRateDetail.AR_OfficialDocumentType = '099' or
              PurchaseVATRateDetail.AR_OfficialDocumentType = '331' or
              PurchaseVATRateDetail.AR_OfficialDocumentType = '332'
            then '0000'
          else PurchaseVATRateDetail.AR_Branch
        end as fiar_branch
      )                                                                        as AR_Branch,

      PurchaseVATRateDetail.AR_OfficialDocumentNumber,

      cast(
        case
          when PurchaseVATRateDetail.AR_OfficialDocumentType = '090' or PurchaseVATRateDetail.AR_OfficialDocumentType = '099'
            then
              case
                when PurchaseVATRateDetail.AR_PrintCharacter <> ''
                  then PurchaseVATRateDetail.AR_OfficialDocumentNumber
                else PurchaseVATRateDetail.DocumentReferenceID
              end
          else PurchaseVATRateDetail.AR_OfficialDocumentNumber
        end as fis_xblnr1 preserving type
      )                                                                        as AccountingDocExternalReference,

      cast(
        case PurchaseVATRateDetail.BusinessPartnerCountry
          when 'AR'
            then PurchaseVATRateDetail.TaxNumber1
          else Ar_FrgnNatlTxCode.AR_CUIT
        end as stcd1 preserving type
      )                                                                        as TaxNumber1,

      cast(
        case PurchaseVATRateDetail.BusinessPartnerCountry
          when 'AR'
            then PurchaseVATRateDetail.TaxNumberType
          else '80'
        end as j_1atoid preserving type
      )                                                                        as TaxNumberType,

      PurchaseVATRateDetail.BusinessPartnerName,
      PurchaseVATRateDetail.CompanyCodeCountry,

      @Semantics.currencyCode:true
      PurchaseVATRateDetail.CompanyCodeCurrency,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      PurchaseVATRateDetail.TaxAmountInCoCodeCrcy,
      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'CompanyCodeCurrency'
      PurchaseVATRateDetail.TaxBaseAmountInCoCodeCrcy,

      @Semantics.currencyCode:true
      PurchaseVATRateDetail.TransactionCurrency,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      PurchaseVATRateDetail.TaxAmountInTransCrcy,
      @DefaultAggregation: #SUM
      @Semantics.amount.currencyCode: 'TransactionCurrency'
      PurchaseVATRateDetail.TaxBaseAmountInTransCrcy,

      @Semantics.currencyCode:true
      PurchaseVATRateDetail.ReportingCurrency,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      cast(
        case PurchaseVATRateDetail.DebitCreditCode
          when 'H'
            then PurchaseVATRateDetail.TaxAmountInRptgCrcy
          else abs(PurchaseVATRateDetail.TaxAmountInRptgCrcy)
        end as glo_tax_amount_rptg_crcy preserving type
      )                                                                        as TaxAmountInRptgCrcy,

      @DefaultAggregation:#SUM
      @Semantics.amount.currencyCode: 'ReportingCurrency'
      cast(
        case PurchaseVATRateDetail.DebitCreditCode
          when 'H'
            then PurchaseVATRateDetail.TaxBaseAmountInRptgCrcy
          else abs(PurchaseVATRateDetail.TaxBaseAmountInRptgCrcy)
        end as glo_taxbase_amount_rptg_crcy preserving type
      )                                                                        as TaxBaseAmountInRptgCrcy
}