A_ServiceConfirmation

@ClientHandling.algorithm:#SESSION_VARIABLE
@EndUserText.label: 'Service Confirmation'
@VDM: {
  viewType: #COMPOSITE,
  lifecycle.contract.type: #PUBLIC_REMOTE_API
}
@AbapCatalog: {
  sqlViewName: 'ASRVCON',
  compiler.compareFilter: true,
  preserveKey: true
}
@AccessControl: {
  authorizationCheck: #CHECK,
  personalData.blocking: #('TRANSACTIONAL_DATA')
  //,

  // _StatusCancelled association is changed to PRIVILEGED_ONLY

  //privilegedAssociations: ['_StatusCancelled']

}
@ObjectModel: {
   representativeKey: 'ServiceConfirmation',
   createEnabled: true,
   updateEnabled: true,
   usageType: {
     dataClass:      #MIXED,
     serviceQuality: #C,
     sizeCategory:   #XXL
   }
}
@Metadata.ignorePropagatedAnnotations: true


define view A_ServiceConfirmation
  as select from I_ServiceDocumentEnhcd as ServiceConfirmation

  association [0..*] to A_ServiceConfirmationItem    as _Item                  on  $projection.ServiceConfirmation = _Item.ServiceConfirmation

  association [0..*] to A_ServiceConfPersonResp      as _PersonResponsible     on  $projection.ServiceConfirmation = _PersonResponsible.ServiceConfirmation

  association [0..*] to A_ServiceConfRefObject       as _ReferenceObject       on  $projection.ServiceConfirmation = _ReferenceObject.ServiceConfirmation

  association [0..*] to A_ServiceConfirmationText    as _Text                  on  $projection.ServiceConfirmation = _Text.ServiceConfirmation

  association [0..1] to I_StatusObjectUUIDStatus     as _StatusCancelled       on  $projection.ServiceConfirmationUUID = _StatusCancelled.StatusObjectUUID
                                                                               and _StatusCancelled.StatusCode         = 'I1096'

  association [0..*] to I_ServiceDocumentPredecessor as _RefServiceOrder       on  $projection.ServiceConfirmationUUID          = _RefServiceOrder.ServiceDocumentUUID
                                                                               and _RefServiceOrder.ServiceDocPrdcssrBusObjType = 'BUS2000116'

  association [0..*] to A_ServiceConfPriceElement    as _PricingElement        on  $projection.ServiceConfirmation = _PricingElement.ServiceConfirmation

  association [0..1] to I_RespyMgmtTeamHeaderDetail  as _ServiceTeamHeader     on  $projection.RespyMgmtServiceTeam = _ServiceTeamHeader.RespyMgmtTeamID

  //Extensibility

  association [0..1] to E_ServiceDocument            as _Extension             on  _Extension.ServiceCategory      = 'BUS2000117'
                                                                               and $projection.ServiceConfirmation = _Extension.ServiceOrder

  association [0..*] to A_ServiceConfUserStatus      as _ServiceConfUserStatus on  $projection.ServiceConfirmation = _ServiceConfUserStatus.ServiceConfirmation

  association [0..*] to A_SrvcConfPartner            as _Partner               on  $projection.ServiceConfirmation = _Partner.ServiceConfirmation

  association [0..*] to A_SrvcConfDuration           as _Duration              on  $projection.ServiceConfirmation = _Duration.ServiceConfirmation

  association [0..*] to A_SrvcConfAppointment        as _Appointment           on  $projection.ServiceConfirmation = _Appointment.ServiceConfirmation
  association [0..1] to I_WBSElementBasicData        as _WBSElementCO          on  _WBSElementCO.WBSElement = ServiceConfirmation.WBSElement
  
  association [0..*] to A_SrvcConfTransHistory       as _SrvcConfTransHistory  on  $projection.ServiceConfirmation = _SrvcConfTransHistory.ServiceConfirmation
{

  key  ServiceDocument                              as ServiceConfirmation,
       @ObjectModel.sapObjectNodeTypeReference: 'ServiceDocumentType'
       ServiceDocumentType                          as ServiceConfirmationType,
       ServiceDocumentUUID                          as ServiceConfirmationUUID,
       ServiceDocumentDescription                   as ServiceConfirmationDescription,
       ServiceObjectType,
       Language,
       @ObjectModel.sapObjectNodeTypeReference: 'ServiceDocumentPriority'
       ServiceDocumentPriority,
       RequestedServiceStartDateTime,
       RequestedServiceEndDateTime,
       ErlstRequestedDeliveryDateTime,

       PurchaseOrderByCustomer,
       CustomerPurchaseOrderDate,

       /* STATUS */
       //case ServiceDocumentStatus

       //when 'C' then 'X'

       //else ''

       //end                                          as ServiceConfirmationIsCompleted,


       case ServiceDocumentIsOpen
       when '' then
       case ServiceDocumentIsReleased
       when '' then 'X' else ''
       end
       else ''
       end                                          as ServiceConfirmationIsCompleted,

       _StatusCancelled.StatusIsActive              as ServiceConfirmationIsCanceled,

       //ServiceConfirmationIsFinal


       /* ORG */
       SalesOrganization,
       DistributionChannel,
       @ObjectModel.sapObjectNodeTypeReference: 'Division'
       Division,
       SalesOffice,
       SalesGroup,

       /* PARTNER */
       SoldToParty,
       ShipToParty,
       BillToParty,
       PayerParty,
       ContactPerson,

       _RefServiceOrder._ServiceDoc.ServiceDocument as ReferenceServiceOrder,

       ServiceConfirmationIsFinal,
       @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
       ServiceDocGrossAmount,
       @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
       ServiceDocNetAmount,
       @Semantics: { amount : {currencyCode: 'TransactionCurrency'} }
       ServiceDocTaxAmount,
       @ObjectModel.sapObjectNodeTypeReference: 'Currency'
       TransactionCurrency,

       /* Shipping */
       ShippingCondition,

       /********************************************************/
       /*********  Cloud Specific Fields **************************/
       //Service Team

       //@ObjectModel.editableFieldFor: 'RespyMgmtServiceTeamName'

       //@feature: 'BF:API_ESSENTIALSCOPE'

       RespyMgmtServiceTeam,

       //@feature: 'BF:API_ESSENTIALSCOPE'

       @ObjectModel.readOnly: true
       _ServiceTeamHeader.TeamName                  as RespyMgmtServiceTeamName,

       //@feature: 'BF:API_ESSENTIALSCOPE'

       _ServiceTeamHeader.RespyMgmtGlobalTeamID     as RespyMgmtGlobalTeamID,

       /********************************************************/

       /********************************************************/
       /*********  OP Specific Fields **************************/
       //@feature: 'BF:API_FULLSCOPE'

       SalesOrganizationOrgUnitID,

       //@feature: 'BF:API_FULLSCOPE'

       ServiceOrganization,

       //@feature: 'BF:API_FULLSCOPE'

       SalesOfficeOrgUnitID,

       //@feature: 'BF:API_FULLSCOPE'

       SalesGroupOrgUnitID,

       @Feature: 'BF:API_FULLSCOPE'
       @ObjectModel.sapObjectNodeTypeReference: 'EnterpriseServiceOrganization'
       EnterpriseServiceOrganization,
       /********************************************************/

       _WBSElementCO.WBSElementExternalID,

       //Associations

       _Item,
       _PersonResponsible,
       _ReferenceObject,
       _Text,
       _PricingElement,
       _ServiceConfUserStatus,
       //@Feature: 'BF:API_FULLSCOPE'

       _Partner,
       _Duration,
       _Appointment,
       _SrvcConfTransHistory
}
where
  ServiceObjectType = 'BUS2000117' // Service Confirmation